Enabling X2APIC
[akaros.git] / kern / arch / x86 / trapentry64.S
1 /* See COPYRIGHT for copyright information.
2  * The two TRAP* macros (minus the .data parts) are from the JOS project.
3  * Everything else:
4  * Copyright (c) 2009, 2013 The Regents of the University of California
5  * Barret Rhoden <brho@cs.berkeley.edu>
6  * See LICENSE for details.
7  */
8 #include <arch/mmu.h>
9 #include <arch/trap.h>
10 #include <arch/x86.h>
11 #include <ros/memlayout.h>
12
13 ###################################################################
14 # exceptions/interrupts
15 ###################################################################
16
17 /* The TRAPHANDLER macro defines a globally-visible function for handling
18  * a trap.  It pushes a trap number onto the stack, then jumps to _alltraps.
19  * It also builds this traps portion of the trap_tbl.
20  * Use TRAPHANDLER for traps where the CPU automatically pushes an error code.
21  */
22 #define TRAPHANDLER(name, num)                                                                  \
23         .text;                                                                                                          \
24         .globl name;            /* define global symbol for 'name' */   \
25         .type name, @function;  /* symbol type is function */           \
26         .align 2;               /* align function definition */                         \
27         name:                   /* function starts here */                                      \
28         pushq $(num);                                                                                           \
29         jmp _alltraps;                                                                                          \
30         .data;                                                                                                          \
31         .quad name;                                                                                                     \
32         .long num
33
34 /* Use TRAPHANDLER_NOEC for traps where the CPU doesn't push an error code.
35  * It pushes a 0 in place of the error code, so the trap frame has the same
36  * format in either case.  */
37 #define TRAPHANDLER_NOEC(name, num)             \
38         .text;                                                          \
39         .globl name;                                            \
40         .type name, @function;                          \
41         .align 2;                                                       \
42         name:                                                           \
43         pushq $0;                                                       \
44         pushq $(num);                                           \
45         jmp _alltraps;                                          \
46         .data;                                                          \
47         .quad name;                                                     \
48         .long num
49
50 /* Same as NOEC, but for IRQs instead.  num is the ISR number it is mapped to */
51 #define IRQ_HANDLER(name, num)                  \
52         .text;                                                          \
53         .globl name;                                            \
54         .type name, @function;                          \
55         .align 2;                                                       \
56         name:                                                           \
57         pushq $0;                                                       \
58         pushq $(num);                                           \
59         jmp _allirqs;                                           \
60         .data;                                                          \
61         .quad name;                                                     \
62         .long num
63
64 /* Only used in the kernel during SMP boot.  Send a LAPIC_EOI and iret. */
65 #define POKE_HANDLER(name, num)                 \
66         .text;                                                          \
67         .globl name;                                            \
68         .type name, @function;                          \
69         .align 2;                                                       \
70         name:;                                                          \
71         pushq %rax;                     \
72         pushq %rcx;                     \
73         pushq %rdx;                     \
74         movq $0, %rax;                  \
75         movq $0, %rdx;                  \
76         movq $(MSR_LAPIC_EOI), %rcx;    \
77         wrmsr;                          \
78         popq %rdx;                      \
79         popq %rcx;                      \
80         popq %rax;                      \
81         iretq;                                                          \
82         .data;                                                          \
83         .quad name;                                                     \
84         .long num
85
86 .data
87 .globl trap_tbl
88 trap_tbl:
89
90 /* Generate entry points for the different traps.  Note that all of these bounce
91  * off the corresponding trap.c function, such as handle_irqs, and that the name
92  * e.g. ISR_NMI is soley for the little stup that jumps to something like
93  * _alltraps.
94  *
95  * Technically, these HANDLER entries do not need to be in numeric order.
96  * trap.c will do a 'foreach (up to last-1), set the IDT for the number to point
97  * to the func' in the order in which they appear in the trap tbl, so the 'last
98  * one wins'. */
99 TRAPHANDLER_NOEC(ISR_divide_error, T_DIVIDE)
100 TRAPHANDLER_NOEC(ISR_debug_exceptions, T_DEBUG)
101 TRAPHANDLER_NOEC(ISR_NMI, T_NMI)
102 TRAPHANDLER_NOEC(ISR_breakpoint, T_BRKPT)
103 TRAPHANDLER_NOEC(ISR_overflow, T_OFLOW)
104 TRAPHANDLER_NOEC(ISR_bounds_check, T_BOUND)
105 TRAPHANDLER_NOEC(ISR_invalid_opcode, T_ILLOP)
106 TRAPHANDLER_NOEC(ISR_device_not_available, T_DEVICE)
107 /* supposedly, DF generates an error code, but the one time we've had a DF so
108  * far, it didn't.  eventually, this should probably be handled with a task gate
109  * it might have pushed a 0, but just the rest of the stack was corrupt
110  */
111 TRAPHANDLER_NOEC(ISR_double_fault, T_DBLFLT)
112 /* 9 reserved */
113 TRAPHANDLER(ISR_invalid_TSS, T_TSS)
114 TRAPHANDLER(ISR_segment_not_present, T_SEGNP)
115 TRAPHANDLER(ISR_stack_exception, T_STACK)
116 TRAPHANDLER(ISR_general_protection_fault, T_GPFLT)
117 TRAPHANDLER(ISR_page_fault, T_PGFLT)
118 /* 15 reserved */
119 TRAPHANDLER_NOEC(ISR_floating_point_error, T_FPERR)
120 TRAPHANDLER(ISR_alignment_check, T_ALIGN)
121 TRAPHANDLER_NOEC(ISR_machine_check, T_MCHK)
122 TRAPHANDLER_NOEC(ISR_simd_error, T_SIMDERR)
123 /* 20 - 31 reserved */
124 /* 32-47 are PIC/8259 IRQ vectors */
125 IRQ_HANDLER(IRQ0, 32)
126 IRQ_HANDLER(IRQ1, 33)
127 IRQ_HANDLER(IRQ2, 34)
128 IRQ_HANDLER(IRQ3, 35)
129 IRQ_HANDLER(IRQ4, 36)
130 IRQ_HANDLER(IRQ5, 37)
131 IRQ_HANDLER(IRQ6, 38)
132 IRQ_HANDLER(IRQ7, 39)
133 IRQ_HANDLER(IRQ8, 40)
134 IRQ_HANDLER(IRQ9, 41)
135 IRQ_HANDLER(IRQ10, 42)
136 IRQ_HANDLER(IRQ11, 43)
137 IRQ_HANDLER(IRQ12, 44)
138 IRQ_HANDLER(IRQ13, 45)
139 IRQ_HANDLER(IRQ14, 46)
140 IRQ_HANDLER(IRQ15, 47)
141 TRAPHANDLER_NOEC(ISR_syscall, T_SYSCALL)
142 /* 49-223 are IOAPIC routing vectors (from IOAPIC to LAPIC) */
143 IRQ_HANDLER(IRQ17, 49)
144 IRQ_HANDLER(IRQ18, 50)
145 IRQ_HANDLER(IRQ19, 51)
146 IRQ_HANDLER(IRQ20, 52)
147 IRQ_HANDLER(IRQ21, 53)
148 IRQ_HANDLER(IRQ22, 54)
149 IRQ_HANDLER(IRQ23, 55)
150 IRQ_HANDLER(IRQ24, 56)
151 IRQ_HANDLER(IRQ25, 57)
152 IRQ_HANDLER(IRQ26, 58)
153 IRQ_HANDLER(IRQ27, 59)
154 IRQ_HANDLER(IRQ28, 60)
155 IRQ_HANDLER(IRQ29, 61)
156 IRQ_HANDLER(IRQ30, 62)
157 IRQ_HANDLER(IRQ31, 63)
158 IRQ_HANDLER(IRQ32, 64)
159 IRQ_HANDLER(IRQ33, 65)
160 IRQ_HANDLER(IRQ34, 66)
161 IRQ_HANDLER(IRQ35, 67)
162 IRQ_HANDLER(IRQ36, 68)
163 IRQ_HANDLER(IRQ37, 69)
164 IRQ_HANDLER(IRQ38, 70)
165 IRQ_HANDLER(IRQ39, 71)
166 IRQ_HANDLER(IRQ40, 72)
167 IRQ_HANDLER(IRQ41, 73)
168 IRQ_HANDLER(IRQ42, 74)
169 IRQ_HANDLER(IRQ43, 75)
170 IRQ_HANDLER(IRQ44, 76)
171 IRQ_HANDLER(IRQ45, 77)
172 IRQ_HANDLER(IRQ46, 78)
173 IRQ_HANDLER(IRQ47, 79)
174 IRQ_HANDLER(IRQ48, 80)
175 IRQ_HANDLER(IRQ49, 81)
176 IRQ_HANDLER(IRQ50, 82)
177 IRQ_HANDLER(IRQ51, 83)
178 IRQ_HANDLER(IRQ52, 84)
179 IRQ_HANDLER(IRQ53, 85)
180 IRQ_HANDLER(IRQ54, 86)
181 IRQ_HANDLER(IRQ55, 87)
182 IRQ_HANDLER(IRQ56, 88)
183 IRQ_HANDLER(IRQ57, 89)
184 IRQ_HANDLER(IRQ58, 90)
185 IRQ_HANDLER(IRQ59, 91)
186 IRQ_HANDLER(IRQ60, 92)
187 IRQ_HANDLER(IRQ61, 93)
188 IRQ_HANDLER(IRQ62, 94)
189 IRQ_HANDLER(IRQ63, 95)
190 IRQ_HANDLER(IRQ64, 96)
191 IRQ_HANDLER(IRQ65, 97)
192 IRQ_HANDLER(IRQ66, 98)
193 IRQ_HANDLER(IRQ67, 99)
194 IRQ_HANDLER(IRQ68, 100)
195 IRQ_HANDLER(IRQ69, 101)
196 IRQ_HANDLER(IRQ70, 102)
197 IRQ_HANDLER(IRQ71, 103)
198 IRQ_HANDLER(IRQ72, 104)
199 IRQ_HANDLER(IRQ73, 105)
200 IRQ_HANDLER(IRQ74, 106)
201 IRQ_HANDLER(IRQ75, 107)
202 IRQ_HANDLER(IRQ76, 108)
203 IRQ_HANDLER(IRQ77, 109)
204 IRQ_HANDLER(IRQ78, 110)
205 IRQ_HANDLER(IRQ79, 111)
206 IRQ_HANDLER(IRQ80, 112)
207 IRQ_HANDLER(IRQ81, 113)
208 IRQ_HANDLER(IRQ82, 114)
209 IRQ_HANDLER(IRQ83, 115)
210 IRQ_HANDLER(IRQ84, 116)
211 IRQ_HANDLER(IRQ85, 117)
212 IRQ_HANDLER(IRQ86, 118)
213 IRQ_HANDLER(IRQ87, 119)
214 IRQ_HANDLER(IRQ88, 120)
215 IRQ_HANDLER(IRQ89, 121)
216 IRQ_HANDLER(IRQ90, 122)
217 IRQ_HANDLER(IRQ91, 123)
218 IRQ_HANDLER(IRQ92, 124)
219 IRQ_HANDLER(IRQ93, 125)
220 IRQ_HANDLER(IRQ94, 126)
221 IRQ_HANDLER(IRQ95, 127)
222 IRQ_HANDLER(IRQ96, 128)
223 IRQ_HANDLER(IRQ97, 129)
224 IRQ_HANDLER(IRQ98, 130)
225 IRQ_HANDLER(IRQ99, 131)
226 IRQ_HANDLER(IRQ100, 132)
227 IRQ_HANDLER(IRQ101, 133)
228 IRQ_HANDLER(IRQ102, 134)
229 IRQ_HANDLER(IRQ103, 135)
230 IRQ_HANDLER(IRQ104, 136)
231 IRQ_HANDLER(IRQ105, 137)
232 IRQ_HANDLER(IRQ106, 138)
233 IRQ_HANDLER(IRQ107, 139)
234 IRQ_HANDLER(IRQ108, 140)
235 IRQ_HANDLER(IRQ109, 141)
236 IRQ_HANDLER(IRQ110, 142)
237 IRQ_HANDLER(IRQ111, 143)
238 IRQ_HANDLER(IRQ112, 144)
239 IRQ_HANDLER(IRQ113, 145)
240 IRQ_HANDLER(IRQ114, 146)
241 IRQ_HANDLER(IRQ115, 147)
242 IRQ_HANDLER(IRQ116, 148)
243 IRQ_HANDLER(IRQ117, 149)
244 IRQ_HANDLER(IRQ118, 150)
245 IRQ_HANDLER(IRQ119, 151)
246 IRQ_HANDLER(IRQ120, 152)
247 IRQ_HANDLER(IRQ121, 153)
248 IRQ_HANDLER(IRQ122, 154)
249 IRQ_HANDLER(IRQ123, 155)
250 IRQ_HANDLER(IRQ124, 156)
251 IRQ_HANDLER(IRQ125, 157)
252 IRQ_HANDLER(IRQ126, 158)
253 IRQ_HANDLER(IRQ127, 159)
254 IRQ_HANDLER(IRQ128, 160)
255 IRQ_HANDLER(IRQ129, 161)
256 IRQ_HANDLER(IRQ130, 162)
257 IRQ_HANDLER(IRQ131, 163)
258 IRQ_HANDLER(IRQ132, 164)
259 IRQ_HANDLER(IRQ133, 165)
260 IRQ_HANDLER(IRQ134, 166)
261 IRQ_HANDLER(IRQ135, 167)
262 IRQ_HANDLER(IRQ136, 168)
263 IRQ_HANDLER(IRQ137, 169)
264 IRQ_HANDLER(IRQ138, 170)
265 IRQ_HANDLER(IRQ139, 171)
266 IRQ_HANDLER(IRQ140, 172)
267 IRQ_HANDLER(IRQ141, 173)
268 IRQ_HANDLER(IRQ142, 174)
269 IRQ_HANDLER(IRQ143, 175)
270 IRQ_HANDLER(IRQ144, 176)
271 IRQ_HANDLER(IRQ145, 177)
272 IRQ_HANDLER(IRQ146, 178)
273 IRQ_HANDLER(IRQ147, 179)
274 IRQ_HANDLER(IRQ148, 180)
275 IRQ_HANDLER(IRQ149, 181)
276 IRQ_HANDLER(IRQ150, 182)
277 IRQ_HANDLER(IRQ151, 183)
278 IRQ_HANDLER(IRQ152, 184)
279 IRQ_HANDLER(IRQ153, 185)
280 IRQ_HANDLER(IRQ154, 186)
281 IRQ_HANDLER(IRQ155, 187)
282 IRQ_HANDLER(IRQ156, 188)
283 IRQ_HANDLER(IRQ157, 189)
284 IRQ_HANDLER(IRQ158, 190)
285 IRQ_HANDLER(IRQ159, 191)
286 IRQ_HANDLER(IRQ160, 192)
287 IRQ_HANDLER(IRQ161, 193)
288 IRQ_HANDLER(IRQ162, 194)
289 IRQ_HANDLER(IRQ163, 195)
290 IRQ_HANDLER(IRQ164, 196)
291 IRQ_HANDLER(IRQ165, 197)
292 IRQ_HANDLER(IRQ166, 198)
293 IRQ_HANDLER(IRQ167, 199)
294 IRQ_HANDLER(IRQ168, 200)
295 IRQ_HANDLER(IRQ169, 201)
296 IRQ_HANDLER(IRQ170, 202)
297 IRQ_HANDLER(IRQ171, 203)
298 IRQ_HANDLER(IRQ172, 204)
299 IRQ_HANDLER(IRQ173, 205)
300 IRQ_HANDLER(IRQ174, 206)
301 IRQ_HANDLER(IRQ175, 207)
302 IRQ_HANDLER(IRQ176, 208)
303 IRQ_HANDLER(IRQ177, 209)
304 IRQ_HANDLER(IRQ178, 210)
305 IRQ_HANDLER(IRQ179, 211)
306 IRQ_HANDLER(IRQ180, 212)
307 IRQ_HANDLER(IRQ181, 213)
308 IRQ_HANDLER(IRQ182, 214)
309 IRQ_HANDLER(IRQ183, 215)
310 IRQ_HANDLER(IRQ184, 216)
311 IRQ_HANDLER(IRQ185, 217)
312 IRQ_HANDLER(IRQ186, 218)
313 IRQ_HANDLER(IRQ187, 219)
314 IRQ_HANDLER(IRQ188, 220)
315 IRQ_HANDLER(IRQ189, 221)
316 IRQ_HANDLER(IRQ190, 222)
317 IRQ_HANDLER(IRQ191, 223)
318 /* 224-239 are OS IPI vectors (0xe0-0xef) */
319 IRQ_HANDLER(IRQ192, I_SMP_CALL0)
320 IRQ_HANDLER(IRQ193, I_SMP_CALL1)
321 IRQ_HANDLER(IRQ194, I_SMP_CALL2)
322 IRQ_HANDLER(IRQ195, I_SMP_CALL3)
323 IRQ_HANDLER(IRQ196, I_SMP_CALL4)
324 IRQ_HANDLER(IRQ197, 229)
325 IRQ_HANDLER(IRQ198, 230)
326 IRQ_HANDLER(IRQ199, 231)
327 IRQ_HANDLER(IRQ200, 232)
328 IRQ_HANDLER(IRQ201, 233)
329 IRQ_HANDLER(IRQ202, 234)
330 IRQ_HANDLER(IRQ203, 235)
331 IRQ_HANDLER(IRQ204, 236)
332 IRQ_HANDLER(IRQ205, I_TESTING)
333 POKE_HANDLER(IRQ206, I_POKE_CORE)
334 IRQ_HANDLER(IRQ207, I_KERNEL_MSG)
335 /* 240-255 are LAPIC vectors (0xf0-0xff), hightest priority class */
336 IRQ_HANDLER(IRQ208, 240)
337 IRQ_HANDLER(IRQ209, 241)
338 IRQ_HANDLER(IRQ210, 242)
339 IRQ_HANDLER(IRQ211, 243)
340 IRQ_HANDLER(IRQ212, 244)
341 IRQ_HANDLER(IRQ213, 245)
342 IRQ_HANDLER(IRQ214, 246)
343 IRQ_HANDLER(IRQ215, 247)
344 IRQ_HANDLER(IRQ216, 248)
345 IRQ_HANDLER(IRQ217, 249)
346 IRQ_HANDLER(IRQ218, 250)
347 IRQ_HANDLER(IRQ219, 251)
348 IRQ_HANDLER(IRQ220, 252)
349 IRQ_HANDLER(IRQ221, 253)
350 IRQ_HANDLER(IRQ222, 254)
351 IRQ_HANDLER(IRQ223, 255)
352 /* But make sure default is last!! */
353 TRAPHANDLER_NOEC(ISR_default, T_DEFAULT)
354
355 .data
356 .globl trap_tbl_end
357 trap_tbl_end:
358
359 .text
360 _alltraps:
361         cld
362         pushq %r15
363         pushq %r14
364         pushq %r13
365         pushq %r12
366         pushq %r11
367         pushq %r10
368         pushq %r9
369         pushq %r8
370         pushq %rdi
371         pushq %rsi
372         pushq %rbp
373         pushq %rdx
374         pushq %rcx
375         pushq %rbx
376         pushq %rax
377         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
378         je trap_all_tf
379         # this is a user TF.  we need to swapgs to get the kernel's gs and mark the
380         # context as partial
381         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
382         movl $0x1, 0xac(%rsp)   # 0xac - diff btw tf_padding0 and tf_rax
383 trap_all_tf:
384         pushq $0                                # fsbase space
385         pushq $0                                # gsbase space
386         movq $0, %rbp                   # so we can backtrace to this point
387         movq %rsp, %rdi
388         call trap
389         # the return paths are only used by the kernel
390         addq $0x10, %rsp                        # skip fs/gs base
391         popq %rax
392         popq %rbx
393         popq %rcx
394         popq %rdx
395         popq %rbp
396         popq %rsi
397         popq %rdi
398         popq %r8
399         popq %r9
400         popq %r10
401         popq %r11
402         popq %r12
403         popq %r13
404         popq %r14
405         popq %r15
406         addq $0x10, %rsp                        # skip trapno and err
407         iretq
408
409 # might merge this with _alltraps
410 _allirqs:
411         cld
412         pushq %r15
413         pushq %r14
414         pushq %r13
415         pushq %r12
416         pushq %r11
417         pushq %r10
418         pushq %r9
419         pushq %r8
420         pushq %rdi
421         pushq %rsi
422         pushq %rbp
423         pushq %rdx
424         pushq %rcx
425         pushq %rbx
426         pushq %rax
427         cmpw $GD_KT, 0x90(%rsp) # 0x90 - diff btw tf_cs and tf_rax
428         je irq_all_tf
429         # this is a user TF.  we need to swapgs to get the kernel's gs and mark the
430         # context as partial
431         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
432         movl $0x1, 0xac(%rsp)   # 0xac - diff btw tf_padding0 and tf_rax
433 irq_all_tf:
434         pushq $0                                # fsbase space
435         pushq $0                                # gsbase space
436         movq $0, %rbp                   # so we can backtrace to this point
437         movq %rsp, %rdi
438         call handle_irq
439         # the return paths are only used by the kernel
440         addq $0x10, %rsp                        # skip fs/gs base
441         popq %rax
442         popq %rbx
443         popq %rcx
444         popq %rdx
445         popq %rbp
446         popq %rsi
447         popq %rdi
448         popq %r8
449         popq %r9
450         popq %r10
451         popq %r11
452         popq %r12
453         popq %r13
454         popq %r14
455         popq %r15
456         addq $0x10, %rsp                        # skip trapno and err
457         iretq
458
459 .globl sysenter_handler;
460 .type sysenter_handler, @function;
461
462 sysenter_handler:
463 #ifndef CONFIG_NOFASTCALL_FSBASE
464         # Do a quick TLS / FS base change, never changing stacks.
465         # When rdi has the magic number, rsi has the new base
466         movabs $FASTCALL_SETFSBASE, %rax
467         cmp %rax, %rdi
468         jne normal_syscall      # could profile this and handle the jump differently
469         # need to check rsi, make sure it is canonical (will enfore below ULIM).
470         # need to either do this check, or handle the kernel GP fault on wrmsr.
471         movq %rsi, %rdi
472         shrq $47, %rdi
473         cmp $0, %rdi
474         jne fastcall_pop
475         # need to use cx, dx, and ax for the wrmsr.  dx and ax are free.
476         movq %rcx, %rdi         # save rcx, the retaddr
477         movq %rsi, %rdx
478         movq %rsi, %rax
479         shrq $32, %rdx
480         andl $0xffffffff, %eax
481         movl $MSR_FS_BASE, %ecx
482         wrmsr
483         movq %rdi, %rcx         # restore retaddr
484 fastcall_pop:
485         rex.w sysret
486 normal_syscall:
487 #endif
488         # cld is handled by the SFMASK
489         swapgs                                  # user's GS is now in MSR_KERNEL_GS_BASE
490         movq %gs:0, %rsp
491         # Saving the FPU callee-saved state for now.  Might be able to have the
492         # preempt handler deal with it.
493         pushq $0                                # space for mxcsr, fpucw, and padding0
494         movw $0x1, 0x6(%rsp)    # tf_padding0 = 1, partial context
495         fnstcw 0x4(%rsp)
496         stmxcsr (%rsp)
497         pushq %rdx                      # rsp, saved by userspace
498         pushq %rcx                      # rip, saved by hardware
499         pushq %r15
500         pushq %r14
501         pushq %r13
502         pushq %r12
503         pushq %rbp
504         pushq %rbx
505         pushq $0                        # fsbase space
506         pushq $0                        # gsbase space
507         movq $0, %rbp                   # so we can backtrace to this point
508         movq %rsp, %rdx
509         # arg0, rdi: struct sysc*.  arg1, rsi: count.  arg2, rdx: sw_tf
510         call sysenter_callwrapper
511         # return via pop_tf, never this path
512 sysenter_spin:
513         jmp sysenter_spin
514
515 .globl vmexit_handler;
516 .type vmexit_handler, @function;
517 vmexit_handler:
518         # rflags has all flags = 0, so cli and cld already.
519         # HOST_GS_BASE and RSP is set by the hardware
520         # Set default values.  Most of these will be set in C later.
521         pushq $0                        # guest_pa
522         pushq $0                        # guest_va
523         pushq $0                        # intrinfo2 and 1
524         pushq $0                        # exit_qual + exit_reason
525         pushq $0                        # pad + trap_inject
526         pushq $0                        # flags + guest_pcorid
527         pushq $0                        # cr3
528         pushq $0                        # cr2
529         pushq $0                        # rsp
530         pushq $0                        # rflags
531         pushq $0                        # rip
532         # Save register state
533         pushq %r15
534         pushq %r14
535         pushq %r13
536         pushq %r12
537         pushq %r11
538         pushq %r10
539         pushq %r9
540         pushq %r8
541         pushq %rdi
542         pushq %rsi
543         pushq %rbp
544         pushq %rdx
545         pushq %rcx
546         pushq %rbx
547         pushq %rax
548         movq $0, %rbp                   # so we can backtrace to this point
549         movq %rsp, %rdi
550         call handle_vmexit
551 vmexit_spin:
552         jmp vmexit_spin