VMM: Clean up per-cpu VMCS state
[akaros.git] / kern / arch / riscv / kernel.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_ARCH("riscv")
5 ENTRY(_start)
6
7 SECTIONS
8 {
9         /* Link the kernel for 0xFFFFFFFF80002000, but load it at 0x2000) */
10
11         .text 0xFFFFFFFF80002000 : AT(0x2000) {
12                 *(.text .stub .text.* .gnu.linkonce.t.*)
13         }
14
15         PROVIDE(etext = .);     /* Define the 'etext' symbol to this value */
16
17         INCLUDE kern/linker_tables.ld
18
19         .rodata : {
20                 *(.rodata .rodata.* .gnu.linkonce.r.*)
21         }
22
23         /* Include debugging information in kernel memory */
24         .stab : {
25                 PROVIDE(stab = .);
26                 PROVIDE(__STAB_BEGIN__ = .);
27                 *(.stab);
28                 PROVIDE(estab = .);
29                 PROVIDE(__STAB_END__ = .);
30                 BYTE(0)         /* Force the linker to allocate space
31                                    for this section */
32         }
33
34         .stabstr : {
35                 PROVIDE(stabstr = .);
36                 PROVIDE(__STABSTR_BEGIN__ = .);
37                 *(.stabstr);
38                 PROVIDE(estabstr = .);
39                 PROVIDE(__STABSTR_END__ = .);
40                 BYTE(0)         /* Force the linker to allocate space
41                                    for this section */
42         }
43
44         /* Adjust the address for the data segment to the next page */
45         . = ALIGN(0x1000);
46
47         /* The data segment */
48         .data : {
49                 *(.data)
50                 *(.sdata)
51         }
52
53         .bss : {
54                 PROVIDE(__start_bss = .);
55                 *(.bss)
56                 *(.sbss)
57                 PROVIDE(__stop_bss = .);
58         }
59
60         PROVIDE(end = .);
61
62         /DISCARD/ : {
63                 *(.eh_frame .note.GNU-stack)
64         }
65 }