for risc-v, don't store irq mask in trapframe
[akaros.git] / kern / arch / riscv / entry.S
1 #include <arch/pcr.h>
2 #include <arch/trap.h>
3 #include <ros/memlayout.h>
4
5 #ifdef __riscv64
6 # define STORE    sd
7 # define LOAD     ld
8 # define LOG_REGBYTES 3
9 #else
10 # define STORE    sw
11 # define LOAD     lw
12 # define LOG_REGBYTES 2
13 #endif
14 #define REGBYTES (1 << LOG_REGBYTES)
15
16   .text
17   .ent    save_kernel_tf_asm
18   .global save_kernel_tf_asm
19 save_kernel_tf_asm:
20   STORE  s0,20*REGBYTES(a0)
21   STORE  s1,21*REGBYTES(a0)
22   STORE  s2,22*REGBYTES(a0)
23   STORE  s3,23*REGBYTES(a0)
24   STORE  s4,24*REGBYTES(a0)
25   STORE  s5,25*REGBYTES(a0)
26   STORE  s6,26*REGBYTES(a0)
27   STORE  s7,27*REGBYTES(a0)
28   STORE  s8,28*REGBYTES(a0)
29   STORE  s9,29*REGBYTES(a0)
30   STORE  sp,30*REGBYTES(a0)
31
32   mfpcr  t0,ASM_CR(PCR_SR)
33   STORE  t0,32*REGBYTES(a0)
34
35   # set EPC to this function's return address
36   STORE  ra,33*REGBYTES(a0)
37   ret
38   .end  save_kernel_tf_asm
39
40   .text
41   .ent    pop_kernel_tf
42   .global pop_kernel_tf
43 pop_kernel_tf:
44   LOAD  t0,32*REGBYTES(a0)
45   LOAD  ra,33*REGBYTES(a0)
46
47   LOAD  s0,20*REGBYTES(a0)
48   LOAD  s1,21*REGBYTES(a0)
49   LOAD  s2,22*REGBYTES(a0)
50   LOAD  s3,23*REGBYTES(a0)
51   LOAD  s4,24*REGBYTES(a0)
52   LOAD  s5,25*REGBYTES(a0)
53   LOAD  s6,26*REGBYTES(a0)
54   LOAD  s7,27*REGBYTES(a0)
55   LOAD  s8,28*REGBYTES(a0)
56   LOAD  s9,29*REGBYTES(a0)
57   LOAD  sp,30*REGBYTES(a0)
58
59   mtpcr  t0,ASM_CR(PCR_SR)
60   ret
61
62   .end  pop_kernel_tf
63
64   .ent  save_tf
65 save_tf:  # write the trap frame onto the stack
66
67   ret
68   .end  save_tf
69
70   .globl  env_pop_tf
71   .ent  env_pop_tf
72 env_pop_tf:  # write the trap frame onto the stack
73   # restore gprs
74   LOAD  t0,32*REGBYTES(a0)  # restore sr (should disable interrupts)
75   mfpcr t1, ASM_CR(PCR_SR)
76   andi  t1, t1, ~(SR_PS | SR_EF | SR_U64)
77   andi  t0, t0, SR_PS | SR_EF | SR_U64
78   or    t0, t0, t1
79   mtpcr t0, ASM_CR(PCR_SR)
80
81   LOAD  x1,1*REGBYTES(a0)
82   mtpcr  x1,ASM_CR(PCR_K0)
83   LOAD  x1,2*REGBYTES(a0)
84   mtpcr x1,ASM_CR(PCR_K1)
85   move  x1,a0
86   LOAD  x3,3*REGBYTES(x1)
87   LOAD  x4,4*REGBYTES(x1)
88   LOAD  x5,5*REGBYTES(x1)
89   LOAD  x6,6*REGBYTES(x1)
90   LOAD  x7,7*REGBYTES(x1)
91   LOAD  x8,8*REGBYTES(x1)
92   LOAD  x9,9*REGBYTES(x1)
93   LOAD  x10,10*REGBYTES(x1)
94   LOAD  x11,11*REGBYTES(x1)
95   LOAD  x12,12*REGBYTES(x1)
96   LOAD  x13,13*REGBYTES(x1)
97   LOAD  x14,14*REGBYTES(x1)
98   LOAD  x15,15*REGBYTES(x1)
99   LOAD  x16,16*REGBYTES(x1)
100   LOAD  x17,17*REGBYTES(x1)
101   LOAD  x18,18*REGBYTES(x1)
102   LOAD  x19,19*REGBYTES(x1)
103   LOAD  x20,20*REGBYTES(x1)
104   LOAD  x21,21*REGBYTES(x1)
105   LOAD  x22,22*REGBYTES(x1)
106   LOAD  x23,23*REGBYTES(x1)
107   LOAD  x24,24*REGBYTES(x1)
108   LOAD  x25,25*REGBYTES(x1)
109   LOAD  x26,26*REGBYTES(x1)
110   LOAD  x27,27*REGBYTES(x1)
111   LOAD  x28,28*REGBYTES(x1)
112   LOAD  x29,29*REGBYTES(x1)
113   LOAD  x30,30*REGBYTES(x1)
114   LOAD  x31,31*REGBYTES(x1)
115
116   # gtfo!
117   LOAD  x2,33*REGBYTES(x1)
118   mtpcr x2,ASM_CR(PCR_EPC)
119   mfpcr x1,ASM_CR(PCR_K0)
120   mfpcr x2,ASM_CR(PCR_K1)
121   eret
122   .end  env_pop_tf
123
124   .global  trap_entry
125   .ent  trap_entry
126 trap_entry:
127   # save x1 and x2 so we can use them as temporaries
128   mtpcr x1, ASM_CR(PCR_K0)
129   mtpcr x2, ASM_CR(PCR_K1)
130
131   # when coming from kernel, continue below its stack
132   mfpcr x1, ASM_CR(PCR_SR)
133   and   x1, x1, SR_PS
134   add   x2, sp, -SIZEOF_TRAPFRAME_T
135   bnez  x1, 1f
136
137   # otherwise, start at the top of the per-core stack
138   la    x2, core_stacktops
139   mfpcr x1, ASM_CR(PCR_COREID)
140   sll   x1, x1, LOG_REGBYTES
141   add   x2, x2, x1
142   LOAD  x2, 0(x2)
143   add   x2, x2, -SIZEOF_TRAPFRAME_T
144
145 1:# save gprs
146   STORE  x3,3*REGBYTES(x2)
147   STORE  x4,4*REGBYTES(x2)
148   STORE  x5,5*REGBYTES(x2)
149   STORE  x6,6*REGBYTES(x2)
150   STORE  x7,7*REGBYTES(x2)
151   STORE  x8,8*REGBYTES(x2)
152   STORE  x9,9*REGBYTES(x2)
153   STORE  x10,10*REGBYTES(x2)
154   STORE  x11,11*REGBYTES(x2)
155   STORE  x12,12*REGBYTES(x2)
156   STORE  x13,13*REGBYTES(x2)
157   STORE  x14,14*REGBYTES(x2)
158   STORE  x15,15*REGBYTES(x2)
159   STORE  x16,16*REGBYTES(x2)
160   STORE  x17,17*REGBYTES(x2)
161   STORE  x18,18*REGBYTES(x2)
162   STORE  x19,19*REGBYTES(x2)
163   STORE  x20,20*REGBYTES(x2)
164   STORE  x21,21*REGBYTES(x2)
165   STORE  x22,22*REGBYTES(x2)
166   STORE  x23,23*REGBYTES(x2)
167   STORE  x24,24*REGBYTES(x2)
168   STORE  x25,25*REGBYTES(x2)
169   STORE  x26,26*REGBYTES(x2)
170   STORE  x27,27*REGBYTES(x2)
171   STORE  x28,28*REGBYTES(x2)
172   STORE  x29,29*REGBYTES(x2)
173   STORE  x30,30*REGBYTES(x2)
174   STORE  x31,31*REGBYTES(x2)
175
176   mfpcr  x3,ASM_CR(PCR_K0)
177   STORE  x3,1*REGBYTES(x2)          # x1 is in PCR_K0
178   mfpcr  x3,ASM_CR(PCR_K1)
179   STORE  x3,2*REGBYTES(x2)          # x2 is in PCR_K1
180
181   # get sr, epc, badvaddr, cause
182   mfpcr  x3,ASM_CR(PCR_SR)          # sr
183   STORE  x3,32*REGBYTES(x2)
184   mfpcr  x4,ASM_CR(PCR_EPC)          # epc
185   STORE  x4,33*REGBYTES(x2)
186   mfpcr  x3,ASM_CR(PCR_BADVADDR)      # badvaddr
187   STORE  x3,34*REGBYTES(x2)
188   mfpcr  x3,ASM_CR(PCR_CAUSE)        # cause
189   STORE  x3,35*REGBYTES(x2)
190
191   li    s9, 0
192   move  sp, x2
193   move  a0, x2
194   j     handle_trap
195   .end  trap_entry
196
197   .global  cpu_halt
198   .global  after_cpu_halt
199   .ent  cpu_halt
200 cpu_halt:
201   setpcr ASM_CR(PCR_SR), SR_ET
202 1:b     1b   # handle_ipi can advance the PC to break out of this loop.
203   ret
204 after_cpu_halt:
205   .end  cpu_halt