Linker tables for automatic structures
[akaros.git] / kern / arch / x86 / kernel32.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
5 OUTPUT_ARCH(i386)
6 ENTRY(_start)
7 KERNBASE = 0xc0000000;
8
9 SECTIONS
10 {
11         /* Entry Linked and loaded at 0x00100000 (includes multiboot) */
12         . = 0x00100000;
13
14         .bootstrap : {
15                 *(.boottext .bootdata)
16         }
17
18         /* Needed this for syslinux, which was sitting around 16MB phys.  This just
19          * jumps us forward to the 32MB mark, both physically and virtually. */
20         . = 0x02000000;
21
22         /* Link the main kernel for the space after entry + KERNBASE.  We'll still
23          * load it adjacent in physical memory */
24         . += KERNBASE;
25
26         .text : AT(ADDR(.text) - KERNBASE) {
27                 *(.text .stub .text.* .gnu.linkonce.t.*)
28         }
29
30         PROVIDE(etext = .);     /* Define the 'etext' symbol to this value */
31
32         INCLUDE kern/linker_tables.ld
33
34         .rodata : {
35                 *(.rodata .rodata.* .gnu.linkonce.r.*)
36         }
37
38         /* Include debugging information in kernel memory */
39         .stab : {
40                 PROVIDE(stab = .);
41                 PROVIDE(__STAB_BEGIN__ = .);
42                 *(.stab);
43                 PROVIDE(estab = .);
44                 PROVIDE(__STAB_END__ = .);
45                 BYTE(0)         /* Force the linker to allocate space
46                                    for this section */
47         }
48
49         .stabstr : {
50                 PROVIDE(stabstr = .);
51                 PROVIDE(__STABSTR_BEGIN__ = .);
52                 *(.stabstr);
53                 PROVIDE(estabstr = .);
54                 PROVIDE(__STABSTR_END__ = .);
55                 BYTE(0)         /* Force the linker to allocate space
56                                    for this section */
57         }
58
59         /* Adjust the address for the data segment to the next page */
60         . = ALIGN(0x1000);
61
62         /* The data segment */
63         .data : {
64                 *(.data)
65         }
66
67         PROVIDE(edata = .);
68
69         .bss : {
70                 *(.bss)
71                 *(COMMON)
72         }
73
74         PROVIDE(end = .);
75
76         /DISCARD/ : {
77                 *(.eh_frame .note.GNU-stack)
78         }
79 }