Stop using snprintf in write_hex_to_fd (XCC)
[akaros.git] / tools / compilers / gcc-glibc / glibc-2.19-akaros / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
7
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11                    [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13                    [Bug reporting address])
14
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17   [m4_divert_text([DEFAULTS],
18     [ac_includes_default='/* none */'])])
19
20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29   CPP=
30 fi
31 if test -z "$CPP"; then
32   CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
36
37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
41
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
44
45 AC_CANONICAL_HOST
46
47 AC_PROG_CC
48 if test $host != $build; then
49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 # We need the C++ compiler only for testing.
54 AC_PROG_CXX
55 AC_CHECK_TOOL(READELF, readelf, false)
56
57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
58   AC_MSG_ERROR([you must configure in a separate build directory])
59 fi
60
61 # This will get text that should go into config.make.
62 config_vars=
63
64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
65 AC_ARG_WITH([gd],
66             AC_HELP_STRING([--with-gd=DIR],
67                            [find libgd include dir and library with prefix DIR]),
68             [dnl
69 case "$with_gd" in
70 yes|''|no) ;;
71 *) libgd_include="-I$withval/include"
72    libgd_ldflags="-L$withval/lib" ;;
73 esac
74 ])
75 AC_ARG_WITH([gd-include],
76             AC_HELP_STRING([--with-gd-include=DIR],
77                            [find libgd include files in DIR]),
78             [dnl
79 case "$with_gd_include" in
80 ''|no) ;;
81 *) libgd_include="-I$withval" ;;
82 esac
83 ])
84 AC_ARG_WITH([gd-lib],
85             AC_HELP_STRING([--with-gd-lib=DIR],
86                            [find libgd library files in DIR]),
87             [dnl
88 case "$with_gd_lib" in
89 ''|no) ;;
90 *) libgd_ldflags="-L$withval" ;;
91 esac
92 ])
93
94 if test -n "$libgd_include"; then
95   config_vars="$config_vars
96 CFLAGS-memusagestat.c = $libgd_include"
97 fi
98 if test -n "$libgd_ldflags"; then
99   config_vars="$config_vars
100 libgd-LDFLAGS = $libgd_ldflags"
101 fi
102
103 dnl Arguments to specify presence of other packages/features.
104 AC_ARG_WITH([fp],
105             AC_HELP_STRING([--with-fp],
106                            [if using floating-point hardware @<:@default=yes@:>@]),
107             [with_fp=$withval],
108             [with_fp=yes])
109 AC_SUBST(with_fp)
110 AC_ARG_WITH([binutils],
111             AC_HELP_STRING([--with-binutils=PATH],
112                            [specify location of binutils (as and ld)]),
113             [path_binutils=$withval],
114             [path_binutils=''])
115 AC_ARG_WITH([selinux],
116             AC_HELP_STRING([--with-selinux],
117                            [if building with SELinux support]),
118             [with_selinux=$withval],
119             [with_selinux=auto])
120
121 AC_ARG_WITH([headers],
122             AC_HELP_STRING([--with-headers=PATH],
123                            [location of system headers to use
124                             (for example /usr/src/linux/include)
125                             @<:@default=compiler default@:>@]),
126             [sysheaders=$withval],
127             [sysheaders=''])
128 AC_SUBST(sysheaders)
129
130 AC_SUBST(use_default_link)
131 AC_ARG_WITH([default-link],
132             AC_HELP_STRING([--with-default-link],
133                            [do not use explicit linker scripts]),
134             [use_default_link=$withval],
135             [use_default_link=default])
136
137 AC_ARG_ENABLE([sanity-checks],
138               AC_HELP_STRING([--disable-sanity-checks],
139                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
140               [enable_sanity=$enableval],
141               [enable_sanity=yes])
142
143 AC_ARG_ENABLE([shared],
144               AC_HELP_STRING([--enable-shared],
145                              [build shared library @<:@default=yes if GNU ld@:>@]),
146               [shared=$enableval],
147               [shared=yes])
148 AC_ARG_ENABLE([profile],
149               AC_HELP_STRING([--enable-profile],
150                              [build profiled library @<:@default=no@:>@]),
151               [profile=$enableval],
152               [profile=no])
153
154 AC_ARG_ENABLE([oldest-abi],
155               AC_HELP_STRING([--enable-oldest-abi=ABI],
156                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
157               [oldest_abi=$enableval],
158               [oldest_abi=no])
159 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
160   oldest_abi=default
161 else
162   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
163 fi
164 AC_SUBST(oldest_abi)
165
166 AC_ARG_ENABLE([hardcoded-path-in-tests],
167               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
168                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
169               [hardcoded_path_in_tests=$enableval],
170               [hardcoded_path_in_tests=no])
171 AC_SUBST(hardcoded_path_in_tests)
172
173 AC_ARG_ENABLE([stackguard-randomization],
174               AC_HELP_STRING([--enable-stackguard-randomization],
175                              [initialize __stack_chk_guard canary with a random number at program start]),
176               [enable_stackguard_randomize=$enableval],
177               [enable_stackguard_randomize=no])
178 if test "$enable_stackguard_randomize" = yes; then
179   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
180 fi
181
182 AC_ARG_ENABLE([lock-elision],
183               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
184                              [Enable lock elision for pthread mutexes by default]),
185               [enable_lock_elision=$enableval],
186               [enable_lock_elision=no])
187 if test "$enable_lock_elision" = yes ; then
188   AC_DEFINE(ENABLE_LOCK_ELISION)
189 fi
190
191 dnl Generic infrastructure for drop-in additions to libc.
192 AC_ARG_ENABLE([add-ons],
193               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
194                              [configure and build add-ons in DIR1,DIR2,...
195                               search for add-ons if no parameter given]),
196                              , [enable_add_ons=yes])
197
198 AC_ARG_ENABLE([hidden-plt],
199               AC_HELP_STRING([--disable-hidden-plt],
200                              [do not hide internal function calls to avoid PLT]),
201               [hidden=$enableval],
202               [hidden=yes])
203 if test "x$hidden" = xno; then
204   AC_DEFINE(NO_HIDDEN)
205 fi
206
207 AC_ARG_ENABLE([bind-now],
208               AC_HELP_STRING([--enable-bind-now],
209                              [disable lazy relocations in DSOs]),
210               [bindnow=$enableval],
211               [bindnow=no])
212 AC_SUBST(bindnow)
213
214 dnl On some platforms we cannot use dynamic loading.  We must provide
215 dnl static NSS modules.
216 AC_ARG_ENABLE([static-nss],
217               AC_HELP_STRING([--enable-static-nss],
218                              [build static NSS modules @<:@default=no@:>@]),
219               [static_nss=$enableval],
220               [static_nss=no])
221 dnl Enable static NSS also if we build no shared objects.
222 if test x"$static_nss" = xyes || test x"$shared" = xno; then
223   static_nss=yes
224   AC_DEFINE(DO_STATIC_NSS)
225 fi
226
227 AC_ARG_ENABLE([force-install],
228               AC_HELP_STRING([--disable-force-install],
229                              [don't force installation of files from this package, even if they are older than the installed files]),
230               [force_install=$enableval],
231               [force_install=yes])
232 AC_SUBST(force_install)
233
234 AC_ARG_ENABLE([maintainer-mode],
235               AC_HELP_STRING([--enable-maintainer-mode],
236                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
237               [maintainer=$enableval],
238               [maintainer=no])
239
240 dnl On some platforms we allow dropping compatibility with all kernel
241 dnl versions.
242 AC_ARG_ENABLE([kernel],
243               AC_HELP_STRING([--enable-kernel=VERSION],
244                              [compile for compatibility with kernel not older than VERSION]),
245               [minimum_kernel=$enableval],
246               [])
247 dnl Prevent unreasonable values.
248 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
249   # Better nothing than this.
250   minimum_kernel=""
251 else
252   if test "$minimum_kernel" = current; then
253     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
254   fi
255 fi
256
257 dnl For the development we sometimes want gcc to issue even more warnings.
258 dnl This is not the default since many of the extra warnings are not
259 dnl appropriate.
260 AC_ARG_ENABLE([all-warnings],
261               AC_HELP_STRING([--enable-all-warnings],
262                              [enable all useful warnings gcc can issue]),
263               [all_warnings=$enableval],
264               [])
265 AC_SUBST(all_warnings)
266
267 AC_ARG_ENABLE([multi-arch],
268               AC_HELP_STRING([--enable-multi-arch],
269                              [enable single DSO with optimizations for multiple architectures]),
270               [multi_arch=$enableval],
271               [multi_arch=default])
272
273 AC_ARG_ENABLE([nss-crypt],
274               AC_HELP_STRING([--enable-nss-crypt],
275                              [enable libcrypt to use nss]),
276               [nss_crypt=$enableval],
277               [nss_crypt=no])
278 if test x$nss_crypt = xyes; then
279   nss_includes=-I$(nss-config --includedir 2>/dev/null)
280   if test $? -ne 0; then
281     AC_MSG_ERROR([cannot find include directory with nss-config])
282   fi
283   old_CFLAGS="$CFLAGS"
284   CFLAGS="$CFLAGS $nss_includes"
285   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
286 #include <hasht.h>
287 #include <nsslowhash.h>
288 void f (void) { NSSLOW_Init (); }])],
289              libc_cv_nss_crypt=yes,
290              AC_MSG_ERROR([
291 cannot find NSS headers with lowlevel hash function interfaces]))
292   old_LIBS="$LIBS"
293   LIBS="$LIBS -lfreebl3"
294   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
295 #include <hasht.h>
296 #include <nsslowhash.h>],
297                                   [NSSLOW_Init();])],
298                  libc_cv_nss_crypt=yes,
299                  AC_MSG_ERROR([
300 cannot link program using lowlevel NSS hash functions]))
301   CFLAGS="$old_CFLAGS"
302   LIBS="$old_LIBS"
303 else
304   libc_cv_nss_crypt=no
305 fi
306 AC_SUBST(libc_cv_nss_crypt)
307
308
309 AC_ARG_ENABLE([obsolete-rpc],
310               AC_HELP_STRING([--enable-obsolete-rpc],
311                              [build and install the obsolete RPC code for link-time usage]),
312               [link_obsolete_rpc=$enableval],
313               [link_obsolete_rpc=no])
314 AC_SUBST(link_obsolete_rpc)
315
316 if test "$link_obsolete_rpc" = yes; then
317   AC_DEFINE(LINK_OBSOLETE_RPC)
318 fi
319
320 AC_ARG_ENABLE([systemtap],
321               [AS_HELP_STRING([--enable-systemtap],
322                [enable systemtap static probe points @<:@default=no@:>@])],
323               [systemtap=$enableval],
324               [systemtap=no])
325 if test "x$systemtap" != xno; then
326   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
327   old_CFLAGS="$CFLAGS"
328   CFLAGS="-std=gnu99 $CFLAGS"
329   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
330 void foo (int i, void *p)
331 {
332   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
333        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
334 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
335   CFLAGS="$old_CFLAGS"])
336   if test $libc_cv_sdt = yes; then
337     AC_DEFINE([USE_STAP_PROBE])
338   elif test "x$systemtap" != xauto; then
339     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
340   fi
341 fi
342
343 AC_ARG_ENABLE([build-nscd],
344               [AS_HELP_STRING([--disable-build-nscd],
345                [disable building and installing the nscd daemon])],
346               [build_nscd=$enableval],
347               [build_nscd=default])
348 AC_SUBST(build_nscd)
349
350 # Note the use of $use_nscd is near the bottom of the file.
351 AC_ARG_ENABLE([nscd],
352               [AS_HELP_STRING([--disable-nscd],
353                [library functions will not contact the nscd daemon])],
354               [use_nscd=$enableval],
355               [use_nscd=yes])
356
357 AC_ARG_ENABLE([pt_chown],
358               [AS_HELP_STRING([--enable-pt_chown],
359                [Enable building and installing pt_chown])],
360               [build_pt_chown=$enableval],
361               [build_pt_chown=no])
362 AC_SUBST(build_pt_chown)
363 if test "$build_pt_chown" = yes; then
364   AC_DEFINE(HAVE_PT_CHOWN)
365 fi
366
367 # The way shlib-versions is used to generate soversions.mk uses a
368 # fairly simplistic model for name recognition that can't distinguish
369 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
370 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
371 # tell.  This doesn't get used much beyond that, so it's fairly safe.
372 case "$host_os" in
373 linux*)
374   ;;
375 gnu*)
376   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
377   ;;
378 esac
379
380 # We keep the original values in `$config_*' and never modify them, so we
381 # can write them unchanged into config.make.  Everything else uses
382 # $machine, $vendor, and $os, and changes them whenever convenient.
383 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
384
385 # Don't allow vendor == "unknown"
386 test "$config_vendor" = unknown && config_vendor=
387 config_os="`echo $config_os | sed 's/^unknown-//'`"
388
389 # Some configurations imply other options.
390 elf=yes
391
392 # The configure fragment of an add-on port can modify these to supplement
393 # or override the table in the case statement below.  No fragment should
394 # ever change the config_* variables, however.
395 machine=$config_machine
396 vendor=$config_vendor
397 os=$config_os
398 base_os=''
399
400 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
401 # Unify this here.
402 if test "$machine" = rs6000; then
403   machine="powerpc"
404 fi
405
406 # Braindead PowerPC box with absolutely no FPU.
407 case "$machine-$host_os" in
408   powerpc*-*soft)
409     with_fp=no
410     ;;
411 esac
412
413 submachine=
414 AC_ARG_WITH([cpu],
415             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
416             [dnl
417   case "$withval" in
418   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
419   no) ;;
420   *) submachine="$withval" ;;
421   esac
422 ])
423
424 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
425 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
426
427 # An add-on can set this when it wants to disable the sanity check below.
428 libc_config_ok=no
429
430 dnl Having this here, though empty, makes sure that if add-ons' fragments
431 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
432 dnl our AC_OUTPUT will actually use it.
433 AC_CONFIG_SUBDIRS()
434
435 case "$enable_add_ons" in
436 ''|no) add_ons= ;;
437 yes|'*')
438  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
439           sed 's@/[[^/]]*$@@' | sort | uniq`
440          add_ons_automatic=yes
441          ;;
442 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
443        add_ons_automatic=no ;;
444 esac
445
446 configured_add_ons=
447 add_ons_sfx=
448 add_ons_pfx=
449 if test x"$add_ons" != x; then
450   for f in $add_ons; do
451     # Some sanity checks
452     case "$f" in
453     crypt)
454       AC_MSG_ERROR([
455 *** It seems that you're using an old \`crypt' add-on.  crypt is now
456 *** part of glibc and using the old add-on will not work with this
457 *** release.  Start again with fresh sources and without the old
458 *** \`crypt' add-on.])
459     ;;
460     localedata)
461       AC_MSG_ERROR([
462 *** It seems that you're using an old \`localedata' add-on.  localedata
463 *** is now part of glibc and using the old add-on will not work with
464 *** this release.  Start again with fresh sources and without the old
465 *** \`localedata' add-on.])
466     ;;
467     esac
468   done
469
470   # Now source each add-on's configure fragment.
471   # The fragments can use $srcdir/$libc_add_on to find themselves,
472   # and test $add_ons_automatic to see if they were explicitly requested.
473   # A fragment can clear (or even change) $libc_add_on to affect
474   # whether it goes into the list to be actually used in the build.
475   use_add_ons=
476   for libc_add_on in $add_ons; do
477     # Test whether such a directory really exists.
478     # It can be absolute, or relative to $srcdir, or relative to the build dir.
479     case "$libc_add_on" in
480     /*)
481       libc_add_on_srcdir=$libc_add_on
482       ;;
483     *)
484       test -d "$srcdir/$libc_add_on" || {
485         if test -d "$libc_add_on"; then
486           libc_add_on="`pwd`/$libc_add_on"
487         else
488           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
489         fi
490       }
491       libc_add_on_srcdir=$srcdir/$libc_add_on
492       ;;
493     esac
494
495     libc_add_on_frag=$libc_add_on_srcdir/configure
496     libc_add_on_canonical=
497     libc_add_on_config_subdirs=
498     if test -r "$libc_add_on_frag"; then
499       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
500       libc_add_on_canonical=unknown
501       libc_add_on_subdirs=
502       . "$libc_add_on_frag"
503       test -z "$libc_add_on" || {
504         configured_add_ons="$configured_add_ons $libc_add_on"
505         if test "x$libc_add_on_canonical" = xunknown; then
506           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
507         fi
508         for d in $libc_add_on_subdirs; do
509           case "$libc_add_on" in
510           /*) subdir_srcdir="$libc_add_on" ;;
511           *) subdir_srcdir="\$(..)$libc_add_on" ;;
512           esac
513           case "$d" in
514           .)
515             d="${libc_add_on_canonical:-$libc_add_on}"
516             ;;
517           /*)
518             subdir_srcdir="$d"
519             ;;
520           *)
521             subdir_srcdir="$subdir_srcdir/$d"
522             ;;
523           esac
524           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
525           add_on_subdirs="$add_on_subdirs $d"
526           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
527 $d-srcdir = $subdir_srcdir"
528         done
529         for d in $libc_add_on_config_subdirs; do
530           case "$d" in
531           /*) AC_MSG_ERROR(dnl
532 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
533           esac
534           if test ! -d "$libc_add_on_srcdir/$d"; then
535             AC_MSG_ERROR(fragment wants to configure missing directory $d)
536           fi
537           case "$libc_add_on" in
538           /*) AC_MSG_ERROR(dnl
539 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
540           esac
541           subdirs="$subdirs $libc_add_on/$d"
542         done
543       }
544     fi
545     if test -n "$libc_add_on"; then
546       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
547       use_add_ons="$use_add_ons $libc_add_on"
548       add_ons_pfx="$add_ons_pfx $libc_add_on/"
549       test -z "$libc_add_on_canonical" ||
550       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
551     fi
552   done
553   # Use echo to strip excess whitespace.
554   add_ons="`echo $use_add_ons`"
555 fi
556 AC_SUBST(add_ons)
557 AC_SUBST(add_on_subdirs)
558
559
560 ###
561 ### I put this here to prevent those annoying emails from people who cannot
562 ### read and try to compile glibc on unsupported platforms.  --drepper
563 ###
564 ### By using the undocumented --enable-hacker-mode option for configure
565 ### one can skip this test to make the configuration not fail for unsupported
566 ### platforms.
567 ###
568 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
569   case "$machine-$host_os" in
570   *-linux* | *-gnu*)
571     ;;
572   *)
573     echo "*** The GNU C library is currently not available for this platform."
574     echo "*** So far nobody cared to port it and if there is no volunteer it"
575     echo "*** might never happen.  So, if you have interest to see glibc on"
576     echo "*** this platform visit"
577     echo "***   http://www.gnu.org/software/libc/porting.html"
578     echo "*** and join the group of porters"
579     exit 1
580     ;;
581   esac
582 fi
583
584 dnl We need to use [ and ] for other purposes for a while now.
585 changequote(,)dnl
586 # Expand the configuration machine name into a subdirectory by architecture
587 # type and particular chip.  If an add-on configure fragment already set
588 # base_machine, we don't change it.
589 test -n "$base_machine" || case "$machine" in
590 i[4567]86)      base_machine=i386 machine=i386/$machine ;;
591 powerpc64*)     base_machine=powerpc machine=powerpc/powerpc64 ;;
592 powerpc*)       base_machine=powerpc machine=powerpc/powerpc32 ;;
593 s390)           base_machine=s390 machine=s390/s390-32 ;;
594 s390x)          base_machine=s390 machine=s390/s390-64 ;;
595 sh3*)           base_machine=sh machine=sh/sh3 ;;
596 sh4*)           base_machine=sh machine=sh/sh4 ;;
597 sparc | sparcv[67])
598                 base_machine=sparc machine=sparc/sparc32 ;;
599 sparcv8 | supersparc | hypersparc)
600                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
601 sparcv8plus | sparcv8plusa | sparcv9)
602                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
603 sparcv8plusb | sparcv9b)
604                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
605 sparcv9v)
606                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
607 sparcv9v2)
608                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
609 sparc64)
610                 base_machine=sparc machine=sparc/sparc64 ;;
611 sparc64b)
612                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
613 sparc64v)
614                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
615 sparc64v2)
616                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
617 *)              base_machine=$machine ;;
618 esac
619 changequote([,])dnl
620 AC_SUBST(base_machine)
621
622 if test "$base_machine" = "i386"; then
623   AC_DEFINE(USE_REGPARMS)
624 fi
625
626 # For the multi-arch option we need support in the assembler & linker.
627 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
628                libc_cv_ld_gnu_indirect_function, [dnl
629 cat > conftest.S <<EOF
630 .type foo,%gnu_indirect_function
631 foo:
632 .globl _start
633 _start:
634 .globl __start
635 __start:
636 .data
637 #ifdef _LP64
638 .quad foo
639 #else
640 .long foo
641 #endif
642 EOF
643 libc_cv_ld_gnu_indirect_function=no
644 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
645             -nostartfiles -nostdlib \
646             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
647   # Do a link to see if the backend supports IFUNC relocs.
648   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
649   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
650     libc_cv_ld_gnu_indirect_function=yes
651   }
652 fi
653 rm -f conftest*])
654
655 AC_MSG_CHECKING(whether .text pseudo-op must be used)
656 AC_CACHE_VAL(libc_cv_dot_text, [dnl
657 cat > conftest.s <<EOF
658 .text
659 EOF
660 libc_cv_dot_text=
661 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
662   libc_cv_dot_text=.text
663 fi
664 rm -f conftest*])
665 if test -z "$libc_cv_dot_text"; then
666   AC_MSG_RESULT(no)
667 else
668   AC_MSG_RESULT(yes)
669 fi
670
671 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
672   if test x"$multi_arch" = xyes; then
673     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
674   else
675     multi_arch=no
676   fi
677 fi
678 multi_arch_d=
679 if test x"$multi_arch" != xno; then
680   multi_arch_d=/multiarch
681 fi
682
683 # Compute the list of sysdep directories for this configuration.
684 # This can take a while to compute.
685 sysdep_dir=$srcdir/sysdeps
686 AC_MSG_CHECKING(sysdep dirs)
687 dnl We need to use [ and ] for other purposes for a while now.
688 changequote(,)dnl
689 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
690 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
691
692 test "x$base_os" != x || case "$os" in
693 gnu*)
694   base_os=mach/hurd ;;
695 linux*)
696   base_os=unix/sysv ;;
697 esac
698
699 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
700 tail=$os
701 ostry=$os
702 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
703   ostry="$ostry /$o"
704   tail=$o
705 done
706 o=`echo $tail | sed 's/[0-9]*$//'`
707 if test $o != $tail; then
708   ostry="$ostry /$o"
709 fi
710 # For linux-gnu, try linux-gnu, then linux.
711 o=`echo $tail | sed 's/-.*$//'`
712 if test $o != $tail; then
713   ostry="$ostry /$o"
714 fi
715
716 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
717 base=
718 tail=$base_os
719 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
720   set $b
721   base="$base /$1"
722   tail="$2"
723 done
724
725 # For akaros, we don't have a base OS, which messes things up. Change this for
726 # the purpose of sysdeps detection.
727 test "x$base_os" != x || case "$os" in
728 akaros*)
729   base=/akaros
730   vendor=
731   ostry=
732   ;;
733 esac
734
735 # For sparc/sparc32, try sparc/sparc32 and then sparc.
736 mach=
737 tail=$machine${submachine:+/$submachine}
738 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
739   set $m
740   # Prepend the machine's FPU directory unless --without-fp.
741   if test "$with_fp" = yes; then
742     maybe_fpu=/fpu
743   else
744     maybe_fpu=/nofpu
745   fi
746   # For each machine term, try it with and then without /multiarch.
747   for try_fpu in $maybe_fpu ''; do
748     for try_multi in $multi_arch_d ''; do
749       mach="$mach /$1$try_fpu$try_multi"
750     done
751   done
752   tail="$2"
753 done
754
755 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
756 changequote([,])dnl
757
758 # Find what sysdep directories exist.
759 sysnames_add_ons=
760 sysnames=
761 for b in $base ''; do
762   for m0 in $mach ''; do
763     for v in /$vendor ''; do
764       test "$v" = / && continue
765       for o in /$ostry ''; do
766         test "$o" = / && continue
767         for m in $mach ''; do
768           for d in $add_ons_pfx ''; do
769             for a in $add_ons_sfx ''; do
770               try_suffix="$m0$b$v$o$m"
771               if test -n "$try_suffix"; then
772                 try_srcdir="${srcdir}/"
773                 case "$d" in
774                 /*) try_srcdir= ;;
775                 esac
776                 try="${d}sysdeps$try_suffix$a"
777                 test -n "$enable_debug_configure" &&
778                 echo "$0 [DEBUG]: try $try" >&2
779                 if test -d "$try_srcdir$try"; then
780                   sysnames="$sysnames $try"
781                   { test -n "$o" || test -n "$b"; } && os_used=t
782                   { test -n "$m" || test -n "$m0"; } && machine_used=t
783                   case x${m0:-$m} in
784                   x*/$submachine) submachine_used=t ;;
785                   esac
786                   if test -n "$d"; then
787                     case "$sysnames_add_ons" in
788                     *" $d "*) ;;
789                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
790                     esac
791                   fi
792                 fi
793               fi
794             done
795           done
796         done
797       done
798     done
799   done
800 done
801
802 # If the assembler supports gnu_indirect_function symbol type and the
803 # architecture supports multi-arch, we enable multi-arch by default.
804 case $sysnames_add_ons$sysnames in
805 *"$multi_arch_d"*)
806   ;;
807 *)
808   test x"$multi_arch" = xdefault && multi_arch=no
809   ;;
810 esac
811 if test x"$multi_arch" != xno; then
812   AC_DEFINE(USE_MULTIARCH)
813 fi
814 AC_SUBST(multi_arch)
815
816 if test -z "$os_used" && test "$os" != none; then
817   AC_MSG_ERROR(Operating system $os is not supported.)
818 fi
819 if test -z "$machine_used" && test "$machine" != none; then
820   AC_MSG_ERROR(The $machine is not supported.)
821 fi
822 if test -z "$submachine_used" && test -n "$submachine"; then
823   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
824 fi
825 AC_SUBST(submachine)
826
827 # We have now validated the configuration.
828
829 # Expand the list of system names into a full list of directories
830 # from each element's parent name and Implies file (if present).
831 set $sysnames
832 names=
833 while test $# -gt 0; do
834   name=$1
835   shift
836
837   case " $names " in *" $name "*)
838     # Already in the list.
839     continue
840   esac
841
842   # Report each name as we discover it, so there is no long pause in output.
843   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
844
845   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
846
847   case $name in
848     /*) xsrcdir= ;;
849     *)  xsrcdir=$srcdir/ ;;
850   esac
851   test -n "$enable_debug_configure" &&
852   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
853
854   for implies_file in Implies Implies-before Implies-after; do
855     implies_type=`echo $implies_file | sed s/-/_/`
856     eval ${implies_type}=
857     if test -f $xsrcdir$name/$implies_file; then
858       # Collect more names from the `Implies' file (removing comments).
859       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
860       for x in $implied_candidate; do
861         found=no
862         if test -d $xsrcdir$name_base/$x; then
863           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
864           found=yes
865         fi
866         for d in $add_ons_pfx ''; do
867           try="${d}sysdeps/$x"
868           case $d in
869            /*) try_srcdir= ;;
870            *) try_srcdir=$srcdir/ ;;
871           esac
872           test -n "$enable_debug_configure" &&
873            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
874           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
875           then
876             eval "${implies_type}=\"\$${implies_type} \$try\""
877             found=yes
878             case "$sysnames_add_ons" in
879             *" $d "*) ;;
880             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
881             esac
882           fi
883         done
884         if test $found = no; then
885           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
886         fi
887       done
888     fi
889   done
890
891   # Add NAME to the list of names.
892   names="$names $name"
893
894   # Find the parent of NAME, using the empty string if it has none.
895 changequote(,)dnl
896   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
897 changequote([,])dnl
898
899   test -n "$enable_debug_configure" &&
900     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
901 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
902
903   # Add the names implied by NAME, and NAME's parent (if it has one), to
904   # the list of names to be processed (the argument list).  We prepend the
905   # implied names to the list and append the parent.  We want implied
906   # directories to come before further directories inferred from the
907   # configuration components; this ensures that for sysv4, unix/common
908   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
909   # after sysv4).
910   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
911   test -n "$sysnames" && set $sysnames
912 done
913
914 # Add the default directories.
915 default_sysnames="sysdeps/generic"
916 sysnames="$names $default_sysnames"
917 AC_SUBST(sysnames)
918 # The other names were emitted during the scan.
919 AC_MSG_RESULT($default_sysnames)
920
921 # Collect the list of add-ons that supply partial sysdeps trees.
922 sysdeps_add_ons=
923 for add_on in $add_ons; do
924   case "$add_on" in
925   /*) xsrcdir= ;;
926   *) xsrcdir="$srcdir/" ;;
927   esac
928
929   test -d "$xsrcdir$add_on/sysdeps" || {
930     case "$configured_add_ons " in
931     *" $add_on "*) ;;
932     *|'')
933       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
934       ;;
935     esac
936     continue
937   }
938
939   sysdeps_add_ons="$sysdeps_add_ons $add_on"
940   case "$sysnames_add_ons" in
941   *" $add_on/ "*) ;;
942   *|'')
943     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
944     continue ;;
945   esac
946
947   found=no
948   for d in $sysnames; do
949     case "$d" in
950     $add_on/sysdeps/*) ;;
951     *) continue ;;
952     esac
953     (cd "$xsrcdir$d" && for f in *[[!~]]; do
954        case "$f" in
955        sys|bits)
956          for ff in $f/*.h; do
957            test -d "$ff" || { test -e "$ff" && exit 88; }
958          done
959          ;;
960        *)
961          test -d "$f" || { test -e "$f" && exit 88; }
962          ;;
963        esac
964      done)
965     if test $? -eq 88; then
966       found=yes
967       break
968     fi
969   done
970   if test $found = no; then
971     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
972   fi
973 done
974 AC_SUBST(sysdeps_add_ons)
975
976
977 ### Locate tools.
978
979 AC_PROG_INSTALL
980 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
981   # The makefiles need to use a different form to find it in $srcdir.
982   INSTALL='\$(..)./scripts/install-sh -c'
983 fi
984 AC_PROG_LN_S
985
986 LIBC_PROG_BINUTILS
987
988 # Accept binutils 2.20 or newer.
989 AC_CHECK_PROG_VER(AS, $AS, --version,
990                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
991                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
992 AC_CHECK_PROG_VER(LD, $LD, --version,
993                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
994                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
995
996 # These programs are version sensitive.
997 AC_CHECK_TOOL_PREFIX
998 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
999   [version \([egcygnustpi-]*[0-9.]*\)], [4.[4-9].* | 4.[1-9][0-9].* | [5-9].* ],
1000   critic_missing="$critic_missing gcc")
1001 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1002   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1003   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1004
1005 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1006   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1007   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1008   MSGFMT=: aux_missing="$aux_missing msgfmt")
1009 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1010   [GNU texinfo.* \([0-9][0-9.]*\)],
1011   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
1012   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1013 AC_CHECK_PROG_VER(SED, sed, --version,
1014   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1015   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1016   SED=: aux_missing="$aux_missing sed")
1017 AC_CHECK_PROG_VER(AWK, gawk, --version,
1018   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1019   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1020
1021 AC_CHECK_TOOL(NM, nm, false)
1022
1023 if test "x$maintainer" = "xyes"; then
1024   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1025   case "x$AUTOCONF" in
1026   xno|x|x:) AUTOCONF=no ;;
1027   *)
1028     AC_CACHE_CHECK(dnl
1029   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1030     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1031       libc_cv_autoconf_works=yes
1032     else
1033       libc_cv_autoconf_works=no
1034     fi])
1035     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1036     ;;
1037   esac
1038   if test "x$AUTOCONF" = xno; then
1039     aux_missing="$aux_missing autoconf"
1040   fi
1041 else
1042   AUTOCONF=no
1043 fi
1044
1045 test -n "$critic_missing" && AC_MSG_ERROR([
1046 *** These critical programs are missing or too old:$critic_missing
1047 *** Check the INSTALL file for required versions.])
1048
1049 test -n "$aux_missing" && AC_MSG_WARN([
1050 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1051 *** some features will be disabled.
1052 *** Check the INSTALL file for required versions.])
1053
1054 # if using special system headers, find out the compiler's sekrit
1055 # header directory and add that to the list.  NOTE: Only does the right
1056 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1057 if test -n "$sysheaders"; then
1058   SYSINCLUDES=-nostdinc
1059   for d in include include-fixed; do
1060     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1061     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1062   done
1063   SYSINCLUDES="$SYSINCLUDES \
1064 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1065   if test -n "$CXX"; then
1066     CXX_SYSINCLUDES=
1067     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1068     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1069       test "x$cxxheaders" != x &&
1070       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1071     done
1072   fi
1073 fi
1074 AC_SUBST(SYSINCLUDES)
1075 AC_SUBST(CXX_SYSINCLUDES)
1076
1077 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1078 # since this would lead to problems installing/building glibc.
1079 # LD_LIBRARY_PATH contains the current directory if one of the following
1080 # is true:
1081 # - one of the terminals (":" and ";") is the first or last sign
1082 # - two terminals occur directly after each other
1083 # - the path contains an element with a dot in it
1084 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1085 changequote(,)dnl
1086 case ${LD_LIBRARY_PATH} in
1087   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1088     ld_library_path_setting="contains current directory"
1089     ;;
1090   *)
1091     ld_library_path_setting="ok"
1092     ;;
1093 esac
1094 changequote([,])dnl
1095 AC_MSG_RESULT($ld_library_path_setting)
1096 if test "$ld_library_path_setting" != "ok"; then
1097 AC_MSG_ERROR([
1098 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1099 *** building glibc. Please change the environment variable
1100 *** and run configure again.])
1101 fi
1102
1103 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1104 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1105   libc_cv_gcc_static_libgcc=
1106 else
1107   libc_cv_gcc_static_libgcc=-static-libgcc
1108 fi])
1109 AC_SUBST(libc_cv_gcc_static_libgcc)
1110
1111 AC_PATH_PROG(BASH_SHELL, bash, no)
1112 if test "$BASH_SHELL" != no &&
1113    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1114              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1115   libc_cv_have_bash2=yes
1116 else
1117   libc_cv_have_bash2=no
1118 fi
1119 AC_SUBST(libc_cv_have_bash2)
1120
1121 dnl We need a ksh compatible shell for tzselect.
1122 if test "$BASH_SHELL" = no; then
1123   AC_PATH_PROG(KSH, ksh, no)
1124   if test "$KSH" = no; then
1125     libc_cv_have_ksh=no
1126   else
1127     libc_cv_have_ksh=yes
1128   fi
1129 else
1130   KSH="$BASH_SHELL"
1131   AC_SUBST(KSH)
1132   libc_cv_have_ksh=yes
1133 fi
1134 AC_SUBST(libc_cv_have_ksh)
1135
1136 AC_PATH_PROG(PERL, perl, no)
1137 if test "$PERL" != no &&
1138    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1139   PERL=no
1140 fi
1141 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1142              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1143 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1144
1145 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1146 AC_TRY_COMPILE(dnl
1147 [#define __need_size_t
1148 #define __need_wchar_t
1149 #include <stddef.h>
1150 #define __need_NULL
1151 #include <stddef.h>], [size_t size; wchar_t wchar;
1152 #ifdef offsetof
1153 #error stddef.h ignored __need_*
1154 #endif
1155 if (&size == NULL || &wchar == NULL) abort ();],
1156                libc_cv_friendly_stddef=yes,
1157                libc_cv_friendly_stddef=no)])
1158 if test $libc_cv_friendly_stddef = yes; then
1159   config_vars="$config_vars
1160 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1161 fi
1162
1163 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1164                libc_cv_need_minus_P, [dnl
1165 cat > conftest.S <<EOF
1166 #include "confdefs.h"
1167 /* Nothing whatsoever.  */
1168 EOF
1169 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1170   libc_cv_need_minus_P=no
1171 else
1172   libc_cv_need_minus_P=yes
1173 fi
1174 rm -f conftest*])
1175 if test $libc_cv_need_minus_P = yes; then
1176   config_vars="$config_vars
1177 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1178 fi
1179
1180 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1181 cat > conftest.s <<EOF
1182 ${libc_cv_dot_text}
1183 foo:
1184 .set glibc_conftest_frobozz,foo
1185 .globl glibc_conftest_frobozz
1186 EOF
1187 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1188 # (but it doesn't work), so we must do a linking check to be sure.
1189 cat > conftest1.c <<\EOF
1190 extern int glibc_conftest_frobozz;
1191 void _start() { glibc_conftest_frobozz = 1; }
1192 EOF
1193 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1194             -nostartfiles -nostdlib \
1195             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1196   libc_cv_asm_set_directive=yes
1197 else
1198   libc_cv_asm_set_directive=no
1199 fi
1200 rm -f conftest*])
1201 if test $libc_cv_asm_set_directive = yes; then
1202   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1203 fi
1204
1205 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1206                libc_cv_asm_unique_object, [dnl
1207 cat > conftest.s <<EOF
1208 ${libc_cv_dot_text}
1209 _sym:
1210 .type _sym, %gnu_unique_object
1211 EOF
1212 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1213   libc_cv_asm_unique_object=yes
1214 else
1215   libc_cv_asm_unique_object=no
1216 fi
1217 rm -f conftest*])
1218 if test $libc_cv_asm_unique_object = yes; then
1219   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1220 fi
1221
1222 AC_CACHE_CHECK(for .previous assembler directive,
1223                libc_cv_asm_previous_directive, [dnl
1224 cat > conftest.s <<EOF
1225 .section foo_section
1226 .previous
1227 EOF
1228 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1229   libc_cv_asm_previous_directive=yes
1230 else
1231   libc_cv_asm_previous_directive=no
1232 fi
1233 rm -f conftest*])
1234 if test $libc_cv_asm_previous_directive = yes; then
1235   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1236 else
1237   AC_CACHE_CHECK(for .popsection assembler directive,
1238                  libc_cv_asm_popsection_directive, [dnl
1239   cat > conftest.s <<EOF
1240 .pushsection foo_section
1241 .popsection
1242 EOF
1243   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1244     libc_cv_asm_popsection_directive=yes
1245   else
1246     libc_cv_asm_popsection_directive=no
1247   fi
1248   rm -f conftest*])
1249   if test $libc_cv_asm_popsection_directive = yes; then
1250     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1251   fi
1252 fi
1253 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1254                libc_cv_asm_protected_directive, [dnl
1255 cat > conftest.s <<EOF
1256 .protected foo
1257 foo:
1258 .hidden bar
1259 bar:
1260 EOF
1261 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1262   libc_cv_asm_protected_directive=yes
1263 else
1264   AC_MSG_ERROR(assembler support for symbol visibility is required)
1265 fi
1266 rm -f conftest*])
1267
1268 if test $libc_cv_asm_protected_directive = yes; then
1269   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1270                  libc_cv_visibility_attribute,
1271                  [cat > conftest.c <<EOF
1272                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1273                   int bar __attribute__ ((visibility ("protected"))) = 1;
1274 EOF
1275                   libc_cv_visibility_attribute=no
1276                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1277                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1278                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1279                         libc_cv_visibility_attribute=yes
1280                       fi
1281                     fi
1282                   fi
1283                   rm -f conftest.{c,s}
1284                  ])
1285   if test $libc_cv_visibility_attribute != yes; then
1286     AC_MSG_ERROR(compiler support for visibility attribute is required)
1287   fi
1288 fi
1289
1290 if test $libc_cv_visibility_attribute = yes; then
1291   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1292                  libc_cv_broken_visibility_attribute,
1293                  [cat > conftest.c <<EOF
1294                   int foo (int x);
1295                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1296                   int bar (int x) { return x; }
1297 EOF
1298                   libc_cv_broken_visibility_attribute=yes
1299                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1300 changequote(,)dnl
1301                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1302 changequote([,])dnl
1303                       libc_cv_broken_visibility_attribute=no
1304                     fi
1305                   fi
1306                   rm -f conftest.c conftest.s
1307                  ])
1308   if test $libc_cv_broken_visibility_attribute = yes; then
1309     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1310   fi
1311 fi
1312
1313 AC_CACHE_CHECK(for broken __attribute__((alias())),
1314                libc_cv_broken_alias_attribute,
1315                [cat > conftest.c <<EOF
1316                extern int foo (int x) __asm ("xyzzy");
1317                int bar (int x) { return x; }
1318                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1319                extern int dfoo;
1320                extern __typeof (dfoo) dfoo __asm ("abccb");
1321                int dfoo = 1;
1322 EOF
1323                libc_cv_broken_alias_attribute=yes
1324                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1325                  if grep 'xyzzy' conftest.s >/dev/null &&
1326                     grep 'abccb' conftest.s >/dev/null; then
1327                    libc_cv_broken_alias_attribute=no
1328                  fi
1329                fi
1330                rm -f conftest.c conftest.s
1331                ])
1332 if test $libc_cv_broken_alias_attribute = yes; then
1333   AC_MSG_ERROR(working alias attribute support required)
1334 fi
1335
1336 if test $libc_cv_visibility_attribute = yes; then
1337   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1338                  libc_cv_have_sdata_section,
1339                  [echo "int i;" > conftest.c
1340                   libc_cv_have_sdata_section=no
1341                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1342                      | grep '\.sdata' >/dev/null; then
1343                     libc_cv_have_sdata_section=yes
1344                   fi
1345                   rm -f conftest.c conftest.so
1346                  ])
1347   if test $libc_cv_have_sdata_section = yes; then
1348     AC_DEFINE(HAVE_SDATA_SECTION)
1349   fi
1350 fi
1351
1352 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1353                libc_cv_initfini_array, [dnl
1354 LIBC_TRY_LINK_STATIC([
1355 int foo (void) { return 1; }
1356 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1357 ],
1358   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1359     libc_cv_initfini_array=yes
1360   else
1361     libc_cv_initfini_array=no
1362   fi],
1363   [libc_cv_initfini_array=no])
1364 ])
1365 if test $libc_cv_initfini_array != yes; then
1366   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1367 fi
1368
1369 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1370                libc_cv_ctors_header, [dnl
1371   libc_cv_ctors_header=yes
1372   LIBC_TRY_LINK_STATIC([
1373 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1374 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1375 ],
1376               [dnl
1377       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1378         { gsub(/\@<:@ */, "@<:@") }
1379         $2 == ".ctors" || $2 == ".dtors" {
1380           size = strtonum("0x" $6)
1381           align = strtonum("0x" $NF)
1382           seen@<:@$2@:>@ = 1
1383           stub@<:@$2@:>@ = size == align * 2
1384         }
1385         END {
1386           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1387           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1388           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1389         }
1390       '], [libc_cv_ctors_header=no])
1391     ], [dnl
1392       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1393     ])
1394 ])
1395 if test $libc_cv_ctors_header = no; then
1396   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1397 fi
1398
1399 AC_CACHE_CHECK(for libunwind-support in compiler,
1400                libc_cv_cc_with_libunwind, [
1401   cat > conftest.c <<EOF
1402 int main (void) { return 0; }
1403 EOF
1404   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1405      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1406     libc_cv_cc_with_libunwind=yes
1407   else
1408     libc_cv_cc_with_libunwind=no
1409   fi
1410   rm -f conftest*])
1411 AC_SUBST(libc_cv_cc_with_libunwind)
1412 if test $libc_cv_cc_with_libunwind = yes; then
1413   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1414 fi
1415
1416 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1417                     [libc_cv_z_nodelete=yes],
1418                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1419
1420 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1421                     [libc_cv_z_nodlopen=yes],
1422                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1423
1424 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1425                     [libc_cv_z_initfirst=yes],
1426                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1427
1428 # Add-on fragments can set these for other machines.
1429 libc_commonpagesize=${libc_commonpagesize:-no}
1430 libc_relro_required=${libc_relro_required:-no}
1431 case "$base_machine" in
1432   i[[34567]]86 | x86_64 | powerpc* | s390*)
1433     libc_commonpagesize=0x1000
1434     libc_relro_required=yes
1435     ;;
1436   sparc*)
1437     libc_commonpagesize=0x2000
1438     libc_relro_required=yes
1439     ;;
1440 esac
1441
1442 if test $libc_commonpagesize != no; then
1443   AC_CACHE_CHECK(for -z relro option,
1444                  libc_cv_z_relro, [dnl
1445   libc_cv_z_relro=no
1446   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1447 int _start (void) { return 42; }
1448 extern void _exit (int);
1449 /* Since these pointers are const, they should go in rodata.
1450    Since they refer to functions that have to be resolved by
1451    dynamic linking, they should instead go in RELRO data.  */
1452 const void *const relro[] = { &_start, &_exit, 0 };
1453 /* GNU ld fails to produce RELRO data when it's very small and there is no
1454    normal writable data following it, or if only uninitialized (.bss) data
1455    follows it, or only very small writable data.  */
1456 int data[0x10000] = { 1, };
1457 ]])])
1458   cat > conftest.awk <<\EOF
1459 BEGIN {
1460   result = "no"
1461   commonpagesize = strtonum(commonpagesize)
1462 }
1463 { print "LINE:", $0 > "/dev/stderr" }
1464 $1 == "GNU_RELRO" {
1465   vaddr = strtonum($3)
1466   memsz = strtonum($6)
1467   end = vaddr + memsz
1468   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1469     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1470   result = (end % commonpagesize == 0) ? "yes" : "broken"
1471 }
1472 END { print result }
1473 EOF
1474   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1475                     -fPIC -shared -o conftest.so conftest.c
1476                     -nostartfiles -nostdlib
1477                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1478   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1479   AC_TRY_COMMAND([
1480       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1481            conftest.ph > conftest.cps
1482     ]) &&
1483   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1484   rm -f conftest*])
1485   if { test "x$libc_relro_required" = xyes &&
1486        test "x$libc_cv_z_relro" != xyes
1487      }
1488   then
1489     AC_MSG_ERROR(linker with -z relro support required)
1490   fi
1491 else
1492   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1493 fi
1494
1495 AC_CACHE_CHECK(for -Bgroup option,
1496                libc_cv_Bgroup, [dnl
1497 cat > conftest.c <<EOF
1498 int _start (void) { return 42; }
1499 EOF
1500 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1501                             -fPIC -shared -o conftest.so conftest.c
1502                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1503 then
1504   libc_cv_Bgroup=yes
1505 else
1506   libc_cv_Bgroup=no
1507 fi
1508 rm -f conftest*])
1509 AC_SUBST(libc_cv_Bgroup)
1510
1511 ASFLAGS_config=
1512 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1513                libc_cv_as_noexecstack, [dnl
1514 cat > conftest.c <<EOF
1515 void foo (void) { }
1516 EOF
1517 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1518                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1519    && grep .note.GNU-stack conftest.s >/dev/null \
1520    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1521                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1522 then
1523   libc_cv_as_noexecstack=yes
1524 else
1525   libc_cv_as_noexecstack=no
1526 fi
1527 rm -f conftest*])
1528 if test $libc_cv_as_noexecstack = yes; then
1529   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1530 fi
1531 AC_SUBST(ASFLAGS_config)
1532
1533 AC_CACHE_CHECK(for -z combreloc,
1534                libc_cv_z_combreloc, [dnl
1535 cat > conftest.c <<EOF
1536 extern int bar (int);
1537 extern int mumble;
1538 int foo (void) { return bar (mumble); }
1539 EOF
1540 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1541                         -fPIC -shared -o conftest.so conftest.c
1542                         -nostdlib -nostartfiles
1543                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1544 then
1545 dnl The following test is a bit weak.  We must use a tool which can test
1546 dnl cross-platform since the gcc used can be a cross compiler.  Without
1547 dnl introducing new options this is not easily doable.  Instead use a tool
1548 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1549 dnl look for a section named .rel.dyn.
1550   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1551     libc_cv_z_combreloc=yes
1552   else
1553     libc_cv_z_combreloc=no
1554   fi
1555 else
1556   libc_cv_z_combreloc=no
1557 fi
1558 rm -f conftest*])
1559 if test "$libc_cv_z_combreloc" = yes; then
1560   AC_DEFINE(HAVE_Z_COMBRELOC)
1561 fi
1562 AC_SUBST(libc_cv_z_combreloc)
1563
1564 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1565                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1566 AC_SUBST(libc_cv_z_execstack)
1567
1568 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1569 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1570 ])
1571
1572 AC_SUBST(libc_cv_fpie)
1573
1574 AC_CACHE_CHECK(for --hash-style option,
1575                libc_cv_hashstyle, [dnl
1576 cat > conftest.c <<EOF
1577 int _start (void) { return 42; }
1578 EOF
1579 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1580                             -fPIC -shared -o conftest.so conftest.c
1581                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1582 then
1583   libc_cv_hashstyle=yes
1584 else
1585   libc_cv_hashstyle=no
1586 fi
1587 rm -f conftest*])
1588 AC_SUBST(libc_cv_hashstyle)
1589
1590 # The linker's default -shared behavior is good enough if it
1591 # does these things that our custom linker scripts ensure that
1592 # all allocated NOTE sections come first.
1593 if test "$use_default_link" = default; then
1594   AC_CACHE_CHECK([for sufficient default -shared layout],
1595                   libc_cv_use_default_link, [dnl
1596   libc_cv_use_default_link=no
1597   cat > conftest.s <<\EOF
1598           .section .note.a,"a",%note
1599           .balign 4
1600           .long 4,4,9
1601           .string "GNU"
1602           .string "foo"
1603           .section .note.b,"a",%note
1604           .balign 4
1605           .long 4,4,9
1606           .string "GNU"
1607           .string "bar"
1608 EOF
1609   if AC_TRY_COMMAND([dnl
1610   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1611        ac_try=`$READELF -S conftest.so | sed -n \
1612          ['${x;p;}
1613           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1614           t a
1615           b
1616           : a
1617           H']`
1618   then
1619     libc_seen_a=no libc_seen_b=no
1620     set -- $ac_try
1621     while test $# -ge 2 -a "$1" = NOTE; do
1622       case "$2" in
1623       .note.a) libc_seen_a=yes ;;
1624       .note.b) libc_seen_b=yes ;;
1625       esac
1626       shift 2
1627     done
1628     case "$libc_seen_a$libc_seen_b" in
1629     yesyes)
1630       libc_cv_use_default_link=yes
1631       ;;
1632     *)
1633       echo >&AS_MESSAGE_LOG_FD "\
1634 $libc_seen_a$libc_seen_b from:
1635 $ac_try"
1636       ;;
1637     esac
1638   fi
1639   rm -f conftest*])
1640   use_default_link=$libc_cv_use_default_link
1641 fi
1642
1643 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1644 if libc_cv_output_format=`
1645 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1646 then
1647   :
1648 else
1649   libc_cv_output_format=
1650 fi
1651 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1652 AC_SUBST(libc_cv_output_format)
1653
1654 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1655 cat > conftest.c <<EOF
1656 int foo;
1657 EOF
1658 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1659                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1660 then
1661   libc_cv_fno_toplevel_reorder=yes
1662 else
1663   libc_cv_fno_toplevel_reorder=no
1664 fi
1665 rm -f conftest*])
1666 if test $libc_cv_fno_toplevel_reorder = yes; then
1667   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1668 else
1669   fno_unit_at_a_time=-fno-unit-at-a-time
1670 fi
1671 AC_SUBST(fno_unit_at_a_time)
1672
1673 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1674 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1675                    [libc_cv_ssp=yes],
1676                    [libc_cv_ssp=no])
1677 ])
1678 AC_SUBST(libc_cv_ssp)
1679
1680 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1681 cat > conftest.c <<EOF
1682 int foo;
1683 #ifdef __GNUC_GNU_INLINE__
1684 main () { return 0;}
1685 #else
1686 #error
1687 #endif
1688 EOF
1689 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1690                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1691 then
1692   libc_cv_gnu89_inline=yes
1693 else
1694   libc_cv_gnu89_inline=no
1695 fi
1696 rm -f conftest*])
1697 if test $libc_cv_gnu89_inline = yes; then
1698   gnu89_inline=-fgnu89-inline
1699 else
1700   gnu89_inline=
1701 fi
1702 AC_SUBST(gnu89_inline)
1703
1704 AC_CACHE_CHECK(whether cc puts quotes around section names,
1705                libc_cv_have_section_quotes,
1706                [cat > conftest.c <<EOF
1707                 static const int foo
1708                 __attribute__ ((section ("bar"))) = 1;
1709 EOF
1710                 if ${CC-cc} -S conftest.c -o conftest.s; then
1711                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1712                     libc_cv_have_section_quotes=yes
1713                   else
1714                     libc_cv_have_section_quotes=no
1715                   fi
1716                 else
1717                   libc_cv_have_section_quotes=unknown
1718                 fi
1719                 rm -f conftest.{c,s}
1720                 ])
1721 if test $libc_cv_have_section_quotes = yes; then
1722   AC_DEFINE(HAVE_SECTION_QUOTES)
1723 fi
1724
1725 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1726                [dnl
1727 cat > conftest.s <<EOF
1728 ${libc_cv_dot_text}
1729 .globl foo
1730 foo:
1731 .weak foo
1732 .weak bar; bar = foo
1733 EOF
1734 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1735   libc_cv_asm_weak_directive=yes
1736 else
1737   libc_cv_asm_weak_directive=no
1738 fi
1739 rm -f conftest*])
1740
1741 if test $libc_cv_asm_weak_directive = no; then
1742   AC_CACHE_CHECK(for assembler .weakext directive,
1743                  libc_cv_asm_weakext_directive,
1744                  [dnl
1745 cat > conftest.s <<EOF
1746 ${libc_cv_dot_text}
1747 .globl foo
1748 foo:
1749 .weakext bar foo
1750 .weakext baz
1751 .globl baz
1752 baz:
1753 EOF
1754   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1755     libc_cv_asm_weakext_directive=yes
1756   else
1757     libc_cv_asm_weakext_directive=no
1758   fi
1759   rm -f conftest*])
1760
1761 fi # no .weak
1762
1763 if test $libc_cv_asm_weak_directive = yes; then
1764   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1765 elif test $libc_cv_asm_weakext_directive = yes; then
1766   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1767 fi
1768
1769 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1770 case $machine in
1771   sparc/sparc64*) cfi_offset=2047;;
1772   *) cfi_offset=0;;
1773 esac
1774 cat > conftest.s <<EOF
1775         .text
1776         .type   func,%function
1777 func:
1778         .cfi_startproc
1779         .cfi_remember_state
1780         .cfi_rel_offset 1, $cfi_offset
1781         .cfi_endproc
1782 EOF
1783 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1784   libc_cv_asm_cfi_directives=yes
1785 else
1786   libc_cv_asm_cfi_directives=no
1787 fi
1788 rm -f conftest*])
1789 if test $libc_cv_asm_cfi_directives = yes; then
1790   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1791 fi
1792
1793 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1794 cat > conftest.c <<\EOF
1795 _start () {}
1796 int __eh_pc;
1797 __throw () {}
1798 EOF
1799 dnl No \ in command here because it ends up inside ''.
1800 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1801                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1802                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1803   libc_cv_ld_no_whole_archive=yes
1804 else
1805   libc_cv_ld_no_whole_archive=no
1806 fi
1807 rm -f conftest*])
1808 if test $libc_cv_ld_no_whole_archive = no; then
1809   AC_MSG_ERROR([support for --no-whole-archive is needed])
1810 fi
1811
1812 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1813 cat > conftest.c <<\EOF
1814 _start () {}
1815 int __eh_pc;
1816 __throw () {}
1817 EOF
1818 dnl No \ in command here because it ends up inside ''.
1819 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1820                             -nostdlib -nostartfiles -fexceptions
1821                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1822   libc_cv_gcc_exceptions=yes
1823 else
1824   libc_cv_gcc_exceptions=no
1825 fi
1826 rm -f conftest*])
1827 if test $libc_cv_gcc_exceptions = yes; then
1828   exceptions=-fexceptions
1829 fi
1830 AC_SUBST(exceptions)dnl
1831
1832 if test "$host_cpu" = powerpc ; then
1833 # Check for a bug present in at least versions 2.8.x of GCC
1834 # and versions 1.0.x of EGCS.
1835 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1836 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1837                libc_cv_c_asmcr0_bug='no',
1838                libc_cv_c_asmcr0_bug='yes')])
1839 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1840   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1841 fi
1842 fi
1843
1844 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1845 cat > conftest.c <<\EOF
1846 void zero (void *x)
1847 {
1848   __builtin_memset (x, 0, 1000);
1849 }
1850 EOF
1851 dnl
1852 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1853 then
1854   libc_cv_gcc_builtin_memset=no
1855 else
1856   libc_cv_gcc_builtin_memset=yes
1857 fi
1858 rm -f conftest* ])
1859 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1860   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1861 fi
1862
1863 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1864 cat > conftest.c <<\EOF
1865 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1866 char *foo (const char *a, const char *b)
1867 {
1868   return __builtin_strstr (a, b);
1869 }
1870 EOF
1871 dnl
1872 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1873 then
1874   libc_cv_gcc_builtin_redirection=yes
1875 else
1876   libc_cv_gcc_builtin_redirection=no
1877 fi
1878 rm -f conftest* ])
1879 if test "$libc_cv_gcc_builtin_redirection" = no; then
1880   AC_MSG_ERROR([support for the symbol redirection needed])
1881 fi
1882
1883 dnl Check whether the compiler supports the __thread keyword.
1884 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1885 [cat > conftest.c <<\EOF
1886 __thread int a = 42;
1887 EOF
1888 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1889   libc_cv_gcc___thread=yes
1890 else
1891   libc_cv_gcc___thread=no
1892 fi
1893 rm -f conftest*])
1894 if test "$libc_cv_gcc___thread" = no; then
1895   AC_MSG_ERROR([support for the __thread keyword is required])
1896 fi
1897
1898 dnl Check whether the compiler supports the tls_model attribute.
1899 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1900 cat > conftest.c <<\EOF
1901 extern __thread int a __attribute__((tls_model ("initial-exec")));
1902 EOF
1903 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1904   libc_cv_gcc_tls_model_attr=yes
1905 else
1906   libc_cv_gcc_tls_model_attr=no
1907 fi
1908 rm -f conftest*])
1909 if test "$libc_cv_gcc_tls_model_attr" = no; then
1910   AC_MSG_ERROR([support for the tls_model attribute is required])
1911 fi
1912
1913 dnl Determine how to disable generation of FMA instructions.
1914 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1915                libc_cv_cc_nofma, [dnl
1916 libc_cv_cc_nofma=
1917 for opt in -ffp-contract=off -mno-fused-madd; do
1918   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1919 done])
1920 AC_SUBST(libc_cv_cc_nofma)
1921
1922 if test -n "$submachine"; then
1923   AC_CACHE_CHECK([for compiler option for CPU variant],
1924                  libc_cv_cc_submachine, [dnl
1925   libc_cv_cc_submachine=no
1926   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1927     LIBC_TRY_CC_OPTION([$opt], [
1928       libc_cv_cc_submachine="$opt"
1929       break], [])
1930   done])
1931   if test "x$libc_cv_cc_submachine" = xno; then
1932     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1933   fi
1934 fi
1935 AC_SUBST(libc_cv_cc_submachine)
1936
1937 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1938 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1939 cat > conftest.c <<EOF
1940 void
1941 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1942 foo (void) {}
1943 EOF
1944 libc_cv_cc_loop_to_function=no
1945 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1946 then
1947   libc_cv_cc_loop_to_function=yes
1948 fi
1949 rm -f conftest*])
1950 if test $libc_cv_cc_loop_to_function = yes; then
1951   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1952 fi
1953 AC_SUBST(libc_cv_cc_loop_to_function)
1954
1955 dnl Check whether we have the gd library available.
1956 AC_MSG_CHECKING(for libgd)
1957 if test "$with_gd" != "no"; then
1958   old_CFLAGS="$CFLAGS"
1959   CFLAGS="$CFLAGS $libgd_include"
1960   old_LDFLAGS="$LDFLAGS"
1961   LDFLAGS="$LDFLAGS $libgd_ldflags"
1962   old_LIBS="$LIBS"
1963   LIBS="$LIBS -lgd -lpng -lz -lm"
1964   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1965   CFLAGS="$old_CFLAGS"
1966   LDFLAGS="$old_LDFLAGS"
1967   LIBS="$old_LIBS"
1968 else
1969   LIBGD=no
1970 fi
1971 AC_MSG_RESULT($LIBGD)
1972 AC_SUBST(LIBGD)
1973
1974 # SELinux detection
1975 if test x$with_selinux = xno ; then
1976   have_selinux=no;
1977 else
1978   # See if we have the SELinux library
1979   AC_CHECK_LIB(selinux, is_selinux_enabled,
1980                have_selinux=yes, have_selinux=no)
1981   # See if we have the SELinux header with the NSCD permissions in it.
1982   if test x$have_selinux = xyes ; then
1983     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1984     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1985                     [#ifdef NSCD__SHMEMHOST
1986                      return 0;
1987                      #else
1988                      #error NSCD__SHMEMHOST not defined
1989                      #endif],
1990                     have_selinux=yes, have_selinux=no)
1991     AC_MSG_RESULT($have_selinux)
1992   fi
1993
1994   if test x$with_selinux = xyes ; then
1995     if test x$have_selinux = xno ; then
1996       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
1997     fi
1998   fi
1999 fi
2000 # Check if we're building with SELinux support.
2001 if test "x$have_selinux" = xyes; then
2002   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2003
2004   # See if we have the libaudit library
2005   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2006                have_libaudit=yes, have_libaudit=no)
2007   if test "x$have_libaudit" = xyes; then
2008     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2009   fi
2010   AC_SUBST(have_libaudit)
2011
2012   # See if we have the libcap library
2013   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2014   if test "x$have_libcap" = xyes; then
2015     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2016   fi
2017   AC_SUBST(have_libcap)
2018 fi
2019 AC_SUBST(have_selinux)
2020
2021 dnl check for the size of 'long double'.
2022 AC_CHECK_SIZEOF(long double, 0)
2023 sizeof_long_double=$ac_cv_sizeof_long_double
2024 AC_SUBST(sizeof_long_double)
2025
2026 CPPUNDEFS=
2027 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2028 dnl Since we are building the implementations of the fortified functions here,
2029 dnl having the macro defined interacts very badly.
2030 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2031 [AC_TRY_COMPILE([], [
2032 #ifdef _FORTIFY_SOURCE
2033 # error bogon
2034 #endif],
2035                 [libc_cv_predef_fortify_source=no],
2036                 [libc_cv_predef_fortify_source=yes])])
2037 if test $libc_cv_predef_fortify_source = yes; then
2038   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2039 fi
2040 AC_SUBST(CPPUNDEFS)
2041
2042 dnl Check for silly hacked compilers inserting -fstack-protector.
2043 dnl This breaks badly for the early startup code we compile, since
2044 dnl the compiled code can refer to a magic machine-dependent location
2045 dnl for the canary value before we have sufficient setup for that to
2046 dnl work.  It's also questionable to build all of libc with this flag
2047 dnl even when you're doing that for most applications you build, since
2048 dnl libc's code is so heavily-used and performance-sensitive.  If we
2049 dnl ever really want to make that work, it should be enabled explicitly
2050 dnl in the libc build, not inherited from implicit compiler settings.
2051 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2052                libc_cv_predef_stack_protector, [
2053 AC_TRY_COMPILE([extern void foobar (char *);],
2054                [char large_array[2048]; foobar (large_array);], [
2055 libc_undefs=`$NM -u conftest.o |
2056   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2057     2>&AS_MESSAGE_LOG_FD` || {
2058   AC_MSG_ERROR([confusing output from $NM -u])
2059 }
2060 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2061 # On some architectures, there are architecture-specific undefined
2062 # symbols (resolved by the linker), so filter out unknown symbols.
2063 # This will fail to produce the correct result if the compiler
2064 # defaults to -fstack-protector but this produces an undefined symbol
2065 # other than __stack_chk_fail.  However, compilers like that have not
2066 # been encountered in practice.
2067 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2068 case "$libc_undefs" in
2069 foobar) libc_cv_predef_stack_protector=no ;;
2070 '__stack_chk_fail
2071 foobar') libc_cv_predef_stack_protector=yes ;;
2072 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2073 esac],
2074                [AC_MSG_ERROR([test compilation failed])])
2075 ])
2076 libc_extra_cflags=
2077 if test $libc_cv_predef_stack_protector = yes; then
2078   libc_extra_cflags=-fno-stack-protector
2079 fi
2080 AC_SUBST(libc_extra_cflags)
2081
2082 ### End of automated tests.
2083 ### Now run sysdeps configure fragments.
2084
2085 # They also can set these variables.
2086 use_ldconfig=no
2087 ldd_rewrite_script=no
2088 libc_cv_sysconfdir=$sysconfdir
2089 libc_cv_localstatedir=$localstatedir
2090 libc_cv_gcc_unwind_find_fde=no
2091 libc_cv_idn=no
2092
2093 # Iterate over all the sysdep directories we will use, running their
2094 # configure fragments.
2095 for dir in $sysnames; do
2096   case $dir in
2097     /*) dest=$dir ;;
2098     *)  dest=$srcdir/$dir ;;
2099   esac
2100   if test -r $dest/configure; then
2101     AC_MSG_RESULT(running configure fragment for $dir)
2102     . $dest/configure
2103   fi
2104 done
2105
2106 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2107   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2108 fi
2109 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2110
2111 # A sysdeps configure fragment can reset this if IFUNC is not actually
2112 # usable even though the assembler knows how to generate the symbol type.
2113 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2114   AC_DEFINE(HAVE_IFUNC)
2115 fi
2116
2117 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2118 # configure fragment can override the value to prevent this AC_DEFINE.
2119 AC_SUBST(use_nscd)
2120 if test "x$use_nscd" != xno; then
2121   AC_DEFINE([USE_NSCD])
2122 fi
2123 if test "x$build_nscd" = xdefault; then
2124   build_nscd=$use_nscd
2125 fi
2126
2127 # Test for old glibc 2.0.x headers so that they can be removed properly
2128 # Search only in includedir.
2129 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2130 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2131 then
2132   old_glibc_headers=yes
2133 else
2134   old_glibc_headers=no
2135 fi
2136 AC_MSG_RESULT($old_glibc_headers)
2137 if test ${old_glibc_headers} = yes; then
2138   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2139   AC_MSG_WARN(*** be removed.)
2140 fi
2141 AC_SUBST(old_glibc_headers)
2142
2143 AC_SUBST(libc_cv_slibdir)
2144 AC_SUBST(libc_cv_rtlddir)
2145 AC_SUBST(libc_cv_localedir)
2146 AC_SUBST(libc_cv_sysconfdir)
2147 AC_SUBST(libc_cv_localstatedir)
2148 AC_SUBST(libc_cv_rootsbindir)
2149 AC_SUBST(libc_cv_forced_unwind)
2150
2151 if test x$use_ldconfig = xyes; then
2152   AC_DEFINE(USE_LDCONFIG)
2153 fi
2154 AC_SUBST(use_ldconfig)
2155 AC_SUBST(ldd_rewrite_script)
2156
2157 AC_SUBST(static)
2158 AC_SUBST(shared)
2159
2160 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2161 [libc_cv_pic_default=yes
2162 cat > conftest.c <<EOF
2163 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2164 # error PIC is default.
2165 #endif
2166 EOF
2167 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2168   libc_cv_pic_default=no
2169 fi
2170 rm -f conftest.*])
2171 AC_SUBST(libc_cv_pic_default)
2172
2173 AC_SUBST(profile)
2174 AC_SUBST(static_nss)
2175
2176 AC_SUBST(DEFINES)
2177
2178 dnl See sysdeps/mach/configure.ac for this variable.
2179 AC_SUBST(mach_interface_list)
2180
2181 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2182 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2183 AC_SUBST(VERSION)
2184 AC_SUBST(RELEASE)
2185
2186 AC_CONFIG_FILES([config.make Makefile])
2187 AC_CONFIG_COMMANDS([default],[[
2188 case $CONFIG_FILES in *config.make*)
2189 echo "$config_vars" >> config.make;;
2190 esac
2191 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2192 AC_OUTPUT