Fix 8 space tab formatting for non-C files
[akaros.git] / kern / arch / riscv / kernel.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_ARCH("riscv")
5 ENTRY(_start)
6
7 SECTIONS
8 {
9         /* Link the kernel for 0xFFFFFFFF80002000, but load it at 0x2000) */
10
11         .text 0xFFFFFFFF80002000 : AT(0x2000) {
12                 *(.text .stub .text.* .gnu.linkonce.t.*)
13                 /* Define the 'etext' symbol to this value */
14                 PROVIDE(etext = .);
15         }
16
17         INCLUDE kern/linker_tables.ld
18         INCLUDE kern/build_id.ld
19
20         .rodata : {
21                 *(.rodata .rodata.* .gnu.linkonce.r.*)
22         }
23
24         /* Adjust the address for the data segment to the next page */
25         . = ALIGN(0x1000);
26
27         /* The data segment */
28         .data : {
29                 *(.data)
30                 *(.sdata)
31         }
32
33         .bss : {
34                 PROVIDE(__start_bss = .);
35                 *(.bss)
36                 *(.sbss)
37                 PROVIDE(__stop_bss = .);
38         }
39
40         .end : {
41                 PROVIDE(end = .);
42         }
43
44         /DISCARD/ : {
45                 *(.eh_frame .note.GNU-stack)
46         }
47 }