e6b4d3503b8985d11842701834dfb97d9237b47b
[akaros.git] / kern / arch / riscv / kernel.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_ARCH("riscv")
5 ENTRY(_start)
6
7 SECTIONS
8 {
9         /* Link the kernel for 0xFFFFFFFF80002000, but load it at 0x2000) */
10
11         .text 0xFFFFFFFF80002000 : AT(0x2000) {
12                 *(.text .stub .text.* .gnu.linkonce.t.*)
13         }
14
15         PROVIDE(etext = .);     /* Define the 'etext' symbol to this value */
16
17         .rodata : {
18                 *(.rodata .rodata.* .gnu.linkonce.r.*)
19         }
20
21         /* Include debugging information in kernel memory */
22         .stab : {
23                 PROVIDE(stab = .);
24                 PROVIDE(__STAB_BEGIN__ = .);
25                 *(.stab);
26                 PROVIDE(estab = .);
27                 PROVIDE(__STAB_END__ = .);
28                 BYTE(0)         /* Force the linker to allocate space
29                                    for this section */
30         }
31
32         .stabstr : {
33                 PROVIDE(stabstr = .);
34                 PROVIDE(__STABSTR_BEGIN__ = .);
35                 *(.stabstr);
36                 PROVIDE(estabstr = .);
37                 PROVIDE(__STABSTR_END__ = .);
38                 BYTE(0)         /* Force the linker to allocate space
39                                    for this section */
40         }
41
42         /* Adjust the address for the data segment to the next page */
43         . = ALIGN(0x1000);
44
45         /* The data segment */
46         .data : {
47                 *(.data)
48                 *(.sdata)
49         }
50
51         PROVIDE(edata = .);
52
53         .bss : {
54                 *(.bss)
55                 *(.sbss)
56         }
57
58         PROVIDE(end = .);
59
60         /DISCARD/ : {
61                 *(.eh_frame .note.GNU-stack)
62         }
63 }