Update akaros to hook in the new topology stuff
[akaros.git] / kern / arch / x86 / entry64.S
1 /* Copyright (c) 2013 The Regents of the University of California
2  * Barret Rhoden <brho@cs.berkeley.edu>
3  * See LICENSE for details. */
4
5 #include <arch/mmu.h>
6 #include <arch/trap.h>
7 #include <arch/x86.h>
8 #include <kstack.h>
9
10 #define MULTIBOOT_PAGE_ALIGN  (1<<0)
11 #define MULTIBOOT_MEMORY_INFO (1<<1)
12 #define MULTIBOOT_HEADER_MAGIC (0x1BADB002)
13 #define MULTIBOOT_HEADER_FLAGS (MULTIBOOT_MEMORY_INFO | MULTIBOOT_PAGE_ALIGN)
14 #define CHECKSUM (-(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS))
15
16 # The kernel bootstrap (this code) is linked and loaded at physical address
17 # 0x00100000 (1MB), which is the start of extended memory.  (See kernel.ld)
18
19 # Flagging boottext to be text.  Check out:
20 # http://sourceware.org/binutils/docs/as/Section.html
21 .section .boottext, "awx"
22
23 .code32
24 .align 4
25 multiboot_header:
26 .long MULTIBOOT_HEADER_MAGIC
27 .long MULTIBOOT_HEADER_FLAGS
28 .long CHECKSUM
29
30 # Calling convention for internal functions:
31 #
32 # my convention:
33 #       callee saved ebp, ebx
34 #       caller saves eax ecx edx esi edi
35 #       args: a0 edi, a1 esi, a2 edx, a3 ecx, a4 eax, a5+ stack
36 #       ret eax
37 #
38 # for reference, the normal convention:
39 #       callee saved: esi, edi, ebp, ebx
40 #       caller saved: eax, ecx, edx
41 #       args on stack
42 #       ret eax
43
44 /* Helper: creates count mappings in the PML3 for 1GB jumbo pages for the given
45  * vaddr to paddr range in physical memory.  Then it puts that PML3's addr in
46  * the PML4's appropriate slot.  Using a macro mostly to help with 64 bit
47  * argument marshalling.  
48  *
49  * This will clobber ax, dx, cx, di, si.
50  *
51  * A few notes about the jumbo GB mapping:
52  *      - PML3 is responsible for the 9 bits from 30-38, hence the >> 30 and mask
53  *      - PML4 is responsible for the 9 bits from 47-39, hence the >> 39 and mask
54  *      - We use the jumbo PTE_PS flag only on PML3 - can't do it for PML4.
55  *      - PTEs are 8 bytes each, hence the scale = 8 in the indirect addressing
56  *      - The top half of all of PML4's PTEs are set to 0.  This includes the top 20
57  *      bits of the physical address of the page tables - which are 0 in our case.
58  *      - The paddr for the PML3 PTEs is split across two 32-byte halves of the PTE.
59  *      We drop off the lower 30 bits, since we're dealing with 1GB pages.  The 2
60  *      LSBs go at the top of the first half of the PTE, and the remaining 30 are
61  *      the lower 30 of the top half. */
62 #define MAP_GB_PAGES(pml3, vaddr, paddr, count)                                \
63         movl    $(boot_pml4), %eax;                                                \
64         push    %eax;                                                              \
65         movl    $(count), %eax;                                                    \
66         push    %eax;                                                              \
67         movl    $(pml3), %edi;                                                     \
68         movl    $(vaddr >> 32), %esi;                                              \
69         movl    $(vaddr & 0xffffffff), %edx;                                       \
70         movl    $(paddr >> 32), %ecx;                                              \
71         movl    $(paddr & 0xffffffff), %eax;                                       \
72         call    map_gb_pages;                                                      \
73         add             $0x8, %esp
74
75 # Maps count GBs (up to 512) of vaddr -> paddr using pml3 and pml4 in 1GB pages
76 #
77 # edi pml3, esi vaddr_hi, edx vaddr_lo, ecx paddr_hi, eax paddr_lo,
78 # stack: count, pml4
79 map_gb_pages:
80         push    %ebx
81         movl    0x8(%esp), %ebx
82         # save these 3, need them for the next call
83         push    %edi
84         push    %esi
85         push    %edx
86         # arg5 on stack.  other args already in regs.
87         push    %ebx
88         call    fill_jpml3
89         add             $0x4, %esp              # pop arg5 frame
90         # restore our regs/args for next call
91         pop             %edx
92         pop             %esi
93         pop             %edi
94         movl    0xc(%esp), %ecx
95         call    insert_pml3
96         pop             %ebx
97         ret
98         
99 # Fills pml3 with "count" jumbo entries, mapping from vaddr -> paddr.
100 # pml3s are responsible for bits 38..30 of vaddr space and 30 bit paddr entries
101 #
102 # edi pml3, esi vaddr_hi, edx vaddr_lo, ecx paddr_hi, eax paddr_lo, stack count
103 fill_jpml3:
104         push    %ebx
105         movl    0x8(%esp), %ebx
106         # want (vaddr >> 30) & 0x1ff into esi.  append upper 2 bits of edx to esi.
107         shll    $2, %esi
108         shrl    $30, %edx
109         orl             %edx, %esi
110         andl    $0x1ff, %esi
111         # want (paddr >> 30) into ecx.
112         shll    $2, %ecx
113         shrl    $30, %eax
114         orl             %eax, %ecx
115 1:
116         movl    %ecx, %eax
117         shll    $30, %eax                                       # lower part of PTE ADDR
118         orl             $(PTE_P | PTE_W | PTE_PS), %eax
119         movl    %eax, (%edi, %esi, 8)
120         movl    %ecx, %eax
121         shrl    $2, %eax                                        # upper part of PTE ADDR
122         movl    %eax, 4(%edi, %esi, 8)
123         # prep for next loop
124         incl    %esi
125         incl    %ecx
126         decl    %ebx
127         jnz             1b
128         pop             %ebx
129         ret
130         
131 #define MAP_2MB_PAGES(pml3, vaddr, paddr, count, pml2base)                     \
132         movl    $(pml2base), %eax;                                                 \
133         push    %eax;                                                              \
134         movl    $(boot_pml4), %eax;                                                \
135         push    %eax;                                                              \
136         movl    $(count), %eax;                                                    \
137         push    %eax;                                                              \
138         movl    $(pml3), %edi;                                                     \
139         movl    $(vaddr >> 32), %esi;                                              \
140         movl    $(vaddr & 0xffffffff), %edx;                                       \
141         movl    $(paddr >> 32), %ecx;                                              \
142         movl    $(paddr & 0xffffffff), %eax;                                       \
143         call    map_2mb_pages;                                                     \
144         add             $0xc, %esp
145
146 # Maps count GBs (up to 512) of vaddr -> paddr using pml3, pml4, and an array of
147 # pml2s in 2MB pages
148 #
149 # edi pml3, esi vaddr_hi, edx vaddr_lo, ecx paddr_hi, eax paddr_lo,
150 # stack: count, pml4, pml2_base
151 map_2mb_pages:
152         push    %ebx
153         # save these 3, need them for the next call
154         push    %edi
155         push    %esi
156         push    %edx
157         # arg5 and 7 on stack.  other args already in regs.
158         movl    0x1c(%esp), %ebx        # arg7 (4 pushes, 1 retaddr, arg 5, arg6)
159         push    %ebx
160         movl    0x18(%esp), %ebx        # arg6 (5 pushes, 1 retaddr)
161         push    %ebx
162         call    fill_pml3
163         add             $0x8, %esp                      # pop args frame
164         # restore our regs/args for next call
165         pop             %edx
166         pop             %esi
167         pop             %edi
168         movl    0xc(%esp), %ecx
169         call    insert_pml3
170         pop             %ebx
171         ret
172         
173 # Fills pml3 with "count" pml2 entries, mapping from vaddr -> paddr.
174 # pml3s are responsible for bits 38..30 of vaddr space and 30 bit paddr entries
175 #
176 # edi pml3, esi vaddr_hi, edx vaddr_lo, ecx paddr_hi, eax paddr_lo,
177 # stack count, pml2base
178 fill_pml3:
179         push    %ebx
180         push    %ebp                                            # scratch register
181         movl    0xc(%esp), %ebx
182 1:
183         push    %edi                                            # save edi = pml3
184         push    %esi
185         push    %edx
186         push    %ecx
187         push    %eax
188         movl    $512, %ebp                                      # count = 512 for PML2 (map it all)
189         push    %ebp
190         # compute pml2 (pml2base + (total count - current count) * PGSIZE)
191         movl    0x28(%esp), %ebp                        # pml2base (8 push, 1 ret, arg5)
192         movl    0x24(%esp), %edi                        # total count
193         subl    %ebx, %edi
194         shll    $12, %edi
195         addl    %edi, %ebp
196         movl    %ebp, %edi                                      # arg0 for the func call
197         call    fill_jpml2
198         add             $0x4, %esp
199         pop             %eax
200         pop             %ecx
201         pop             %edx
202         pop             %esi
203         pop             %edi
204         # re-save our register frame
205         push    %edi
206         push    %esi
207         push    %edx
208         push    %ecx
209         push    %eax
210         # prep call to insert (ecx = pml3, edi = pml2)
211         movl    %edi, %ecx
212         movl    %ebp, %edi
213         call    insert_pml2
214         pop             %eax
215         pop             %ecx
216         pop             %edx
217         pop             %esi
218         pop             %edi
219         # prep for next loop.  need to advance vaddr and paddr by 1GB
220         addl    $(1 << 30), %edx
221         adcl    $0, %esi
222         addl    $(1 << 30), %eax
223         adcl    $0, %ecx
224         decl    %ebx
225         jnz             1b
226         pop             %ebp
227         pop             %ebx
228         ret
229
230 # Fills pml2 with "count" jumbo entries, mapping from vaddr -> paddr
231 # pml2s are responsible for bits 29..21 of vaddr space and 21 bit paddr entries
232 #
233 # edi pml2, esi vaddr_hi, edx vaddr_lo, ecx paddr_hi, eax paddr_lo, stack count
234 fill_jpml2:
235         push    %ebx
236         movl    0x8(%esp), %ebx
237         # want (vaddr >> 21) & 0x1ff into esi.
238         shrl    $21, %edx
239         movl    %edx, %esi
240         andl    $0x1ff, %esi
241         # want (paddr >> 21) into ecx.
242         shll    $11, %ecx
243         shrl    $21, %eax
244         orl             %eax, %ecx
245 1:
246         movl    %ecx, %eax
247         shll    $21, %eax                                       # lower part of PTE ADDR
248         orl             $(PTE_P | PTE_W | PTE_PS), %eax
249         movl    %eax, (%edi, %esi, 8)
250         movl    %ecx, %eax
251         shrl    $11, %eax                                       # upper part of PTE ADDR
252         movl    %eax, 4(%edi, %esi, 8)
253         # prep for next loop
254         incl    %esi
255         incl    %ecx
256         decl    %ebx
257         jnz             1b
258         pop             %ebx
259         ret
260
261 # Inserts a pml3 into pml4, so that it handles mapping for vaddr
262 #
263 # edi pml3, esi vaddr_hi, edx vaddr_lo, ecx pml4
264 insert_pml3:
265         shrl    $7, %esi        # want to shift vaddr >> 39
266         andl    $0x1ff, %esi
267         orl             $(PTE_P | PTE_W), %edi
268         movl    %edi, (%ecx, %esi, 8)
269         movl    $0x0, 4(%ecx, %esi, 8)  # being clever, i know upper bits are 0
270         ret
271
272 # Inserts a pml2 into pml3, so that it handles mapping for vaddr
273 #
274 # edi pml2, esi vaddr_hi, edx vaddr_lo, ecx pml3
275 insert_pml2:
276         # want (vaddr >> 30) & 0x1ff into esi.  append upper 2 bits of edx to esi.
277         shll    $2, %esi
278         shrl    $30, %edx
279         orl             %edx, %esi
280         andl    $0x1ff, %esi
281         orl             $(PTE_P | PTE_W), %edi
282         movl    %edi, (%ecx, %esi, 8)
283         movl    $0x0, 4(%ecx, %esi, 8)  # being clever, i know upper bits are 0
284         ret
285
286 .globl          _start
287 _start:
288         movl    $stack32top, %esp
289         push    %ebx                                    # save mulitboot info
290         movw    $0x1234,0x472                   # warm boot
291         movl    $0x80000001, %eax
292         # some machines / VMs might not support long mode
293         cpuid
294         test    $(1 << 29), %edx
295         jz              err_no_long
296         # others don't support 1GB jumbo pages, which is a shame
297         test    $(1 << 26), %edx
298         jz              no_pml3ps
299         # build page table.  need mappings for
300         #       - current code/data at 0x00100000 -> 0x00100000
301         #       - kernel load location: 0xffffffffc0000000 -> 0x0000000000000000
302         #       - kernbase: 0xffff80000000 -> 0x0000000000000000
303         # we'll need one table for the PML4, and three PML3 (PDPE)'s.  1GB will
304         # suffice for lo and hi (til we do the VPT and LAPIC mappings).  For
305         # kernbase, we'll do all 512 PML3 entries (covers 512GB)
306         MAP_GB_PAGES(boot_pml3_lo, 0x0000000000000000, 0x0, 1)
307         MAP_GB_PAGES(boot_pml3_hi, 0xffffffffc0000000, 0x0, 1)
308         MAP_GB_PAGES(boot_pml3_kb, 0xffff800000000000, 0x0, 512)
309         jmp             post_mapping
310 no_pml3ps:
311         MAP_2MB_PAGES(boot_pml3_lo, 0x0000000000000000, 0x0,   1, boot_pml2_lo)
312         MAP_2MB_PAGES(boot_pml3_hi, 0xffffffffc0000000, 0x0,   1, boot_pml2_hi)
313         MAP_2MB_PAGES(boot_pml3_kb, 0xffff800000000000, 0x0, 512, boot_pml2_kb)
314 post_mapping:
315         # load cr3 - note that in long mode, cr3 is 64 bits wide.  our boot pml4 is
316         # in lower memory, so it'll be fine if the HW 0 extends.
317         movl    $boot_pml4, %eax
318         movl    %eax, %cr3
319         # turn on paging option in cr4.  note we assume PSE support.  if we didn't
320         # have it, then our jumbo page mappings are going to fail.  we also want
321         # global pages (for performance).  PAE is the basics needed for long paging
322         movl    %cr4, %eax
323         orl             $(CR4_PSE | CR4_PGE | CR4_PAE), %eax
324         movl    %eax, %cr4
325         # Turn on the IA32E enabled bit.
326         # rd/wrmsr use ecx for the addr, and eax as the in/out register.
327         movl    $IA32_EFER_MSR, %ecx
328         rdmsr
329         orl             $IA32_EFER_IA32E_EN, %eax
330         wrmsr
331         # Setup cr0.  PE and PG are critical for now.  The others are similar to
332         # what we want in general (-AM with 64 bit, it's useless).
333         movl    %cr0, %eax
334         orl             $(CR0_PE | CR0_PG | CR0_WP | CR0_NE | CR0_MP), %eax  
335         andl    $(~(CR0_AM | CR0_TS | CR0_EM | CR0_CD | CR0_NW)), %eax  
336         movl    %eax, %cr0
337         pop             %ebx                            # restore multiboot info
338         # load the 64bit GDT and jump to long mode
339         lgdt    gdt64desc
340         ljmp    $0x08, $long_mode
341         # these are error handlers, we're jumping over these
342 err_no_long:
343         mov             $no_long_string, %esi
344         jmp             printstring
345 err_no_pml3ps:
346         mov             $no_pml3ps_string, %esi
347         jmp             printstring
348 printstring:
349         mov             $0xb8a00, %edi          # assuming CGA buffer, 16 lines down
350         mov             $0, %ecx
351 1:
352         movb    (%esi, %ecx), %bl
353         test    %bl, %bl
354         je              printdone
355         # print to the console (0x07 is white letters on black background)
356         mov             $0x07, %bh
357         mov             %bx, (%edi, %ecx, 2)
358         # print to serial
359         mov             $(0x3f8 + 5), %edx      # assuming COM1
360 2:
361         inb             %dx, %al
362         test    $0x20, %al                      # ready check
363         jz              2b
364         mov             $0x3f8, %edx            # assuming COM1
365         mov             %bl, %al
366         outb    %al, %dx
367         # advance the loop
368         inc             %ecx
369         jmp             1b
370 printdone:
371         hlt
372         jmp             printdone
373
374 .code64
375 long_mode:
376         # zero the data segments.  Not sure if this is legit or not.
377         xor             %rax, %rax
378         mov             %ax, %ds
379         mov             %ax, %es
380         mov             %ax, %ss
381         mov             %ax, %fs
382         mov             %ax, %gs
383         lldt    %ax
384         # paging is on, and our code is still running at 0x00100000.
385         # do some miscellaneous OS setup.
386         # set up gs to point to our pcpu info (both GS base and KERN GS base)
387         movabs  $(per_cpu_info), %rdx
388         movq    %rdx, %rax
389         shrq    $32, %rdx
390         andl    $0xffffffff, %eax
391         movl    $MSR_GS_BASE, %ecx
392         wrmsr
393         movl    $MSR_KERN_GS_BASE, %ecx
394         wrmsr
395         # Clear the frame pointer for proper backtraces
396         movq    $0x0, %rbp
397         movabs  $(bootstacktop), %rsp
398         # Pass multiboot info to kernel_init (%rdi == arg1)
399         movq    %rbx, %rdi
400         movabs  $(kernel_init), %rax
401         call    *%rax
402         # Should never get here, but in case we do, just spin.
403 spin:   jmp     spin
404
405 .section .bootdata, "aw"
406         .p2align        2               # force 4 byte alignment
407 .globl gdt64
408 gdt64:
409         # keep the number of these in sync with SEG_COUNT
410         SEG_NULL
411         SEG_CODE_64(0)          # kernel code segment
412         SEG_DATA_64(0)          # kernel data segment
413         SEG_DATA_64(3)          # user data segment
414         SEG_CODE_64(3)          # user code segment
415         SEG_NULL                        # these two nulls are a placeholder for the TSS
416         SEG_NULL                        # these two nulls are a placeholder for the TSS
417 .globl gdt64desc
418 gdt64desc:
419         .word   (gdt64desc - gdt64 - 1)         # sizeof(gdt64) - 1
420         .long   gdt64           # HW 0-extends this to 64 bit when loading (i think)
421 no_long_string:
422         .string "Unable to boot: long mode not supported"
423 no_pml3ps_string:
424         .string "Unable to boot: 1 GB pages not supported"
425 # boot page tables
426         .align PGSIZE
427 .globl boot_pml4
428 boot_pml4:
429         .space  PGSIZE
430 boot_pml3_lo:
431         .space  PGSIZE
432 boot_pml3_hi:
433         .space  PGSIZE
434 boot_pml3_kb:
435         .space  PGSIZE
436 stack32:
437         .space  PGSIZE
438 stack32top:
439 # Could make all of the no-jumbo stuff a config var
440 boot_pml2_lo:           # one pml2 (1GB in the lo pml3)
441         .space  PGSIZE
442 boot_pml2_hi:           # one pml2 (1GB in the hi pml3)
443         .space  PGSIZE
444 boot_pml2_kb:           # 512 pml2s in the kb pml3
445         .space  PGSIZE * 512
446
447 # From here down is linked for KERNBASE
448 .text
449         .globl get_boot_pml4
450 get_boot_pml4:
451         movabs  $(boot_pml4), %rax
452         ret
453         .globl get_gdt64
454 get_gdt64:
455         movabs  $(gdt64), %rax
456         ret
457 .data
458         .p2align        PGSHIFT         # force page alignment
459         .globl          bootstack
460 bootstack:
461         .space          KSTKSIZE
462         .globl          bootstacktop
463 bootstacktop: