Support new risc-v calling convention
[akaros.git] / kern / arch / riscv / entry.S
1 #include <arch/pcr.h>
2 #include <arch/trap.h>
3 #include <ros/memlayout.h>
4
5 #ifdef __riscv64
6 # define STORE    sd
7 # define LOAD     ld
8 # define LOG_REGBYTES 3
9 #else
10 # define STORE    sw
11 # define LOAD     lw
12 # define LOG_REGBYTES 2
13 #endif
14 #define REGBYTES (1 << LOG_REGBYTES)
15
16   .text
17   .global save_kernel_tf_asm
18 save_kernel_tf_asm:
19   mfpcr  a1,ASM_CR(PCR_SR)
20
21   STORE  s0,20*REGBYTES(a0)
22   STORE  s1,21*REGBYTES(a0)
23   STORE  s2,22*REGBYTES(a0)
24   STORE  s3,23*REGBYTES(a0)
25   STORE  s4,24*REGBYTES(a0)
26   STORE  s5,25*REGBYTES(a0)
27   STORE  s6,26*REGBYTES(a0)
28   STORE  s7,27*REGBYTES(a0)
29   STORE  s8,28*REGBYTES(a0)
30   STORE  s9,29*REGBYTES(a0)
31   STORE  sp,30*REGBYTES(a0)
32
33   STORE  a1,32*REGBYTES(a0)
34
35   # set EPC to this function's return address
36   STORE  ra,33*REGBYTES(a0)
37   ret
38
39   .text
40   .global pop_kernel_ctx
41 pop_kernel_ctx:
42   LOAD  a1,32*REGBYTES(a0)
43   LOAD  ra,33*REGBYTES(a0)
44
45   LOAD  s0,20*REGBYTES(a0)
46   LOAD  s1,21*REGBYTES(a0)
47   LOAD  s2,22*REGBYTES(a0)
48   LOAD  s3,23*REGBYTES(a0)
49   LOAD  s4,24*REGBYTES(a0)
50   LOAD  s5,25*REGBYTES(a0)
51   LOAD  s6,26*REGBYTES(a0)
52   LOAD  s7,27*REGBYTES(a0)
53   LOAD  s8,28*REGBYTES(a0)
54   LOAD  s9,29*REGBYTES(a0)
55   LOAD  sp,30*REGBYTES(a0)
56
57   mtpcr  a1,ASM_CR(PCR_SR)
58   ret
59
60
61 save_tf:  # write the trap frame onto the stack
62
63   ret
64
65   .globl  env_pop_tf
66 env_pop_tf:  # write the trap frame onto the stack
67   # restore gprs
68   LOAD  v0,32*REGBYTES(a0)  # restore sr (should disable interrupts)
69   mfpcr v1, ASM_CR(PCR_SR)
70   andi  v1, v1, ~(SR_PS | SR_EF | SR_U64)
71   andi  v0, v0, SR_PS | SR_EF | SR_U64
72   or    v0, v0, v1
73   mtpcr v0, ASM_CR(PCR_SR)
74
75   LOAD  x1,1*REGBYTES(a0)
76   mtpcr  x1,ASM_CR(PCR_K0)
77   LOAD  x1,2*REGBYTES(a0)
78   mtpcr x1,ASM_CR(PCR_K1)
79   move  x1,a0
80   LOAD  x3,3*REGBYTES(x1)
81   LOAD  x4,4*REGBYTES(x1)
82   LOAD  x5,5*REGBYTES(x1)
83   LOAD  x6,6*REGBYTES(x1)
84   LOAD  x7,7*REGBYTES(x1)
85   LOAD  x8,8*REGBYTES(x1)
86   LOAD  x9,9*REGBYTES(x1)
87   LOAD  x10,10*REGBYTES(x1)
88   LOAD  x11,11*REGBYTES(x1)
89   LOAD  x12,12*REGBYTES(x1)
90   LOAD  x13,13*REGBYTES(x1)
91   LOAD  x14,14*REGBYTES(x1)
92   LOAD  x15,15*REGBYTES(x1)
93   LOAD  x16,16*REGBYTES(x1)
94   LOAD  x17,17*REGBYTES(x1)
95   LOAD  x18,18*REGBYTES(x1)
96   LOAD  x19,19*REGBYTES(x1)
97   LOAD  x20,20*REGBYTES(x1)
98   LOAD  x21,21*REGBYTES(x1)
99   LOAD  x22,22*REGBYTES(x1)
100   LOAD  x23,23*REGBYTES(x1)
101   LOAD  x24,24*REGBYTES(x1)
102   LOAD  x25,25*REGBYTES(x1)
103   LOAD  x26,26*REGBYTES(x1)
104   LOAD  x27,27*REGBYTES(x1)
105   LOAD  x28,28*REGBYTES(x1)
106   LOAD  x29,29*REGBYTES(x1)
107   LOAD  x30,30*REGBYTES(x1)
108   LOAD  x31,31*REGBYTES(x1)
109
110   # gtfo!
111   LOAD  x2,33*REGBYTES(x1)
112   mtpcr x2,ASM_CR(PCR_EPC)
113   mfpcr x1,ASM_CR(PCR_K0)
114   mfpcr x2,ASM_CR(PCR_K1)
115   eret
116
117   .global  trap_entry
118 trap_entry:
119   mtpcr x1, ASM_CR(PCR_K0)  # stash x1 in k0
120   mfpcr x1, ASM_CR(PCR_SR)
121   mtpcr x2, ASM_CR(PCR_K1)  # stash x2 in k1
122   # when coming from kernel, continue below its stack
123   add   x2, sp, -SIZEOF_HW_TRAPFRAME
124   and   x1, x1, SR_PS
125   bnez  x1, 1f
126
127   # otherwise, start at the top of the per-core stack
128   mfpcr x1, ASM_CR(PCR_COREID)
129   lui   x2, %hi(core_stacktops)
130   sll   x1, x1, LOG_REGBYTES
131   add   x2, x2, x1
132   LOAD  x2, %lo(core_stacktops)(x2)
133   add   x2, x2, -SIZEOF_HW_TRAPFRAME
134
135 1:# save gprs
136   STORE  x3,3*REGBYTES(x2)
137   STORE  x4,4*REGBYTES(x2)
138   mfpcr  x3,ASM_CR(PCR_K0)    # retrieve x1
139   mfpcr  x4,ASM_CR(PCR_K1)    # retrieve x2
140   STORE  x5,5*REGBYTES(x2)
141   STORE  x6,6*REGBYTES(x2)
142   STORE  x7,7*REGBYTES(x2)
143   STORE  x8,8*REGBYTES(x2)
144   STORE  x9,9*REGBYTES(x2)
145   STORE  x3,1*REGBYTES(x2)    # save x1
146   STORE  x4,2*REGBYTES(x2)    # save x2
147   STORE  x10,10*REGBYTES(x2)
148   STORE  x11,11*REGBYTES(x2)
149   STORE  x12,12*REGBYTES(x2)
150   STORE  x13,13*REGBYTES(x2)
151   STORE  x14,14*REGBYTES(x2)
152   STORE  x15,15*REGBYTES(x2)
153   STORE  x16,16*REGBYTES(x2)
154   STORE  x17,17*REGBYTES(x2)
155   STORE  x18,18*REGBYTES(x2)
156   STORE  x19,19*REGBYTES(x2)
157   STORE  x20,20*REGBYTES(x2)
158   STORE  x21,21*REGBYTES(x2)
159   STORE  x22,22*REGBYTES(x2)
160   STORE  x23,23*REGBYTES(x2)
161   STORE  x24,24*REGBYTES(x2)
162   STORE  x25,25*REGBYTES(x2)
163   STORE  x26,26*REGBYTES(x2)
164   STORE  x27,27*REGBYTES(x2)
165   STORE  x28,28*REGBYTES(x2)
166   STORE  x29,29*REGBYTES(x2)
167   STORE  x30,30*REGBYTES(x2)
168   STORE  x31,31*REGBYTES(x2)
169
170   # get sr, epc, badvaddr, cause
171   mfpcr  x3,ASM_CR(PCR_SR)
172   mfpcr  x4,ASM_CR(PCR_EPC)
173   mfpcr  x5,ASM_CR(PCR_BADVADDR)
174   mfpcr  x6,ASM_CR(PCR_CAUSE)
175   STORE  x3,32*REGBYTES(x2)
176   STORE  x4,33*REGBYTES(x2)
177   STORE  x5,34*REGBYTES(x2)
178   STORE  x6,35*REGBYTES(x2)
179
180   move  sp, x2
181   move  a0, x2
182   j     handle_trap
183
184   .global  cpu_halt
185   .global  after_cpu_halt
186 cpu_halt:
187   setpcr ASM_CR(PCR_SR), SR_ET
188 1:b     1b   # handle_ipi can advance the PC to break out of this loop.
189   ret
190 after_cpu_halt: