Way faster FDIV/FSQRT on SPARC
[akaros.git] / kern / arch / sparc / trap_entry.S
1 #include <arch/sparc.h>
2 #include <arch/trap.h>
3 #include <arch/mmu.h>
4 #include <arch/trap_table.h>
5 #include <ros/memlayout.h>
6
7         .section        ".text"!,#alloc,#execinstr,#progbits
8         .align          4
9
10         .global tflush
11
12         .global handle_trap
13 handle_trap:
14
15         // At this point, %l1 = pc, %l2 = npc, and %l0/3/4/5
16         // might contain an active message.  so we only get %l6/%l7
17
18         // calculate stack pointer (-64 is space for window spill).
19         // sp = bootstacktop - core_id*KSTKSIZE - 64 - sizeof(trapframe_t).
20         // should you change this, make sure to change stack_fucked()
21         set     bootstacktop-64-SIZEOF_TRAPFRAME_T,%l6
22         mov     CORE_ID_REG,%l7
23         sll     %l7,KSTKSHIFT,%l7
24         sub     %l6,%l7,%l6
25
26         // see if trap came from kernel; if so, use that stack
27         // also preserve the psr, since we'll screw with the condition codes
28         mov     %psr,%l7
29         btst    PSR_PS,%l7
30         bne,a   1f
31          sub    %fp,64+SIZEOF_TRAPFRAME_T,%l6
32
33         // here is where we might do something with an active message
34
35 1:      mov     %l7,%l0
36         // At this point we may use %l3/4/5/7 as temporary regs
37
38         // is CWP valid?
39         and     %l0,PSR_CWP,%l4 ! %l4 = cwp
40         mov     1,%l7
41         sll     %l7,%l4,%l4     ! %l4 = 1 << cwp
42         mov     %wim,%l3
43         btst    %l3,%l4         ! (%wim & %l4) == 0?
44         be      2f
45          sethi  %hi(spill),%l7
46         jmpl    %lo(spill)+%l7,%l7      !no, spill a window
47          nop
48
49
50         // At this point we may use %o0-7, %l3/4/5/7 as temporary regs
51         // save the whole user context to a trapframe_t
52
53 2:      mov     %l0,%psr
54         mov     %l6,%sp
55         mov     %l1,%o1
56         mov     %l2,%o2
57         call    env_save_tf
58          add    %sp,64,%o0
59
60         // enable traps (but not interrupts)
61         or      %l0,PSR_PIL,%l3
62         wr      %l3,0,%psr
63         wr      %l3,PSR_ET,%psr
64
65         // spill all trapper's windows out to the stack.
66         // the 'save' may trap (triggering the spill),
67         // and if the stack is corrupted, the process may die
68         set     NWINDOWS,%g1
69         ld      [%g1],%g1
70         sub     %g1,1,%g2
71 5:      deccc   %g2
72         bne,a   5b
73 tflush:  save   %sp,0,%sp
74
75         // get our old cwp back (restore should NOT trap)
76         sub     %g1,1,%g2
77 6:      deccc   %g2
78         bne,a   6b
79          restore
80
81         // restore interrupt level
82         wr      %l0,PSR_ET,%psr
83
84         // call the handler and pass in the tf, message, and handler addr
85         add     %sp,64,%o0
86         call    trap
87          mov    %l5,%o1
88
89         // should never get here
90         unimp
91
92 // void env_save_tf(trapframe_t* tf, uint32_t trap_pc, uint32_t trap_npc)
93         .global env_save_tf
94 env_save_tf:
95
96         mov     %psr,%o4
97         st      %o4,[%o0+128]
98         st      %o1,[%o0+132]
99         st      %o2,[%o0+136]
100         mov     %wim,%o4
101         st      %o4,[%o0+140]
102         mov     %tbr,%o4
103         mov     %y,%o5
104         std     %o4,[%o0+144]
105
106         set     0x300,%o4
107         set     0x400,%o5
108         lda     [%o4] 4,%o4
109         lda     [%o5] 4,%o5
110         std     %o4,[%o0+152]
111         lda     [%g0] 2,%o4
112         mov     4,%o5
113         lda     [%o5] 2,%o5
114         std     %o4,[%o0+160]
115
116         std     %g0,[%o0+ 0]
117         std     %g2,[%o0+ 8]
118         std     %g4,[%o0+16]
119         std     %g6,[%o0+24]
120
121         mov     %o0,%g2
122
123         restore
124         std     %o0,[%g2+32]
125         std     %o2,[%g2+40]
126         std     %o4,[%g2+48]
127         std     %o6,[%g2+56]
128         std     %l0,[%g2+64]
129         std     %l2,[%g2+72]
130         std     %l4,[%g2+80]
131         std     %l6,[%g2+88]
132         std     %i0,[%g2+96]
133         std     %i2,[%g2+104]
134         std     %i4,[%g2+112]
135         std     %i6,[%g2+120]
136         save
137
138         retl
139          nop
140
141         .global env_pop_tf
142 env_pop_tf:
143
144         // disable interrupts.
145         // since wrpsr/rdpsr is interruptible, all interrupt handlers
146         // must restore the psr to its interrupt-time value
147         mov     %psr,%o1
148         or      %o1,PSR_PIL,%o2
149         wr      %o2,%psr
150
151         // spill all kernel windows to the stack
152         set     NWINDOWS,%g1
153         ld      [%g1],%g1
154         sub     %g1,1,%g2
155 5:      deccc   %g2
156         bne,a   5b
157          save   %sp,0,%sp
158
159         // get our old cwp back (restore should NOT trap)
160         sub     %g1,1,%g2
161 6:      deccc   %g2
162         bne,a   6b
163          restore
164         
165
166         // disable traps, and restore interrupt level
167         wr      %o2,PSR_ET,%psr
168         wr      %o1,PSR_ET,%psr
169
170         // if we did this right (and didn't get an NMI!),
171         // then (CWP+1) % NWINDOWS should be invalid.  fix that.
172         save
173         mov     %i0,%o0
174
175 #if 0
176         // is (CWP+1) % NWINDOWS valid?
177         and     %o1,PSR_CWP,%o2
178         set     NWINDOWS,%o1
179         ld      [%o1],%o1
180         add     %o2,1,%o2
181         cmp     %o2,%o1
182         be,a    3f
183          mov    0,%o2
184
185 3:      mov     1,%o3
186         sll     %o3,%o2,%o2             ! %o2 = 1 << ((CWP+1)%NWINDOWS)
187         mov     %wim,%o3
188         btst    %o2,%o3                 ! (%wim & %o2) == 0?
189         be      4f
190          nop
191
192         sethi   %hi(fill),%o3           ! gotta fill a window
193         jmpl    %lo(fill)+%o3,%o3
194          save   %o3,0,%l7               ! fill returns to %l7
195         restore
196
197 #endif
198
199         // restore user context
200 4:      mov     %o0,%g2
201         restore
202         ldd     [%g2+32],%o0
203         ldd     [%g2+40],%o2
204         ldd     [%g2+48],%o4
205         ldd     [%g2+56],%o6
206         ldd     [%g2+64],%l0
207         ldd     [%g2+72],%l2
208         ldd     [%g2+80],%l4
209         ldd     [%g2+88],%l6
210         ldd     [%g2+96],%i0
211         ldd     [%g2+104],%i2
212         ldd     [%g2+112],%i4
213         ldd     [%g2+120],%i6
214         save
215
216         ld      [%o0+ 4],%g1
217         ldd     [%o0+ 8],%g2
218         ldd     [%o0+16],%g4
219         ldd     [%o0+24],%g6
220
221         ldd     [%o0+128],%l0
222         mov     %psr,%l2
223         and     %l2,PSR_CWP,%l2
224         andn    %l0,PSR_CWP,%l0
225         wr      %l2,%l0,%psr
226
227         ldd     [%o0+136],%l2
228         !mov    %l3,%wim
229         ldd     [%o0+144],%l4
230         mov     %l4,%tbr
231         mov     %l5,%y
232         nop
233
234         jmp     %l1
235         rett    %l2
236
237         .global send_active_message_raw
238 send_active_message_raw:
239         retl
240          .word  0x81f00000