Merge remote branch 'origin/sparc-dev'
[akaros.git] / kern / arch / sparc / entry.S
1 /* See COPYRIGHT for copyright information. */
2
3 #include <arch/mmu.h>
4 #include <arch/sparc.h>
5 #include <arch/arch.h>
6 #include <ros/memlayout.h>
7
8 ///////////////////////////////////////////////////////////////////
9 // The kernel (this code) is linked at address (KERNBASE + 0x00000000),
10 // but we tell the bootloader to load it at physical address 
11 // 0x00000000, which is the start of extended memory.
12 // (See kernel.ld)
13 ///////////////////////////////////////////////////////////////////
14
15
16 ///////////////////////////////////////////////////////////////////
17 // RELOC(x) maps a symbol x from its link address to its actual
18 // location in physical memory (its load address).       
19 ///////////////////////////////////////////////////////////////////
20 #define RELOC(x) ((x) - KERNBASE)
21
22 ///////////////////////////////////////////////////////////////////
23 // entry point
24 ///////////////////////////////////////////////////////////////////
25
26 .text
27
28 .global         _start
29 _start:
30         // This is the first code that ever executes.  It executes on all
31         // cores (RAMP Gold-specific).  All we know is that PSR.S (supervisor)
32         // and PSR.ET (enable traps) are both 0.  Before we can enable traps,
33         // we must determine how many register windows we have, set up the
34         // trap table, and set up a stack frame.
35
36         // compute NWINDOWS
37
38         mov     -1,%wim                 ! mark all windows invalid.
39         mov     (PSR_S|PSR_PS),%psr
40         nop                             ! 3 insns between wrwim/rdwim
41         mov     0,%g2           ! g2 will contain NWINDOWS-1
42         mov     %wim,%g1        ! get wim. nonexistent windows set to 0
43
44 1:      srl     %g1,1,%g1
45         tst     %g1
46         bne,a   1b
47          inc    %g2
48
49         // now g2 = NWINDOWS - 1.  Patch the window spill trap handler.
50         set     RELOC(spill_patchme),%g1
51         ld      [%g1],%g3
52         or      %g2,%g3,%g3
53         st      %g3,[%g1]
54         flush   %g1
55
56         // and patch the window fill trap handler.
57         set     RELOC(fill_patchme),%g1
58         ld      [%g1],%g3
59         or      %g2,%g3,%g3
60         st      %g3,[%g1]
61         flush   %g1
62
63         // store NWINDOWS away for safekeeping
64         set     RELOC(NWINDOWS),%g1
65         inc     %g2
66         st      %g2,[%g1]
67
68         // PSR.CWP (current window pointer) == 0.
69         // Set WIM so we'll trap on the next save instruction.
70         mov     1 << 1,%wim
71
72         // set up the TBR (trap base register)
73         set     RELOC(trap_table),%g1
74         mov     %g1,%tbr
75
76         // clear frame pointer for backtrace termination
77         mov     0,%fp
78
79         // set stack pointer (-64 is space for window spill)
80         // sp = bootstacktop - core_id*KSTKSIZE - 64
81         set     RELOC(bootstacktop)-64,%sp
82         mov     CORE_ID_REG,%g1
83         sll     %g1,KSTKSHIFT,%g1
84         sub     %sp,%g1,%sp
85
86         // set up a virtual->physical mapping
87         call    mmu_boot
88          nop
89
90         // relocate
91         set     trap_table,%g1
92         mov     %g1,%tbr
93         set     reloc,%g1
94         set     KERNBASE,%g2
95         jmp     %g1
96          add    %g2,%sp,%sp
97 reloc:
98
99         // finish mmu_boot
100         call    mmu_boot_finish
101          nop
102
103         // now it's safe to enable traps
104         mov     %psr,%g1
105         wr      %g1,PSR_ET,%psr
106         nop; nop; nop
107
108         // am i core 0?  (do i run BSD?!?)
109         mov     CORE_ID_REG,%g1
110         tst     %g1
111         bne     4f
112          nop
113
114         // only core 0 gets here
115         // set num_cpus
116         set     num_cpus,%l0
117         mov     NUM_CORES_REG,%l1
118         st      %l1,[%l0]
119
120         cmp     %l1,MAX_NUM_CPUS
121         tg      0x7f
122
123         sub     %sp,64,%sp              ! 64 >= sizeof(multiboot_header_t)
124         call    build_multiboot_info
125          add    %sp,64,%o0
126
127         // kernel_init time!
128         // first arg is pointer to multiboot_info_t, but kernel_init
129         // expects it to be a pre-relocation address, so lop off KERNBASE
130         set     KERNBASE,%l0
131         add     %sp,64,%o0
132         call    kernel_init
133          sub    %o0,%l0,%o0
134
135         // shouldn't get here
136 3:      ba      3b
137          nop
138
139         // i'm not core 0, so i'll call smp_init when the time is nigh
140 4:      set     time_for_smp_init,%l1
141         ld      [%l1],%l0
142         tst     %l0
143         be      4b
144          nop
145
146         call    smp_init
147          nop
148
149         // shouldn't get here
150 5:      ba      5b
151          nop
152
153 ///////////////////////////////////////////////////////////////////
154 // various data
155 ///////////////////////////////////////////////////////////////////
156
157         .global         time_for_smp_init
158 time_for_smp_init:
159         .word           0
160
161         .global         NWINDOWS
162 NWINDOWS:
163         .word           0
164
165         .global         num_cpus
166 num_cpus:
167         .word           0
168
169 ///////////////////////////////////////////////////////////////////
170 // boot stack
171 ///////////////////////////////////////////////////////////////////
172
173         .align          PGSIZE          ! force page alignment
174         .global         bootstack
175 bootstack:
176         .space          KSTKSIZE*MAX_NUM_CPUS
177         .global         bootstacktop   
178 bootstacktop:
179
180 ///////////////////////////////////////////////////////////////////
181 // page tables
182 ///////////////////////////////////////////////////////////////////
183         .align          (NCONTEXTS+CONTEXT_TABLE_PAD)*4
184         .global         mmu_context_tables
185 mmu_context_tables:
186         .skip           MAX_NUM_CPUS*(NCONTEXTS+CONTEXT_TABLE_PAD)*4
187
188         .align          1024
189         .global         l1_page_table
190 l1_page_table:
191         .skip           1024