x86: Fixes TLS bug causing kernel page faults
[akaros.git] / kern / arch / sparc / trap_entry.S
1 #include <arch/sparc.h>
2 #include <arch/trap.h>
3 #include <arch/mmu.h>
4 #include <arch/trap_table.h>
5 #include <ros/memlayout.h>
6
7         .section        ".text"!,#alloc,#execinstr,#progbits
8         .align          4
9
10         .global tflush
11
12         .global handle_trap
13 handle_trap:
14
15         // At this point, %l1 = pc, %l2 = npc, and %l0/3/4/5
16         // might contain an active message.  so we only get %l6/%l7
17
18         // calculate stack pointer (-64 is space for window spill).
19         // sp = bootstacktop - core_id*KSTKSIZE - 64 - sizeof(trapframe_t).
20         // should you change this, make sure to change stack_fucked()
21         set     bootstacktop-64-SIZEOF_TRAPFRAME_T,%l6
22         mov     CORE_ID_REG,%l7
23         sll     %l7,KSTKSHIFT,%l7
24         sub     %l6,%l7,%l6
25
26         // see if trap came from kernel; if so, use that stack
27         // also preserve the psr, since we'll screw with the condition codes
28         mov     %psr,%l0
29         btst    PSR_PS,%l0
30         bne,a   1f
31          sub    %fp,64+SIZEOF_TRAPFRAME_T,%l6
32
33         // here is where we might do something with an active message
34
35         // At this point we may use %l3/4/5/7 as temporary regs
36 1:
37         // is CWP valid?
38         and     %l0,PSR_CWP,%l4 ! %l4 = cwp
39         mov     1,%l7
40         sll     %l7,%l4,%l4     ! %l4 = 1 << cwp
41         mov     %wim,%l3
42         btst    %l3,%l4         ! (%wim & %l4) == 0?
43         be      2f
44          sethi  %hi(spill),%l7
45         jmpl    %lo(spill)+%l7,%l7      !no, spill a window
46          nop
47
48         // At this point we may use %o0-7, %l3/4/5/7 as temporary regs
49         // save the whole user context to a trapframe_t
50
51 2:
52         mov     %l6,%sp
53         mov     %l1,%o1
54         mov     %l2,%o2
55         mov     %l0,%psr                        ! restore condition codes before saving trapframe
56         call    env_save_tf
57          add    %sp,64,%o0
58
59         // enable traps (but not interrupts)
60         or      %l0,PSR_PIL,%l3
61         wr      %l3,0,%psr
62         wr      %l3,PSR_ET,%psr
63
64         // spill all trapper's windows out to the stack.
65         // the 'save' may trap (triggering the spill),
66         // and if the stack is corrupted, the process may die
67         mov     %l0,%g3
68         mov     %sp,%g4
69
70         set     NWINDOWS,%g1
71         ld      [%g1],%g1
72         sub     %g1,1,%g2
73 5:      deccc   %g2
74         bne,a   5b
75 tflush:  save   %sp,0,%sp
76
77         // restore interrupt level
78         mov     %g4,%sp 
79         wr      %g3,PSR_ET,%psr
80
81         // call the handler and pass in the tf and handler address
82         call    %l5
83          add    %sp,64,%o0
84
85         // should never get here
86         unimp
87
88 // void env_save_tf(trapframe_t* tf, uint32_t trap_pc, uint32_t trap_npc)
89         .global env_save_tf
90 env_save_tf:
91
92         mov     %psr,%o4
93         st      %o4,[%o0+128]
94         st      %o1,[%o0+132]
95         st      %o2,[%o0+136]
96         mov     %wim,%o4
97         st      %o4,[%o0+140]
98         mov     %tbr,%o4
99         mov     %y,%o5
100         std     %o4,[%o0+144]
101         mov     %asr13,%o5
102         st      %o5,[%o0+152]
103
104         set     0x300,%o4
105         set     0x400,%o5
106         lda     [%o4] 4,%o4
107         lda     [%o5] 4,%o5
108         std     %o4,[%o0+160]
109         lda     [%g0] 2,%o4
110         mov     4,%o5
111         lda     [%o5] 2,%o5
112         std     %o4,[%o0+168]
113
114         # try to read out the faulting insn (in no-fault mode)
115         andn    %o1,3,%o1
116         lda     [%g0] 4,%o2
117         or      %o2,2,%o3
118         sta     %o3,[%g0] 4
119         ld      [%o1],%o1
120         st      %o1,[%o0+156]
121         sta     %o2,[%g0] 4
122
123         std     %g0,[%o0+ 0]
124         std     %g2,[%o0+ 8]
125         std     %g4,[%o0+16]
126         std     %g6,[%o0+24]
127
128         mov     %o0,%g2
129
130         restore
131         std     %o0,[%g2+32]
132         std     %o2,[%g2+40]
133         std     %o4,[%g2+48]
134         std     %o6,[%g2+56]
135         std     %l0,[%g2+64]
136         std     %l2,[%g2+72]
137         std     %l4,[%g2+80]
138         std     %l6,[%g2+88]
139         std     %i0,[%g2+96]
140         std     %i2,[%g2+104]
141         std     %i4,[%g2+112]
142         std     %i6,[%g2+120]
143         save
144
145         retl
146          nop
147
148         // this routine only works for returning to userspace.
149         // right now, there's no mechanism to resume kernel operation after
150         // a fault
151         .global env_pop_tf
152 env_pop_tf:
153         mov     %psr,%o1
154         wr      %o1,PSR_ET,%psr
155
156         // CWP = 0 (therefore 1 after rett), so set window 2 invalid
157         mov     1<<2,%wim
158         ld      [%o0+128],%o1
159         mov     %o0,%g2
160         andn    %o1,PSR_CWP,%o1
161         mov     %o1,%psr
162         nop; nop; nop
163         mov     %g2,%o0
164
165 4:      // restore user context
166         restore
167         ldd     [%g2+32],%o0
168         ldd     [%g2+40],%o2
169         ldd     [%g2+48],%o4
170         ldd     [%g2+56],%o6
171         ldd     [%g2+64],%l0
172         ldd     [%g2+72],%l2
173         ldd     [%g2+80],%l4
174         ldd     [%g2+88],%l6
175         ldd     [%g2+96],%i0
176         ldd     [%g2+104],%i2
177         ldd     [%g2+112],%i4
178         ldd     [%g2+120],%i6
179         save
180
181         ld      [%o0+ 4],%g1
182         ldd     [%o0+ 8],%g2
183         ldd     [%o0+16],%g4
184         ldd     [%o0+24],%g6
185
186         ld      [%o0+132],%l1
187         ld      [%o0+136],%l2
188         ld      [%o0+148],%l5
189         mov     %l5,%y
190         ld      [%o0+152],%l5
191         mov     %l5,%asr13
192
193         jmp     %l1
194         rett    %l2
195
196         .global handle_perfctr
197 handle_perfctr:
198         andn    %i0,7,%i1
199         lda     [%i1] 2,%i0
200         add     %i1,4,%i1
201         lda     [%i1] 2,%i1
202         jmp     %l2
203          rett   %l2+4