BXE: min->MIN, plus an spatch
[akaros.git] / kern / arch / x86 / trapentry64.S
1 /* See COPYRIGHT for copyright information.
2  * The two TRAP* macros (minus the .data parts) are from the JOS project.
3  * Everything else:
4  * Copyright (c) 2009, 2013 The Regents of the University of California
5  * Barret Rhoden <brho@cs.berkeley.edu>
6  * See LICENSE for details.
7  */
8 #include <arch/mmu.h>
9 #include <arch/trap.h>
10 #include <arch/x86.h>
11 #include <ros/memlayout.h>
12
13 ###################################################################
14 # exceptions/interrupts
15 ###################################################################
16
17 /* The TRAPHANDLER macro defines a globally-visible function for handling
18  * a trap.  It pushes a trap number onto the stack, then jumps to _alltraps.
19  * It also builds this traps portion of the trap_tbl.
20  * Use TRAPHANDLER for traps where the CPU automatically pushes an error code.
21  */
22 #define TRAPHANDLER(name, num)                                                                  \
23         .text;                                                                                                          \
24         .globl name;            /* define global symbol for 'name' */   \
25         .type name, @function;  /* symbol type is function */           \
26         .align 2;               /* align function definition */                         \
27         name:                   /* function starts here */                                      \
28         pushq $(num);                                                                                           \
29         jmp _alltraps;                                                                                          \
30         .data;                                                                                                          \
31         .quad name;                                                                                                     \
32         .long num
33
34 /* Use TRAPHANDLER_NOEC for traps where the CPU doesn't push an error code.
35  * It pushes a 0 in place of the error code, so the trap frame has the same
36  * format in either case.  */
37 #define TRAPHANDLER_NOEC(name, num)             \
38         .text;                                                          \
39         .globl name;                                            \
40         .type name, @function;                          \
41         .align 2;                                                       \
42         name:                                                           \
43         pushq $0;                                                       \
44         pushq $(num);                                           \
45         jmp _alltraps;                                          \
46         .data;                                                          \
47         .quad name;                                                     \
48         .long num
49
50 /* Same as NOEC, but for IRQs instead.  num is the ISR number it is mapped to */
51 #define IRQ_HANDLER(name, num)                  \
52         .text;                                                          \
53         .globl name;                                            \
54         .type name, @function;                          \
55         .align 2;                                                       \
56         name:                                                           \
57         pushq $0;                                                       \
58         pushq $(num);                                           \
59         jmp _allirqs;                                           \
60         .data;                                                          \
61         .quad name;                                                     \
62         .long num
63
64 /* Only used in the kernel during SMP boot.  Send a LAPIC_EOI and iret. */
65 #define POKE_HANDLER(name, num)                 \
66         .text;                                                          \
67         .globl name;                                            \
68         .type name, @function;                          \
69         .align 2;                                                       \
70         name:;                                                          \
71         movl $0, (LAPIC_BASE + 0x0b0);      \
72         iretq;                                                          \
73         .data;                                                          \
74         .quad name;                                                     \
75         .long num
76
77 .data
78 .globl trap_tbl
79 trap_tbl:
80
81 /* Generate entry points for the different traps.  Note that all of these bounce
82  * off the corresponding trap.c function, such as handle_irqs, and that the name
83  * e.g. ISR_NMI is soley for the little stup that jumps to something like
84  * _alltraps.
85  *
86  * Technically, these HANDLER entries do not need to be in numeric order.
87  * trap.c will do a 'foreach (up to last-1), set the IDT for the number to point
88  * to the func' in the order in which they appear in the trap tbl, so the 'last
89  * one wins'. */
90 TRAPHANDLER_NOEC(ISR_divide_error, T_DIVIDE)
91 TRAPHANDLER_NOEC(ISR_debug_exceptions, T_DEBUG)
92 TRAPHANDLER_NOEC(ISR_NMI, T_NMI)
93 TRAPHANDLER_NOEC(ISR_breakpoint, T_BRKPT)
94 TRAPHANDLER_NOEC(ISR_overflow, T_OFLOW)
95 TRAPHANDLER_NOEC(ISR_bounds_check, T_BOUND)
96 TRAPHANDLER_NOEC(ISR_invalid_opcode, T_ILLOP)
97 TRAPHANDLER_NOEC(ISR_device_not_available, T_DEVICE)
98 /* supposedly, DF generates an error code, but the one time we've had a DF so
99  * far, it didn't.  eventually, this should probably be handled with a task gate
100  * it might have pushed a 0, but just the rest of the stack was corrupt
101  */
102 TRAPHANDLER_NOEC(ISR_double_fault, T_DBLFLT)
103 /* 9 reserved */
104 TRAPHANDLER(ISR_invalid_TSS, T_TSS)
105 TRAPHANDLER(ISR_segment_not_present, T_SEGNP)
106 TRAPHANDLER(ISR_stack_exception, T_STACK)
107 TRAPHANDLER(ISR_general_protection_fault, T_GPFLT)
108 TRAPHANDLER(ISR_page_fault, T_PGFLT)
109 /* 15 reserved */
110 TRAPHANDLER_NOEC(ISR_floating_point_error, T_FPERR)
111 TRAPHANDLER(ISR_alignment_check, T_ALIGN)
112 TRAPHANDLER_NOEC(ISR_machine_check, T_MCHK)
113 TRAPHANDLER_NOEC(ISR_simd_error, T_SIMDERR)
114 /* 20 - 31 reserved */
115 /* 32-47 are PIC/8259 IRQ vectors */
116 IRQ_HANDLER(IRQ0, 32)
117 IRQ_HANDLER(IRQ1, 33)
118 IRQ_HANDLER(IRQ2, 34)
119 IRQ_HANDLER(IRQ3, 35)
120 IRQ_HANDLER(IRQ4, 36)
121 IRQ_HANDLER(IRQ5, 37)
122 IRQ_HANDLER(IRQ6, 38)
123 IRQ_HANDLER(IRQ7, 39)
124 IRQ_HANDLER(IRQ8, 40)
125 IRQ_HANDLER(IRQ9, 41)
126 IRQ_HANDLER(IRQ10, 42)
127 IRQ_HANDLER(IRQ11, 43)
128 IRQ_HANDLER(IRQ12, 44)
129 IRQ_HANDLER(IRQ13, 45)
130 IRQ_HANDLER(IRQ14, 46)
131 IRQ_HANDLER(IRQ15, 47)
132 TRAPHANDLER_NOEC(ISR_syscall, T_SYSCALL)
133 /* 49-223 are IOAPIC routing vectors (from IOAPIC to LAPIC) */
134 IRQ_HANDLER(IRQ17, 49)
135 IRQ_HANDLER(IRQ18, 50)
136 IRQ_HANDLER(IRQ19, 51)
137 IRQ_HANDLER(IRQ20, 52)
138 IRQ_HANDLER(IRQ21, 53)
139 IRQ_HANDLER(IRQ22, 54)
140 IRQ_HANDLER(IRQ23, 55)
141 IRQ_HANDLER(IRQ24, 56)
142 IRQ_HANDLER(IRQ25, 57)
143 IRQ_HANDLER(IRQ26, 58)
144 IRQ_HANDLER(IRQ27, 59)
145 IRQ_HANDLER(IRQ28, 60)
146 IRQ_HANDLER(IRQ29, 61)
147 IRQ_HANDLER(IRQ30, 62)
148 IRQ_HANDLER(IRQ31, 63)
149 IRQ_HANDLER(IRQ32, 64)
150 IRQ_HANDLER(IRQ33, 65)
151 IRQ_HANDLER(IRQ34, 66)
152 IRQ_HANDLER(IRQ35, 67)
153 IRQ_HANDLER(IRQ36, 68)
154 IRQ_HANDLER(IRQ37, 69)
155 IRQ_HANDLER(IRQ38, 70)
156 IRQ_HANDLER(IRQ39, 71)
157 IRQ_HANDLER(IRQ40, 72)
158 IRQ_HANDLER(IRQ41, 73)
159 IRQ_HANDLER(IRQ42, 74)
160 IRQ_HANDLER(IRQ43, 75)
161 IRQ_HANDLER(IRQ44, 76)
162 IRQ_HANDLER(IRQ45, 77)
163 IRQ_HANDLER(IRQ46, 78)
164 IRQ_HANDLER(IRQ47, 79)
165 IRQ_HANDLER(IRQ48, 80)
166 IRQ_HANDLER(IRQ49, 81)
167 IRQ_HANDLER(IRQ50, 82)
168 IRQ_HANDLER(IRQ51, 83)
169 IRQ_HANDLER(IRQ52, 84)
170 IRQ_HANDLER(IRQ53, 85)
171 IRQ_HANDLER(IRQ54, 86)
172 IRQ_HANDLER(IRQ55, 87)
173 IRQ_HANDLER(IRQ56, 88)
174 IRQ_HANDLER(IRQ57, 89)
175 IRQ_HANDLER(IRQ58, 90)
176 IRQ_HANDLER(IRQ59, 91)
177 IRQ_HANDLER(IRQ60, 92)
178 IRQ_HANDLER(IRQ61, 93)
179 IRQ_HANDLER(IRQ62, 94)
180 IRQ_HANDLER(IRQ63, 95)
181 IRQ_HANDLER(IRQ64, 96)
182 IRQ_HANDLER(IRQ65, 97)
183 IRQ_HANDLER(IRQ66, 98)
184 IRQ_HANDLER(IRQ67, 99)
185 IRQ_HANDLER(IRQ68, 100)
186 IRQ_HANDLER(IRQ69, 101)
187 IRQ_HANDLER(IRQ70, 102)
188 IRQ_HANDLER(IRQ71, 103)
189 IRQ_HANDLER(IRQ72, 104)
190 IRQ_HANDLER(IRQ73, 105)
191 IRQ_HANDLER(IRQ74, 106)
192 IRQ_HANDLER(IRQ75, 107)
193 IRQ_HANDLER(IRQ76, 108)
194 IRQ_HANDLER(IRQ77, 109)
195 IRQ_HANDLER(IRQ78, 110)
196 IRQ_HANDLER(IRQ79, 111)
197 IRQ_HANDLER(IRQ80, 112)
198 IRQ_HANDLER(IRQ81, 113)
199 IRQ_HANDLER(IRQ82, 114)
200 IRQ_HANDLER(IRQ83, 115)
201 IRQ_HANDLER(IRQ84, 116)
202 IRQ_HANDLER(IRQ85, 117)
203 IRQ_HANDLER(IRQ86, 118)
204 IRQ_HANDLER(IRQ87, 119)
205 IRQ_HANDLER(IRQ88, 120)
206 IRQ_HANDLER(IRQ89, 121)
207 IRQ_HANDLER(IRQ90, 122)
208 IRQ_HANDLER(IRQ91, 123)
209 IRQ_HANDLER(IRQ92, 124)
210 IRQ_HANDLER(IRQ93, 125)
211 IRQ_HANDLER(IRQ94, 126)
212 IRQ_HANDLER(IRQ95, 127)
213 IRQ_HANDLER(IRQ96, 128)
214 IRQ_HANDLER(IRQ97, 129)
215 IRQ_HANDLER(IRQ98, 130)
216 IRQ_HANDLER(IRQ99, 131)
217 IRQ_HANDLER(IRQ100, 132)
218 IRQ_HANDLER(IRQ101, 133)
219 IRQ_HANDLER(IRQ102, 134)
220 IRQ_HANDLER(IRQ103, 135)
221 IRQ_HANDLER(IRQ104, 136)
222 IRQ_HANDLER(IRQ105, 137)
223 IRQ_HANDLER(IRQ106, 138)
224 IRQ_HANDLER(IRQ107, 139)
225 IRQ_HANDLER(IRQ108, 140)
226 IRQ_HANDLER(IRQ109, 141)
227 IRQ_HANDLER(IRQ110, 142)
228 IRQ_HANDLER(IRQ111, 143)
229 IRQ_HANDLER(IRQ112, 144)
230 IRQ_HANDLER(IRQ113, 145)
231 IRQ_HANDLER(IRQ114, 146)
232 IRQ_HANDLER(IRQ115, 147)
233 IRQ_HANDLER(IRQ116, 148)
234 IRQ_HANDLER(IRQ117, 149)
235 IRQ_HANDLER(IRQ118, 150)
236 IRQ_HANDLER(IRQ119, 151)
237 IRQ_HANDLER(IRQ120, 152)
238 IRQ_HANDLER(IRQ121, 153)
239 IRQ_HANDLER(IRQ122, 154)
240 IRQ_HANDLER(IRQ123, 155)
241 IRQ_HANDLER(IRQ124, 156)
242 IRQ_HANDLER(IRQ125, 157)
243 IRQ_HANDLER(IRQ126, 158)
244 IRQ_HANDLER(IRQ127, 159)
245 IRQ_HANDLER(IRQ128, 160)
246 IRQ_HANDLER(IRQ129, 161)
247 IRQ_HANDLER(IRQ130, 162)
248 IRQ_HANDLER(IRQ131, 163)
249 IRQ_HANDLER(IRQ132, 164)
250 IRQ_HANDLER(IRQ133, 165)
251 IRQ_HANDLER(IRQ134, 166)
252 IRQ_HANDLER(IRQ135, 167)
253 IRQ_HANDLER(IRQ136, 168)
254 IRQ_HANDLER(IRQ137, 169)
255 IRQ_HANDLER(IRQ138, 170)
256 IRQ_HANDLER(IRQ139, 171)
257 IRQ_HANDLER(IRQ140, 172)
258 IRQ_HANDLER(IRQ141, 173)
259 IRQ_HANDLER(IRQ142, 174)
260 IRQ_HANDLER(IRQ143, 175)
261 IRQ_HANDLER(IRQ144, 176)
262 IRQ_HANDLER(IRQ145, 177)
263 IRQ_HANDLER(IRQ146, 178)
264 IRQ_HANDLER(IRQ147, 179)
265 IRQ_HANDLER(IRQ148, 180)
266 IRQ_HANDLER(IRQ149, 181)
267 IRQ_HANDLER(IRQ150, 182)
268 IRQ_HANDLER(IRQ151, 183)
269 IRQ_HANDLER(IRQ152, 184)
270 IRQ_HANDLER(IRQ153, 185)
271 IRQ_HANDLER(IRQ154, 186)
272 IRQ_HANDLER(IRQ155, 187)
273 IRQ_HANDLER(IRQ156, 188)
274 IRQ_HANDLER(IRQ157, 189)
275 IRQ_HANDLER(IRQ158, 190)
276 IRQ_HANDLER(IRQ159, 191)
277 IRQ_HANDLER(IRQ160, 192)
278 IRQ_HANDLER(IRQ161, 193)
279 IRQ_HANDLER(IRQ162, 194)
280 IRQ_HANDLER(IRQ163, 195)
281 IRQ_HANDLER(IRQ164, 196)
282 IRQ_HANDLER(IRQ165, 197)
283 IRQ_HANDLER(IRQ166, 198)
284 IRQ_HANDLER(IRQ167, 199)
285 IRQ_HANDLER(IRQ168, 200)
286 IRQ_HANDLER(IRQ169, 201)
287 IRQ_HANDLER(IRQ170, 202)
288 IRQ_HANDLER(IRQ171, 203)
289 IRQ_HANDLER(IRQ172, 204)
290 IRQ_HANDLER(IRQ173, 205)
291 IRQ_HANDLER(IRQ174, 206)
292 IRQ_HANDLER(IRQ175, 207)
293 IRQ_HANDLER(IRQ176, 208)
294 IRQ_HANDLER(IRQ177, 209)
295 IRQ_HANDLER(IRQ178, 210)
296 IRQ_HANDLER(IRQ179, 211)
297 IRQ_HANDLER(IRQ180, 212)
298 IRQ_HANDLER(IRQ181, 213)
299 IRQ_HANDLER(IRQ182, 214)
300 IRQ_HANDLER(IRQ183, 215)
301 IRQ_HANDLER(IRQ184, 216)
302 IRQ_HANDLER(IRQ185, 217)
303 IRQ_HANDLER(IRQ186, 218)
304 IRQ_HANDLER(IRQ187, 219)
305 IRQ_HANDLER(IRQ188, 220)
306 IRQ_HANDLER(IRQ189, 221)
307 IRQ_HANDLER(IRQ190, 222)
308 IRQ_HANDLER(IRQ191, 223)
309 /* 224-239 are OS IPI vectors (0xe0-0xef) */
310 IRQ_HANDLER(IRQ192, I_SMP_CALL0)
311 IRQ_HANDLER(IRQ193, I_SMP_CALL1)
312 IRQ_HANDLER(IRQ194, I_SMP_CALL2)
313 IRQ_HANDLER(IRQ195, I_SMP_CALL3)
314 IRQ_HANDLER(IRQ196, I_SMP_CALL4)
315 IRQ_HANDLER(IRQ197, 229)
316 IRQ_HANDLER(IRQ198, 230)
317 IRQ_HANDLER(IRQ199, 231)
318 IRQ_HANDLER(IRQ200, 232)
319 IRQ_HANDLER(IRQ201, 233)
320 IRQ_HANDLER(IRQ202, 234)
321 IRQ_HANDLER(IRQ203, 235)
322 IRQ_HANDLER(IRQ204, 236)
323 IRQ_HANDLER(IRQ205, I_TESTING)
324 POKE_HANDLER(IRQ206, I_POKE_CORE)
325 IRQ_HANDLER(IRQ207, I_KERNEL_MSG)
326 /* 240-255 are LAPIC vectors (0xf0-0xff), hightest priority class */
327 IRQ_HANDLER(IRQ208, 240)
328 IRQ_HANDLER(IRQ209, 241)
329 IRQ_HANDLER(IRQ210, 242)
330 IRQ_HANDLER(IRQ211, 243)
331 IRQ_HANDLER(IRQ212, 244)
332 IRQ_HANDLER(IRQ213, 245)
333 IRQ_HANDLER(IRQ214, 246)
334 IRQ_HANDLER(IRQ215, 247)
335 IRQ_HANDLER(IRQ216, 248)
336 IRQ_HANDLER(IRQ217, 249)
337 IRQ_HANDLER(IRQ218, 250)
338 IRQ_HANDLER(IRQ219, 251)
339 IRQ_HANDLER(IRQ220, 252)
340 IRQ_HANDLER(IRQ221, 253)
341 IRQ_HANDLER(IRQ222, 254)
342 IRQ_HANDLER(IRQ223, 255)
343 /* But make sure default is last!! */
344 TRAPHANDLER_NOEC(ISR_default, T_DEFAULT)
345
346 .data
347 .globl trap_tbl_end
348 trap_tbl_end:
349
350 .text
351 _alltraps:
352         cld
353         swapgs                  # harmless if we were already in the kernel
354         pushq %r15
355         pushq %r14
356         pushq %r13
357         pushq %r12
358         pushq %r11
359         pushq %r10
360         pushq %r9
361         pushq %r8
362         pushq %rdi
363         pushq %rsi
364         pushq %rbp
365         pushq %rdx
366         pushq %rcx
367         pushq %rbx
368         pushq %rax
369         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
370         je trap_kernel_tf
371         # this is a user TF, so we need to save their fs/gsbase and load gs base for
372         # the kernel.
373         movl $MSR_FS_BASE, %ecx
374         rdmsr
375         shl $32, %rdx
376         orq %rax, %rdx
377         pushq %rdx
378         # because we swapped gs earlier, the user GS is now in KERN_GS_BASE
379         movl $MSR_KERN_GS_BASE, %ecx
380         rdmsr
381         shl $32, %rdx
382         orq %rax, %rdx
383         pushq %rdx
384         # make sure the kernel's gs base is loaded into the KERN slot at all times
385         movl $MSR_GS_BASE, %ecx
386         rdmsr
387         movl $MSR_KERN_GS_BASE, %ecx
388         wrmsr
389         jmp trap_all_tf
390 trap_kernel_tf:
391         # we don't muck with fs/gsbase, push placeholders
392         movq $0xdeadbeef, %rax
393         pushq %rax
394         pushq %rax
395 trap_all_tf:
396         movq $0, %rbp                   # so we can backtrace to this point
397         movq %rsp, %rdi
398         call trap
399         # the return paths are only used by the kernel
400         addq $0x10, %rsp                        # skip fs/gs base
401         popq %rax
402         popq %rbx
403         popq %rcx
404         popq %rdx
405         popq %rbp
406         popq %rsi
407         popq %rdi
408         popq %r8
409         popq %r9
410         popq %r10
411         popq %r11
412         popq %r12
413         popq %r13
414         popq %r14
415         popq %r15
416         addq $0x10, %rsp                        # skip trapno and err
417         iretq
418
419 # might merge this with _alltraps
420 _allirqs:
421         cld
422         swapgs                  # harmless if we were already in the kernel
423         pushq %r15
424         pushq %r14
425         pushq %r13
426         pushq %r12
427         pushq %r11
428         pushq %r10
429         pushq %r9
430         pushq %r8
431         pushq %rdi
432         pushq %rsi
433         pushq %rbp
434         pushq %rdx
435         pushq %rcx
436         pushq %rbx
437         pushq %rax
438         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
439         je irq_kernel_tf
440         # this is a user TF, so we need to save their fs/gsbase and load gs base for
441         # the kernel.
442         movl $MSR_FS_BASE, %ecx
443         rdmsr
444         shl $32, %rdx
445         orq %rax, %rdx
446         pushq %rdx
447         # because we swapped gs earlier, the user GS is now in KERN_GS_BASE
448         movl $MSR_KERN_GS_BASE, %ecx
449         rdmsr
450         shl $32, %rdx
451         orq %rax, %rdx
452         pushq %rdx
453         # make sure the kernel's gs base is loaded into the KERN slot at all times
454         movl $MSR_GS_BASE, %ecx
455         rdmsr
456         movl $MSR_KERN_GS_BASE, %ecx
457         wrmsr
458         jmp irq_all_tf
459 irq_kernel_tf:
460         # we don't muck with fs/gsbase, push placeholders
461         movq $0xdeadbeef, %rax
462         pushq %rax
463         pushq %rax
464 irq_all_tf:
465         movq $0, %rbp                   # so we can backtrace to this point
466         movq %rsp, %rdi
467         call handle_irq
468         # the return paths are only used by the kernel
469         addq $0x10, %rsp                        # skip fs/gs base
470         popq %rax
471         popq %rbx
472         popq %rcx
473         popq %rdx
474         popq %rbp
475         popq %rsi
476         popq %rdi
477         popq %r8
478         popq %r9
479         popq %r10
480         popq %r11
481         popq %r12
482         popq %r13
483         popq %r14
484         popq %r15
485         addq $0x10, %rsp                        # skip trapno and err
486         iretq
487
488 .globl sysenter_handler;
489 .type sysenter_handler, @function;
490
491 sysenter_handler:
492 #ifndef CONFIG_NOFASTCALL_FSBASE
493         # Do a quick TLS / FS base change, never changing stacks.
494         # When rdi has the magic number, rsi has the new base
495         movabs $FASTCALL_SETFSBASE, %rax
496         cmp %rax, %rdi
497         jne normal_syscall      # could profile this and handle the jump differently
498         # need to check rsi, make sure it is canonical (will enfore below ULIM).
499         # need to either do this check, or handle the kernel GP fault on wrmsr.
500         movq %rsi, %rdi
501         shrq $47, %rdi
502         cmp $0, %rdi
503         jne fastcall_pop
504         # need to use cx, dx, and ax for the wrmsr.  dx and ax are free.
505         movq %rcx, %rdi         # save rcx, the retaddr
506         movq %rsi, %rdx
507         movq %rsi, %rax
508         shrq $32, %rdx
509         andl $0xffffffff, %eax
510         movl $MSR_FS_BASE, %ecx
511         wrmsr
512         movq %rdi, %rcx         # restore retaddr
513 fastcall_pop:
514         rex.w sysret
515 normal_syscall:
516 #endif
517         # cld is handled by the SFMASK
518         swapgs
519         movq %gs:0, %rsp
520         # Saving the FPU callee-saved state for now.  Might be able to have the
521         # preempt handler deal with it.
522         pushq $0                        # space for mxcsr and fpucw
523         fnstcw 0x4(%rsp)
524         stmxcsr (%rsp)
525         pushq %rdx                      # rsp, saved by userspace
526         pushq %rcx                      # rip, saved by hardware
527         pushq %r15
528         pushq %r14
529         pushq %r13
530         pushq %r12
531         pushq %rbp
532         pushq %rbx
533         # save fs and gs base
534         movl $MSR_FS_BASE, %ecx
535         rdmsr
536         shl $32, %rdx
537         orq %rax, %rdx
538         pushq %rdx
539         # because we swapped gs earlier, the user GS is now in KERN_GS_BASE
540         movl $MSR_KERN_GS_BASE, %ecx
541         rdmsr
542         shl $32, %rdx
543         orq %rax, %rdx
544         pushq %rdx
545         # make sure the kernel's gs base is loaded into the KERN slot at all times
546         movl $MSR_GS_BASE, %ecx
547         rdmsr
548         movl $MSR_KERN_GS_BASE, %ecx
549         wrmsr
550         movq $0, %rbp                   # so we can backtrace to this point
551         movq %rsp, %rdx
552         # arg0, rdi: struct sysc*.  arg1, rsi: count.  arg2, rdx: sw_tf
553         call sysenter_callwrapper
554         # return via pop_tf, never this path
555 sysenter_spin:
556         jmp sysenter_spin