Splits x86 into 32 and 64 bit (XCC)
[akaros.git] / kern / arch / x86 / kernel32.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
5 OUTPUT_ARCH(i386)
6 ENTRY(_start)
7 KERNBASE = 0xc0000000;
8
9 SECTIONS
10 {
11         /* Entry Linked and loaded at 0x00100000 (includes multiboot) */
12         . = 0x00100000;
13
14         .bootstrap : {
15                 *(.boottext .bootdata)
16         }
17
18         /* Link the main kernel for the space after entry + KERNBASE.  We'll still
19          * load it adjacent in physical memory */
20         . += KERNBASE;
21
22         .text : AT(ADDR(.text) - KERNBASE) {
23                 *(.text .stub .text.* .gnu.linkonce.t.*)
24         }
25
26         PROVIDE(etext = .);     /* Define the 'etext' symbol to this value */
27
28         .rodata : {
29                 *(.rodata .rodata.* .gnu.linkonce.r.*)
30         }
31
32         /* Include debugging information in kernel memory */
33         .stab : {
34                 PROVIDE(stab = .);
35                 PROVIDE(__STAB_BEGIN__ = .);
36                 *(.stab);
37                 PROVIDE(estab = .);
38                 PROVIDE(__STAB_END__ = .);
39                 BYTE(0)         /* Force the linker to allocate space
40                                    for this section */
41         }
42
43         .stabstr : {
44                 PROVIDE(stabstr = .);
45                 PROVIDE(__STABSTR_BEGIN__ = .);
46                 *(.stabstr);
47                 PROVIDE(estabstr = .);
48                 PROVIDE(__STABSTR_END__ = .);
49                 BYTE(0)         /* Force the linker to allocate space
50                                    for this section */
51         }
52
53         /* Adjust the address for the data segment to the next page */
54         . = ALIGN(0x1000);
55
56         /* The data segment */
57         .data : {
58                 *(.data)
59         }
60
61         PROVIDE(edata = .);
62
63         .bss : {
64                 *(.bss)
65                 *(COMMON)
66         }
67
68         PROVIDE(end = .);
69
70         /DISCARD/ : {
71                 *(.eh_frame .note.GNU-stack)
72         }
73 }