x86: Prevent NMIs from nesting
[akaros.git] / kern / arch / x86 / trapentry64.S
1 /* See COPYRIGHT for copyright information.
2  * The two TRAP* macros (minus the .data parts) are from the JOS project.
3  * Everything else:
4  * Copyright (c) 2009, 2013 The Regents of the University of California
5  * Barret Rhoden <brho@cs.berkeley.edu>
6  * See LICENSE for details.
7  */
8 #include <arch/mmu.h>
9 #include <arch/trap.h>
10 #include <arch/x86.h>
11 #include <ros/memlayout.h>
12
13 ###################################################################
14 # exceptions/interrupts
15 ###################################################################
16
17 /* The TRAPHANDLER macro defines a globally-visible function for handling
18  * a trap.  It pushes a trap number onto the stack, then jumps to _alltraps.
19  * It also builds this traps portion of the trap_tbl.
20  * Use TRAPHANDLER for traps where the CPU automatically pushes an error code.
21  */
22 #define TRAPHANDLER(name, num)                                                                  \
23         .text;                                                                                                          \
24         .globl name;            /* define global symbol for 'name' */   \
25         .type name, @function;  /* symbol type is function */           \
26         .align 2;               /* align function definition */                         \
27         name:                   /* function starts here */                                      \
28         pushq $(num);                                                                                           \
29         jmp _alltraps;                                                                                          \
30         .data;                                                                                                          \
31         .quad name;                                                                                                     \
32         .long num
33
34 /* Use TRAPHANDLER_NOEC for traps where the CPU doesn't push an error code.
35  * It pushes a 0 in place of the error code, so the trap frame has the same
36  * format in either case.  */
37 #define TRAPHANDLER_NOEC(name, num)             \
38         .text;                                                          \
39         .globl name;                                            \
40         .type name, @function;                          \
41         .align 2;                                                       \
42         name:                                                           \
43         pushq $0;                                                       \
44         pushq $(num);                                           \
45         jmp _alltraps;                                          \
46         .data;                                                          \
47         .quad name;                                                     \
48         .long num
49
50 /* Same as NOEC, but for IRQs instead.  num is the ISR number it is mapped to */
51 #define IRQ_HANDLER(name, num)                  \
52         .text;                                                          \
53         .globl name;                                            \
54         .type name, @function;                          \
55         .align 2;                                                       \
56         name:                                                           \
57         pushq $0;                                                       \
58         pushq $(num);                                           \
59         jmp _allirqs;                                           \
60         .data;                                                          \
61         .quad name;                                                     \
62         .long num
63
64 #define NMI_HANDLER(name, num)                  \
65         .text;                                                          \
66         .globl name;                                            \
67         .type name, @function;                          \
68         .align 2;                                                       \
69         name:                                                           \
70         pushq $0;                                                       \
71         pushq $(num);                                           \
72         jmp _nmi_entry;                                         \
73         .data;                                                          \
74         .quad name;                                                     \
75         .long num
76
77 /* Only used in the kernel during SMP boot.  Send a LAPIC_EOI and iret. */
78 #define POKE_HANDLER(name, num)                 \
79         .text;                                                          \
80         .globl name;                                            \
81         .type name, @function;                          \
82         .align 2;                                                       \
83         name:;                                                          \
84         pushq %rax;                     \
85         pushq %rcx;                     \
86         pushq %rdx;                     \
87         movq $0, %rax;                  \
88         movq $0, %rdx;                  \
89         movq $(MSR_LAPIC_EOI), %rcx;    \
90         wrmsr;                          \
91         popq %rdx;                      \
92         popq %rcx;                      \
93         popq %rax;                      \
94         iretq;                                                          \
95         .data;                                                          \
96         .quad name;                                                     \
97         .long num
98
99 .data
100 .globl trap_tbl
101 trap_tbl:
102
103 /* Generate entry points for the different traps.  Note that all of these bounce
104  * off the corresponding trap.c function, such as handle_irqs, and that the name
105  * e.g. ISR_divide_error is soley for the little stup that jumps to something
106  * like _alltraps.
107  *
108  * Technically, these HANDLER entries do not need to be in numeric order.
109  * trap.c will do a 'foreach (up to last-1), set the IDT for the number to point
110  * to the func' in the order in which they appear in the trap tbl, so the 'last
111  * one wins'. */
112 TRAPHANDLER_NOEC(ISR_divide_error, T_DIVIDE)
113 TRAPHANDLER_NOEC(ISR_debug_exceptions, T_DEBUG)
114 NMI_HANDLER(ISR_NMI, T_NMI)
115 TRAPHANDLER_NOEC(ISR_breakpoint, T_BRKPT)
116 TRAPHANDLER_NOEC(ISR_overflow, T_OFLOW)
117 TRAPHANDLER_NOEC(ISR_bounds_check, T_BOUND)
118 TRAPHANDLER_NOEC(ISR_invalid_opcode, T_ILLOP)
119 TRAPHANDLER_NOEC(ISR_device_not_available, T_DEVICE)
120 /* supposedly, DF generates an error code, but the one time we've had a DF so
121  * far, it didn't.  eventually, this should probably be handled with a task gate
122  * it might have pushed a 0, but just the rest of the stack was corrupt
123  */
124 TRAPHANDLER_NOEC(ISR_double_fault, T_DBLFLT)
125 /* 9 reserved */
126 TRAPHANDLER(ISR_invalid_TSS, T_TSS)
127 TRAPHANDLER(ISR_segment_not_present, T_SEGNP)
128 TRAPHANDLER(ISR_stack_exception, T_STACK)
129 TRAPHANDLER(ISR_general_protection_fault, T_GPFLT)
130 TRAPHANDLER(ISR_page_fault, T_PGFLT)
131 /* 15 reserved */
132 TRAPHANDLER_NOEC(ISR_floating_point_error, T_FPERR)
133 TRAPHANDLER(ISR_alignment_check, T_ALIGN)
134 TRAPHANDLER_NOEC(ISR_machine_check, T_MCHK)
135 TRAPHANDLER_NOEC(ISR_simd_error, T_SIMDERR)
136 /* 20 - 31 reserved */
137 /* 32-47 are PIC/8259 IRQ vectors */
138 IRQ_HANDLER(IRQ0, 32)
139 IRQ_HANDLER(IRQ1, 33)
140 IRQ_HANDLER(IRQ2, 34)
141 IRQ_HANDLER(IRQ3, 35)
142 IRQ_HANDLER(IRQ4, 36)
143 IRQ_HANDLER(IRQ5, 37)
144 IRQ_HANDLER(IRQ6, 38)
145 IRQ_HANDLER(IRQ7, 39)
146 IRQ_HANDLER(IRQ8, 40)
147 IRQ_HANDLER(IRQ9, 41)
148 IRQ_HANDLER(IRQ10, 42)
149 IRQ_HANDLER(IRQ11, 43)
150 IRQ_HANDLER(IRQ12, 44)
151 IRQ_HANDLER(IRQ13, 45)
152 IRQ_HANDLER(IRQ14, 46)
153 IRQ_HANDLER(IRQ15, 47)
154 TRAPHANDLER_NOEC(ISR_syscall, T_SYSCALL)
155 /* 49-223 are IOAPIC routing vectors (from IOAPIC to LAPIC) */
156 IRQ_HANDLER(IRQ17, 49)
157 IRQ_HANDLER(IRQ18, 50)
158 IRQ_HANDLER(IRQ19, 51)
159 IRQ_HANDLER(IRQ20, 52)
160 IRQ_HANDLER(IRQ21, 53)
161 IRQ_HANDLER(IRQ22, 54)
162 IRQ_HANDLER(IRQ23, 55)
163 IRQ_HANDLER(IRQ24, 56)
164 IRQ_HANDLER(IRQ25, 57)
165 IRQ_HANDLER(IRQ26, 58)
166 IRQ_HANDLER(IRQ27, 59)
167 IRQ_HANDLER(IRQ28, 60)
168 IRQ_HANDLER(IRQ29, 61)
169 IRQ_HANDLER(IRQ30, 62)
170 IRQ_HANDLER(IRQ31, 63)
171 IRQ_HANDLER(IRQ32, 64)
172 IRQ_HANDLER(IRQ33, 65)
173 IRQ_HANDLER(IRQ34, 66)
174 IRQ_HANDLER(IRQ35, 67)
175 IRQ_HANDLER(IRQ36, 68)
176 IRQ_HANDLER(IRQ37, 69)
177 IRQ_HANDLER(IRQ38, 70)
178 IRQ_HANDLER(IRQ39, 71)
179 IRQ_HANDLER(IRQ40, 72)
180 IRQ_HANDLER(IRQ41, 73)
181 IRQ_HANDLER(IRQ42, 74)
182 IRQ_HANDLER(IRQ43, 75)
183 IRQ_HANDLER(IRQ44, 76)
184 IRQ_HANDLER(IRQ45, 77)
185 IRQ_HANDLER(IRQ46, 78)
186 IRQ_HANDLER(IRQ47, 79)
187 IRQ_HANDLER(IRQ48, 80)
188 IRQ_HANDLER(IRQ49, 81)
189 IRQ_HANDLER(IRQ50, 82)
190 IRQ_HANDLER(IRQ51, 83)
191 IRQ_HANDLER(IRQ52, 84)
192 IRQ_HANDLER(IRQ53, 85)
193 IRQ_HANDLER(IRQ54, 86)
194 IRQ_HANDLER(IRQ55, 87)
195 IRQ_HANDLER(IRQ56, 88)
196 IRQ_HANDLER(IRQ57, 89)
197 IRQ_HANDLER(IRQ58, 90)
198 IRQ_HANDLER(IRQ59, 91)
199 IRQ_HANDLER(IRQ60, 92)
200 IRQ_HANDLER(IRQ61, 93)
201 IRQ_HANDLER(IRQ62, 94)
202 IRQ_HANDLER(IRQ63, 95)
203 IRQ_HANDLER(IRQ64, 96)
204 IRQ_HANDLER(IRQ65, 97)
205 IRQ_HANDLER(IRQ66, 98)
206 IRQ_HANDLER(IRQ67, 99)
207 IRQ_HANDLER(IRQ68, 100)
208 IRQ_HANDLER(IRQ69, 101)
209 IRQ_HANDLER(IRQ70, 102)
210 IRQ_HANDLER(IRQ71, 103)
211 IRQ_HANDLER(IRQ72, 104)
212 IRQ_HANDLER(IRQ73, 105)
213 IRQ_HANDLER(IRQ74, 106)
214 IRQ_HANDLER(IRQ75, 107)
215 IRQ_HANDLER(IRQ76, 108)
216 IRQ_HANDLER(IRQ77, 109)
217 IRQ_HANDLER(IRQ78, 110)
218 IRQ_HANDLER(IRQ79, 111)
219 IRQ_HANDLER(IRQ80, 112)
220 IRQ_HANDLER(IRQ81, 113)
221 IRQ_HANDLER(IRQ82, 114)
222 IRQ_HANDLER(IRQ83, 115)
223 IRQ_HANDLER(IRQ84, 116)
224 IRQ_HANDLER(IRQ85, 117)
225 IRQ_HANDLER(IRQ86, 118)
226 IRQ_HANDLER(IRQ87, 119)
227 IRQ_HANDLER(IRQ88, 120)
228 IRQ_HANDLER(IRQ89, 121)
229 IRQ_HANDLER(IRQ90, 122)
230 IRQ_HANDLER(IRQ91, 123)
231 IRQ_HANDLER(IRQ92, 124)
232 IRQ_HANDLER(IRQ93, 125)
233 IRQ_HANDLER(IRQ94, 126)
234 IRQ_HANDLER(IRQ95, 127)
235 IRQ_HANDLER(IRQ96, 128)
236 IRQ_HANDLER(IRQ97, 129)
237 IRQ_HANDLER(IRQ98, 130)
238 IRQ_HANDLER(IRQ99, 131)
239 IRQ_HANDLER(IRQ100, 132)
240 IRQ_HANDLER(IRQ101, 133)
241 IRQ_HANDLER(IRQ102, 134)
242 IRQ_HANDLER(IRQ103, 135)
243 IRQ_HANDLER(IRQ104, 136)
244 IRQ_HANDLER(IRQ105, 137)
245 IRQ_HANDLER(IRQ106, 138)
246 IRQ_HANDLER(IRQ107, 139)
247 IRQ_HANDLER(IRQ108, 140)
248 IRQ_HANDLER(IRQ109, 141)
249 IRQ_HANDLER(IRQ110, 142)
250 IRQ_HANDLER(IRQ111, 143)
251 IRQ_HANDLER(IRQ112, 144)
252 IRQ_HANDLER(IRQ113, 145)
253 IRQ_HANDLER(IRQ114, 146)
254 IRQ_HANDLER(IRQ115, 147)
255 IRQ_HANDLER(IRQ116, 148)
256 IRQ_HANDLER(IRQ117, 149)
257 IRQ_HANDLER(IRQ118, 150)
258 IRQ_HANDLER(IRQ119, 151)
259 IRQ_HANDLER(IRQ120, 152)
260 IRQ_HANDLER(IRQ121, 153)
261 IRQ_HANDLER(IRQ122, 154)
262 IRQ_HANDLER(IRQ123, 155)
263 IRQ_HANDLER(IRQ124, 156)
264 IRQ_HANDLER(IRQ125, 157)
265 IRQ_HANDLER(IRQ126, 158)
266 IRQ_HANDLER(IRQ127, 159)
267 IRQ_HANDLER(IRQ128, 160)
268 IRQ_HANDLER(IRQ129, 161)
269 IRQ_HANDLER(IRQ130, 162)
270 IRQ_HANDLER(IRQ131, 163)
271 IRQ_HANDLER(IRQ132, 164)
272 IRQ_HANDLER(IRQ133, 165)
273 IRQ_HANDLER(IRQ134, 166)
274 IRQ_HANDLER(IRQ135, 167)
275 IRQ_HANDLER(IRQ136, 168)
276 IRQ_HANDLER(IRQ137, 169)
277 IRQ_HANDLER(IRQ138, 170)
278 IRQ_HANDLER(IRQ139, 171)
279 IRQ_HANDLER(IRQ140, 172)
280 IRQ_HANDLER(IRQ141, 173)
281 IRQ_HANDLER(IRQ142, 174)
282 IRQ_HANDLER(IRQ143, 175)
283 IRQ_HANDLER(IRQ144, 176)
284 IRQ_HANDLER(IRQ145, 177)
285 IRQ_HANDLER(IRQ146, 178)
286 IRQ_HANDLER(IRQ147, 179)
287 IRQ_HANDLER(IRQ148, 180)
288 IRQ_HANDLER(IRQ149, 181)
289 IRQ_HANDLER(IRQ150, 182)
290 IRQ_HANDLER(IRQ151, 183)
291 IRQ_HANDLER(IRQ152, 184)
292 IRQ_HANDLER(IRQ153, 185)
293 IRQ_HANDLER(IRQ154, 186)
294 IRQ_HANDLER(IRQ155, 187)
295 IRQ_HANDLER(IRQ156, 188)
296 IRQ_HANDLER(IRQ157, 189)
297 IRQ_HANDLER(IRQ158, 190)
298 IRQ_HANDLER(IRQ159, 191)
299 IRQ_HANDLER(IRQ160, 192)
300 IRQ_HANDLER(IRQ161, 193)
301 IRQ_HANDLER(IRQ162, 194)
302 IRQ_HANDLER(IRQ163, 195)
303 IRQ_HANDLER(IRQ164, 196)
304 IRQ_HANDLER(IRQ165, 197)
305 IRQ_HANDLER(IRQ166, 198)
306 IRQ_HANDLER(IRQ167, 199)
307 IRQ_HANDLER(IRQ168, 200)
308 IRQ_HANDLER(IRQ169, 201)
309 IRQ_HANDLER(IRQ170, 202)
310 IRQ_HANDLER(IRQ171, 203)
311 IRQ_HANDLER(IRQ172, 204)
312 IRQ_HANDLER(IRQ173, 205)
313 IRQ_HANDLER(IRQ174, 206)
314 IRQ_HANDLER(IRQ175, 207)
315 IRQ_HANDLER(IRQ176, 208)
316 IRQ_HANDLER(IRQ177, 209)
317 IRQ_HANDLER(IRQ178, 210)
318 IRQ_HANDLER(IRQ179, 211)
319 IRQ_HANDLER(IRQ180, 212)
320 IRQ_HANDLER(IRQ181, 213)
321 IRQ_HANDLER(IRQ182, 214)
322 IRQ_HANDLER(IRQ183, 215)
323 IRQ_HANDLER(IRQ184, 216)
324 IRQ_HANDLER(IRQ185, 217)
325 IRQ_HANDLER(IRQ186, 218)
326 IRQ_HANDLER(IRQ187, 219)
327 IRQ_HANDLER(IRQ188, 220)
328 IRQ_HANDLER(IRQ189, 221)
329 IRQ_HANDLER(IRQ190, 222)
330 IRQ_HANDLER(IRQ191, 223)
331 /* 224-239 are OS IPI vectors (0xe0-0xef) */
332 IRQ_HANDLER(IRQ192, I_SMP_CALL0)
333 IRQ_HANDLER(IRQ193, I_SMP_CALL1)
334 IRQ_HANDLER(IRQ194, I_SMP_CALL2)
335 IRQ_HANDLER(IRQ195, I_SMP_CALL3)
336 IRQ_HANDLER(IRQ196, I_SMP_CALL4)
337 IRQ_HANDLER(IRQ197, 229)
338 IRQ_HANDLER(IRQ198, 230)
339 IRQ_HANDLER(IRQ199, 231)
340 IRQ_HANDLER(IRQ200, 232)
341 IRQ_HANDLER(IRQ201, 233)
342 IRQ_HANDLER(IRQ202, 234)
343 IRQ_HANDLER(IRQ203, 235)
344 IRQ_HANDLER(IRQ204, 236)
345 IRQ_HANDLER(IRQ205, I_TESTING)
346 POKE_HANDLER(IRQ206, I_POKE_CORE)
347 IRQ_HANDLER(IRQ207, I_KERNEL_MSG)
348 /* 240-255 are LAPIC vectors (0xf0-0xff), hightest priority class */
349 IRQ_HANDLER(IRQ208, 240)
350 IRQ_HANDLER(IRQ209, 241)
351 IRQ_HANDLER(IRQ210, 242)
352 IRQ_HANDLER(IRQ211, 243)
353 IRQ_HANDLER(IRQ212, 244)
354 IRQ_HANDLER(IRQ213, 245)
355 IRQ_HANDLER(IRQ214, 246)
356 IRQ_HANDLER(IRQ215, 247)
357 IRQ_HANDLER(IRQ216, 248)
358 IRQ_HANDLER(IRQ217, 249)
359 IRQ_HANDLER(IRQ218, 250)
360 IRQ_HANDLER(IRQ219, 251)
361 IRQ_HANDLER(IRQ220, 252)
362 IRQ_HANDLER(IRQ221, 253)
363 IRQ_HANDLER(IRQ222, 254)
364 IRQ_HANDLER(IRQ223, 255)
365 /* But make sure default is last!! */
366 TRAPHANDLER_NOEC(ISR_default, T_DEFAULT)
367
368 .data
369 .globl trap_tbl_end
370 trap_tbl_end:
371
372 .text
373 _alltraps:
374         cld
375         pushq %r15
376         pushq %r14
377         pushq %r13
378         pushq %r12
379         pushq %r11
380         pushq %r10
381         pushq %r9
382         pushq %r8
383         pushq %rdi
384         pushq %rsi
385         pushq %rbp
386         pushq %rdx
387         pushq %rcx
388         pushq %rbx
389         pushq %rax
390         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
391         je trap_all_tf
392         # this is a user TF.  we need to swapgs to get the kernel's gs and mark the
393         # context as partial
394         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
395         movl $0x1, 0xac(%rsp)   # 0xac - diff btw tf_padding0 and tf_rax
396 trap_all_tf:
397         pushq $0                                # fsbase space
398         pushq $0                                # gsbase space
399         movq $0, %rbp                   # so we can backtrace to this point
400         movq %rsp, %rdi
401         call trap
402         # the return paths are only used by the kernel
403         addq $0x10, %rsp                        # skip fs/gs base
404         popq %rax
405         popq %rbx
406         popq %rcx
407         popq %rdx
408         popq %rbp
409         popq %rsi
410         popq %rdi
411         popq %r8
412         popq %r9
413         popq %r10
414         popq %r11
415         popq %r12
416         popq %r13
417         popq %r14
418         popq %r15
419         addq $0x10, %rsp                        # skip trapno and err
420         iretq
421
422 # might merge this with _alltraps
423 _allirqs:
424         cld
425         pushq %r15
426         pushq %r14
427         pushq %r13
428         pushq %r12
429         pushq %r11
430         pushq %r10
431         pushq %r9
432         pushq %r8
433         pushq %rdi
434         pushq %rsi
435         pushq %rbp
436         pushq %rdx
437         pushq %rcx
438         pushq %rbx
439         pushq %rax
440         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
441         je irq_all_tf
442         # this is a user TF.  we need to swapgs to get the kernel's gs and mark the
443         # context as partial
444         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
445         movl $0x1, 0xac(%rsp)   # 0xac - diff btw tf_padding0 and tf_rax
446 irq_all_tf:
447         pushq $0                                # fsbase space
448         pushq $0                                # gsbase space
449         movq $0, %rbp                   # so we can backtrace to this point
450         movq %rsp, %rdi
451         call handle_irq
452         # the return paths are only used by the kernel
453         addq $0x10, %rsp                        # skip fs/gs base
454         popq %rax
455         popq %rbx
456         popq %rcx
457         popq %rdx
458         popq %rbp
459         popq %rsi
460         popq %rdi
461         popq %r8
462         popq %r9
463         popq %r10
464         popq %r11
465         popq %r12
466         popq %r13
467         popq %r14
468         popq %r15
469         addq $0x10, %rsp                        # skip trapno and err
470         iretq
471
472 # Unlike normal trap and IRQ handlers, both user and kernel TFs are handled the
473 # similarly.  Both come in here and return from here.  We cannot do anything
474 # fancy like proc_restartcore() from NMI context.
475 #
476 # All NMIs will come in fresh on the same stack (IST1, per-core).  We don't need
477 # to find a stackpointer, but we do need to find GS.
478 #
479 # Regardless of whether or not the interrupted context was in the kernel, we
480 # can't trust GS.  Basically we can never tell from looking at GS and KERN_GS
481 # whether swapgs occurred, since the user could have put kernel addrs in their
482 # GS.  But we can use the stack for storage to bootstrap GS.  %rsp at entry
483 # points to pcpui *.
484 #
485 # We can also tell if GS was set correctly or not and avoid the wrmsr calls.
486 # This isn't a huge deal.  But note that we don't know whether or not the kernel
487 # actually set the gsbase.  We just know if it was correct or not.  The user
488 # could have set it and the kernel hadn't had a chance to swapgs yet.  The NMI
489 # handler doesn't care, since all TFs come in and go out via this asm.
490 #
491 # If we want to be paranoid, we can completely ignore user TFs and just save and
492 # restore GS with the same mechanism we use for the kernel.  But since we came
493 # in on a user TF, we can use swapgs.  Note that even for nested NMI handlers,
494 # we have a user TF for only the first time, and only the last exit will swapgs
495 # back to the way it was initially.
496 _nmi_entry:
497         cld
498         pushq %r15
499         pushq %r14
500         pushq %r13
501         pushq %r12
502         pushq %r11
503         pushq %r10
504         pushq %r9
505         pushq %r8
506         pushq %rdi
507         pushq %rsi
508         pushq %rbp
509         pushq %rdx
510         pushq %rcx
511         pushq %rbx
512         pushq %rax
513         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
514         je nmi_kern_tf
515         # this is a user TF.  we need to swapgs to get the kernel's gs and mark the
516         # context as partial
517         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
518         movl $0x1, 0xac(%rsp)   # 0xac - diff btw tf_padding0 and tf_rax
519         pushq $0                                # fsbase space
520         pushq $0                                # gsbase space
521         jmp nmi_all_tf
522 nmi_kern_tf:
523         # this is a kernel TF.  but we don't know if they set up gs yet, so we'll
524         # save and restore whatever they had loaded and use our own
525         pushq $0                                # fsbase space
526         # Get the current GS base into rax
527         movl $MSR_GS_BASE, %ecx
528         rdmsr
529         shlq $32, %rdx
530         orq %rdx, %rax
531         # Get the real GS base from the top of the stack.  This was set in smp_boot,
532         # and our rsp pointed to it when we entered the kernel.
533         movq 0xb8(%rsp), %rdx   # 0xb8 from fs_base to the top
534         # Compare them.  If they are the same, we can just push 0 for gsbase (which
535         # later will mean "no need to restore GS".
536         cmpq %rdx, %rax
537         je nmi_gs_ok
538         # They weren't the same.  Save the old one and set the new one.
539         pushq %rax                              # gsbase space
540         movq %rdx, %rax
541         shrq $32, %rdx
542         andl $0xffffffff, %eax
543         wrmsr
544         jmp nmi_all_tf
545 nmi_gs_ok:
546         pushq $0                                # gsbase space
547 nmi_all_tf:
548         # At this point, GS is set correctly, either due to swapgs (user TF), wrmsr
549         # (kern TF with bad GS), or it was already fine (and gsbase in the TF = 0).
550         movq $0, %rbp                   # so we can backtrace to this point
551         movq %rsp, %rdi
552         call handle_nmi
553         # Unlike in normal IRQs/Traps, both user and kernel contexts return via this
554         # path.
555         cmpw $GD_KT, 0xa0(%rsp) # 0xa0 - diff btw tf_cs and tf_gsbase
556         je nmi_kern_restore_gs
557         # User TF.  Restore whatever was there with swapgs.  We don't care what it
558         # was, nor do we care what was in the TF.
559         swapgs                                  # user's GS is now in MSR_GS_BASE
560         addq $0x10, %rsp                # skip gs/fs base
561         jmp nmi_popal
562 nmi_kern_restore_gs:
563         popq %rax                               # fetch saved gsbase
564         addq $0x08, %rsp                # skip fs base
565         cmpq $0, %rax
566         je nmi_popal
567         # gsbase in the TF != 0, which means we need to restore that gsbase
568         movl $MSR_GS_BASE, %ecx
569         movq %rax, %rdx
570         shrq $32, %rdx
571         andl $0xffffffff, %eax
572         wrmsr
573 nmi_popal:
574         popq %rax
575         popq %rbx
576         popq %rcx
577         popq %rdx
578         popq %rbp
579         popq %rsi
580         popq %rdi
581         popq %r8
582         popq %r9
583         popq %r10
584         popq %r11
585         popq %r12
586         popq %r13
587         popq %r14
588         popq %r15
589         addq $0x10, %rsp                        # skip trapno and err
590         iretq
591
592 .globl __nmi_pop_ok_start;
593 .globl __nmi_pop_ok_end;
594 .globl __nmi_pop_fail_start;
595 .globl __nmi_pop_fail_end;
596
597 # extern void nmi_try_to_pop(struct hw_trapframe *tf, int *status,
598 #                            int old_val, int new_val);
599 #
600 # __nmi_bottom_half calls this to atomically pop a hw_tf (%rdi) and set
601 # &pcpui->nmi_status (%rsi) with compare and swap to NMI_NORMAL_OPN (%ecx) given
602 # that it was NMI_IN_PROGRESS (%edx)
603 #
604 # (Careful, nmi_status is an int, not a long.)
605 #
606 # If the real NMI handler interrupts us, it'll move us to the fail section of
607 # the code.  That code is identical to 'ok', up until ok's final statement.
608 #
609 # In that event, we'll need a little help returning: specifically to bootstrap
610 # pcpui and our current stackpointer.  pcpui is already saved near the top of
611 # stack.  We'll save rsp ourselves.
612 .globl nmi_try_to_pop;
613 .type nmi_try_to_pop, @function;
614 nmi_try_to_pop:
615 __nmi_pop_ok_start:
616         # careful only to use caller-saved or argument registers before saving
617         movl %edx, %eax                 # load old_val into eax for the CAS
618         cmpxchgl %ecx, (%rsi)   # no need for LOCK, since an NMI would serialize
619         jz nmi_ok_cas_worked    # ZF = 1 on successful CAS
620         ret
621 nmi_ok_cas_worked:
622         # save callee-saved regs (the pops below clobber them, and we might return)
623         pushq %rbp
624         pushq %rbx
625         pushq %r12
626         pushq %r13
627         pushq %r14
628         pushq %r15
629         # We need to save the current rsp into the scratch space at the top of the
630         # stack.  This assumes we're within the top page of our stack, which should
631         # always be true.  Careful not to use rdi, which still has an argument.
632         movq %rsp, %rbx
633         # Want to round rbx up to PGSIZE, then subtract 8, to get our slot.
634         movq $0xfff, %rax
635         notq %rax                               # rax = 0xfffffffffffff000
636         andq %rax, %rbx                 # round down rbx
637         addq $0x1000, %rbx              # add PGSIZE, assuming rsp was not page aligned
638         subq $0x8, %rbx                 # point to the scratch space
639         movq %rsp, (%rbx)               # save rsp in the scratch space
640         # We jump our rsp to the base of the HW_TF.  This is still on the same
641         # stack, just farther back than where our caller is.  We need to be careful
642         # to not clobber the stack.  Otherwise we'll have chaos.
643         movq %rdi, %rsp
644         # From here down is the same as the normal NMI exit path, but with 'ok' in
645         # the symbol names.
646         cmpw $GD_KT, 0xa0(%rsp) # 0xa0 - diff btw tf_cs and tf_gsbase
647         je nmi_ok_kern_restore_gs
648         # User TF.  Restore whatever was there with swapgs.  We don't care what it
649         # was, nor do we care what was in the TF.
650         swapgs                                  # user's GS is now in MSR_GS_BASE
651         addq $0x10, %rsp                # skip gs/fs base
652         jmp nmi_ok_popal
653 nmi_ok_kern_restore_gs:
654         popq %rax                               # fetch saved gsbase
655         addq $0x08, %rsp                # skip fs base
656         cmpq $0, %rax
657         je nmi_ok_popal
658         # gsbase in the TF != 0, which means we need to restore that gsbase
659         movl $MSR_GS_BASE, %ecx
660         movq %rax, %rdx
661         shrq $32, %rdx
662         andl $0xffffffff, %eax
663         wrmsr
664 nmi_ok_popal:
665         popq %rax
666         popq %rbx
667         popq %rcx
668         popq %rdx
669         popq %rbp
670         popq %rsi
671         popq %rdi
672         popq %r8
673         popq %r9
674         popq %r10
675         popq %r11
676         popq %r12
677         popq %r13
678         popq %r14
679         popq %r15
680         addq $0x10, %rsp                        # skip trapno and err
681         iretq
682 __nmi_pop_ok_end:
683
684 # This is the 'fail' case.  It is identical to the 'ok' case, up until the
685 # iretq, other than 'ok' replaced with 'fail'.  In place of iretq, we undo the
686 # entire operation.
687 __nmi_pop_fail_start:
688         # careful only to use caller-saved or argument registers before saving
689         movl %edx, %eax                 # load old_val into eax for the CAS
690         cmpxchgl %ecx, (%rsi)   # no need for LOCK, since an NMI would serialize
691         jz nmi_fail_cas_worked  # ZF = 1 on successful CAS
692         ret
693 nmi_fail_cas_worked:
694         # save callee-saved regs (the pops below clobber them, and we might return)
695         pushq %rbp
696         pushq %rbx
697         pushq %r12
698         pushq %r13
699         pushq %r14
700         pushq %r15
701         # We need to save the current rsp into the scratch space at the top of the
702         # stack.  This assumes we're within the top page of our stack, which should
703         # always be true.  Careful not to use rdi, which still has an argument.
704         movq %rsp, %rbx
705         # Want to round rbx up to PGSIZE, then subtract 8, to get our slot.
706         movq $0xfff, %rax
707         notq %rax                               # rax = 0xfffffffffffff000
708         andq %rax, %rbx                 # round down rbx
709         addq $0x1000, %rbx              # add PGSIZE, assuming rsp was not page aligned
710         subq $0x8, %rbx                 # point to the scratch space
711         movq %rsp, (%rbx)               # save rsp in the scratch space
712         # We jump our rsp to the base of the HW_TF.  This is still on the same
713         # stack, just farther back than where our caller is.  We need to be careful
714         # to not clobber the stack.  Otherwise we'll have chaos.
715         movq %rdi, %rsp
716         # From here down is the same as the normal NMI exit path and the ok path,
717         # but with 'fail' in the symbol names.
718         cmpw $GD_KT, 0xa0(%rsp) # 0xa0 - diff btw tf_cs and tf_gsbase
719         je nmi_fail_kern_restore_gs
720         # User TF.  Restore whatever was there with swapgs.  We don't care what it
721         # was, nor do we care what was in the TF.
722         swapgs                                  # user's GS is now in MSR_GS_BASE
723         addq $0x10, %rsp                # skip gs/fs base
724         jmp nmi_fail_popal
725 nmi_fail_kern_restore_gs:
726         popq %rax                               # fetch saved gsbase
727         addq $0x08, %rsp                # skip fs base
728         cmpq $0, %rax
729         je nmi_fail_popal
730         # gsbase in the TF != 0, which means we need to restore that gsbase
731         movl $MSR_GS_BASE, %ecx
732         movq %rax, %rdx
733         shrq $32, %rdx
734         andl $0xffffffff, %eax
735         wrmsr
736 nmi_fail_popal:
737         popq %rax
738         popq %rbx
739         popq %rcx
740         popq %rdx
741         popq %rbp
742         popq %rsi
743         popq %rdi
744         popq %r8
745         popq %r9
746         popq %r10
747         popq %r11
748         popq %r12
749         popq %r13
750         popq %r14
751         popq %r15
752         addq $0x10, %rsp                # skip trapno and err
753         # Here's is where we differ from OK.  Time to undo everything and return
754         # rsp currently is pointing at tf->tf_rip.  Remember that we don't want to
755         # write anything to the stack - everything in the TF is still the way it was
756         # when we started to pop.
757         #
758         # First off, let's get the stack addr of the pcpui pointer loaded
759         movq %rsp, %rbx
760         movq $0xfff, %rax
761         notq %rax                               # rax = 0xfffffffffffff000
762         andq %rax, %rbx                 # round down rbx
763         addq $0x1000, %rbx              # add PGSIZE, assuming rsp was not page aligned
764         subq $0x10, %rbx                # point to the pcpui pointer
765         # Now let's start to unwind
766         subq $0x98, %rsp                # jump from rip to tf_gsbase (top of hw_tf)
767         # Need to restore gs, just like on an NMI entry
768         cmpw $GD_KT, 0xa0(%rsp) # 0xa0 - diff btw tf_cs and tf_gsbase
769         je nmi_pop_fail_kern_tf
770         # This is a user TF.  We need to swapgs to get the kernel's gs
771         # We don't need to mark the context as partial (we never do for NMIs,
772         # actually), and in general, we don't want to write anything on the stack.
773         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
774         jmp nmi_pop_fail_all_tf
775 nmi_pop_fail_kern_tf:
776         # Kernel TF.  We basically need to do the same thing on entry, since we
777         # might have restored some weird GS base.  We can tell based on tf_gsbase
778         # 0 for gsbase means we didn't need to change GS
779         cmpq $0, (%rsp)
780         je nmi_pop_fail_gs_fine
781         # rbx points to where pcpui* is stored
782         mov (%rbx), %rdx
783         movl $MSR_GS_BASE, %ecx
784         movq %rdx, %rax
785         shrq $32, %rdx
786         andl $0xffffffff, %eax
787         wrmsr
788 nmi_pop_fail_gs_fine:
789 nmi_pop_fail_all_tf:
790         addq $0x8, %rbx                 # move to the scratch slot, holding rsp
791         mov (%rbx), %rsp
792         # restore callee-saved regs
793         popq %r15
794         popq %r14
795         popq %r13
796         popq %r12
797         popq %rbx
798         popq %rbp
799         ret
800         # sweet jeebus.
801 __nmi_pop_fail_end:
802
803
804 .globl sysenter_handler;
805 .type sysenter_handler, @function;
806
807 sysenter_handler:
808 #ifndef CONFIG_NOFASTCALL_FSBASE
809         # Do a quick TLS / FS base change, never changing stacks.
810         # When rdi has the magic number, rsi has the new base
811         movabs $FASTCALL_SETFSBASE, %rax
812         cmp %rax, %rdi
813         jne normal_syscall      # could profile this and handle the jump differently
814         # need to check rsi, make sure it is canonical (will enfore below ULIM).
815         # need to either do this check, or handle the kernel GP fault on wrmsr.
816         movq %rsi, %rdi
817         shrq $47, %rdi
818         cmp $0, %rdi
819         jne fastcall_pop
820         # need to use cx, dx, and ax for the wrmsr.  dx and ax are free.
821         movq %rcx, %rdi         # save rcx, the retaddr
822         movq %rsi, %rdx
823         movq %rsi, %rax
824         shrq $32, %rdx
825         andl $0xffffffff, %eax
826         movl $MSR_FS_BASE, %ecx
827         wrmsr
828         movq %rdi, %rcx         # restore retaddr
829 fastcall_pop:
830         rex.w sysret
831 normal_syscall:
832 #endif
833         # cld is handled by the SFMASK
834         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
835         movq %gs:0, %rsp
836         # Saving the FPU callee-saved state for now.  Might be able to have the
837         # preempt handler deal with it.
838         pushq $0                                # space for mxcsr, fpucw, and padding0
839         movw $0x1, 0x6(%rsp)    # tf_padding0 = 1, partial context
840         fnstcw 0x4(%rsp)
841         stmxcsr (%rsp)
842         pushq %rdx                      # rsp, saved by userspace
843         pushq %rcx                      # rip, saved by hardware
844         pushq %r15
845         pushq %r14
846         pushq %r13
847         pushq %r12
848         pushq %rbp
849         pushq %rbx
850         pushq $0                        # fsbase space
851         pushq $0                        # gsbase space
852         movq $0, %rbp                   # so we can backtrace to this point
853         movq %rsp, %rdx
854         # arg0, rdi: struct sysc*.  arg1, rsi: count.  arg2, rdx: sw_tf
855         call sysenter_callwrapper
856         # return via pop_tf, never this path
857 sysenter_spin:
858         jmp sysenter_spin
859
860 .globl vmexit_handler;
861 .type vmexit_handler, @function;
862 vmexit_handler:
863         # rflags has all flags = 0, so cli and cld already.
864         # HOST_GS_BASE and RSP is set by the hardware
865         # Set default values.  Most of these will be set in C later.
866         pushq $0                        # guest_pa
867         pushq $0                        # guest_va
868         pushq $0                        # intrinfo2 and 1
869         pushq $0                        # exit_qual + exit_reason
870         pushq $0                        # pad + trap_inject
871         pushq $0                        # flags + guest_pcorid
872         pushq $0                        # cr3
873         pushq $0                        # cr2
874         pushq $0                        # rsp
875         pushq $0                        # rflags
876         pushq $0                        # rip
877         # Save register state
878         pushq %r15
879         pushq %r14
880         pushq %r13
881         pushq %r12
882         pushq %r11
883         pushq %r10
884         pushq %r9
885         pushq %r8
886         pushq %rdi
887         pushq %rsi
888         pushq %rbp
889         pushq %rdx
890         pushq %rcx
891         pushq %rbx
892         pushq %rax
893         movq $0, %rbp                   # so we can backtrace to this point
894         movq %rsp, %rdi
895         call handle_vmexit
896 vmexit_spin:
897         jmp vmexit_spin