08d0369d21a010044a3e68bd1c84715d80b88971
[akaros.git] / kern / arch / riscv / entry.S
1 #include <arch/pcr.h>
2 #include <arch/trap.h>
3 #include <ros/memlayout.h>
4
5 #ifdef __riscv64
6 # define STORE    sd
7 # define LOAD     ld
8 # define LOG_REGBYTES 3
9 #else
10 # define STORE    sw
11 # define LOAD     lw
12 # define LOG_REGBYTES 2
13 #endif
14 #define REGBYTES (1 << LOG_REGBYTES)
15
16   .text
17   .global save_kernel_tf_asm
18 save_kernel_tf_asm:
19   STORE  s0,20*REGBYTES(a0)
20   STORE  s1,21*REGBYTES(a0)
21   STORE  s2,22*REGBYTES(a0)
22   STORE  s3,23*REGBYTES(a0)
23   STORE  s4,24*REGBYTES(a0)
24   STORE  s5,25*REGBYTES(a0)
25   STORE  s6,26*REGBYTES(a0)
26   STORE  s7,27*REGBYTES(a0)
27   STORE  s8,28*REGBYTES(a0)
28   STORE  s9,29*REGBYTES(a0)
29   STORE  sp,30*REGBYTES(a0)
30
31   mfpcr  t0,ASM_CR(PCR_SR)
32   STORE  t0,32*REGBYTES(a0)
33
34   # set EPC to this function's return address
35   STORE  ra,33*REGBYTES(a0)
36   ret
37
38   .text
39   .global pop_kernel_tf
40 pop_kernel_tf:
41   LOAD  t0,32*REGBYTES(a0)
42   LOAD  ra,33*REGBYTES(a0)
43
44   LOAD  s0,20*REGBYTES(a0)
45   LOAD  s1,21*REGBYTES(a0)
46   LOAD  s2,22*REGBYTES(a0)
47   LOAD  s3,23*REGBYTES(a0)
48   LOAD  s4,24*REGBYTES(a0)
49   LOAD  s5,25*REGBYTES(a0)
50   LOAD  s6,26*REGBYTES(a0)
51   LOAD  s7,27*REGBYTES(a0)
52   LOAD  s8,28*REGBYTES(a0)
53   LOAD  s9,29*REGBYTES(a0)
54   LOAD  sp,30*REGBYTES(a0)
55
56   mtpcr  t0,ASM_CR(PCR_SR)
57   ret
58
59
60 save_tf:  # write the trap frame onto the stack
61
62   ret
63
64   .globl  env_pop_tf
65 env_pop_tf:  # write the trap frame onto the stack
66   # restore gprs
67   LOAD  t0,32*REGBYTES(a0)  # restore sr (should disable interrupts)
68   mfpcr t1, ASM_CR(PCR_SR)
69   andi  t1, t1, ~(SR_PS | SR_EF | SR_U64)
70   andi  t0, t0, SR_PS | SR_EF | SR_U64
71   or    t0, t0, t1
72   mtpcr t0, ASM_CR(PCR_SR)
73
74   LOAD  x1,1*REGBYTES(a0)
75   mtpcr  x1,ASM_CR(PCR_K0)
76   LOAD  x1,2*REGBYTES(a0)
77   mtpcr x1,ASM_CR(PCR_K1)
78   move  x1,a0
79   LOAD  x3,3*REGBYTES(x1)
80   LOAD  x4,4*REGBYTES(x1)
81   LOAD  x5,5*REGBYTES(x1)
82   LOAD  x6,6*REGBYTES(x1)
83   LOAD  x7,7*REGBYTES(x1)
84   LOAD  x8,8*REGBYTES(x1)
85   LOAD  x9,9*REGBYTES(x1)
86   LOAD  x10,10*REGBYTES(x1)
87   LOAD  x11,11*REGBYTES(x1)
88   LOAD  x12,12*REGBYTES(x1)
89   LOAD  x13,13*REGBYTES(x1)
90   LOAD  x14,14*REGBYTES(x1)
91   LOAD  x15,15*REGBYTES(x1)
92   LOAD  x16,16*REGBYTES(x1)
93   LOAD  x17,17*REGBYTES(x1)
94   LOAD  x18,18*REGBYTES(x1)
95   LOAD  x19,19*REGBYTES(x1)
96   LOAD  x20,20*REGBYTES(x1)
97   LOAD  x21,21*REGBYTES(x1)
98   LOAD  x22,22*REGBYTES(x1)
99   LOAD  x23,23*REGBYTES(x1)
100   LOAD  x24,24*REGBYTES(x1)
101   LOAD  x25,25*REGBYTES(x1)
102   LOAD  x26,26*REGBYTES(x1)
103   LOAD  x27,27*REGBYTES(x1)
104   LOAD  x28,28*REGBYTES(x1)
105   LOAD  x29,29*REGBYTES(x1)
106   LOAD  x30,30*REGBYTES(x1)
107   LOAD  x31,31*REGBYTES(x1)
108
109   # gtfo!
110   LOAD  x2,33*REGBYTES(x1)
111   mtpcr x2,ASM_CR(PCR_EPC)
112   mfpcr x1,ASM_CR(PCR_K0)
113   mfpcr x2,ASM_CR(PCR_K1)
114   eret
115
116   .global  trap_entry
117 trap_entry:
118   # save x1 and x2 so we can use them as temporaries
119   mtpcr x1, ASM_CR(PCR_K0)
120   mtpcr x2, ASM_CR(PCR_K1)
121
122   # when coming from kernel, continue below its stack
123   mfpcr x1, ASM_CR(PCR_SR)
124   and   x1, x1, SR_PS
125   add   x2, sp, -SIZEOF_TRAPFRAME_T
126   bnez  x1, 1f
127
128   # otherwise, start at the top of the per-core stack
129   la    x2, core_stacktops
130   mfpcr x1, ASM_CR(PCR_COREID)
131   sll   x1, x1, LOG_REGBYTES
132   add   x2, x2, x1
133   LOAD  x2, 0(x2)
134   add   x2, x2, -SIZEOF_TRAPFRAME_T
135
136 1:# save gprs
137   STORE  x3,3*REGBYTES(x2)
138   STORE  x4,4*REGBYTES(x2)
139   STORE  x5,5*REGBYTES(x2)
140   STORE  x6,6*REGBYTES(x2)
141   STORE  x7,7*REGBYTES(x2)
142   STORE  x8,8*REGBYTES(x2)
143   STORE  x9,9*REGBYTES(x2)
144   STORE  x10,10*REGBYTES(x2)
145   STORE  x11,11*REGBYTES(x2)
146   STORE  x12,12*REGBYTES(x2)
147   STORE  x13,13*REGBYTES(x2)
148   STORE  x14,14*REGBYTES(x2)
149   STORE  x15,15*REGBYTES(x2)
150   STORE  x16,16*REGBYTES(x2)
151   STORE  x17,17*REGBYTES(x2)
152   STORE  x18,18*REGBYTES(x2)
153   STORE  x19,19*REGBYTES(x2)
154   STORE  x20,20*REGBYTES(x2)
155   STORE  x21,21*REGBYTES(x2)
156   STORE  x22,22*REGBYTES(x2)
157   STORE  x23,23*REGBYTES(x2)
158   STORE  x24,24*REGBYTES(x2)
159   STORE  x25,25*REGBYTES(x2)
160   STORE  x26,26*REGBYTES(x2)
161   STORE  x27,27*REGBYTES(x2)
162   STORE  x28,28*REGBYTES(x2)
163   STORE  x29,29*REGBYTES(x2)
164   STORE  x30,30*REGBYTES(x2)
165   STORE  x31,31*REGBYTES(x2)
166
167   mfpcr  x3,ASM_CR(PCR_K0)
168   STORE  x3,1*REGBYTES(x2)          # x1 is in PCR_K0
169   mfpcr  x3,ASM_CR(PCR_K1)
170   STORE  x3,2*REGBYTES(x2)          # x2 is in PCR_K1
171
172   # get sr, epc, badvaddr, cause
173   mfpcr  x3,ASM_CR(PCR_SR)          # sr
174   STORE  x3,32*REGBYTES(x2)
175   mfpcr  x4,ASM_CR(PCR_EPC)          # epc
176   STORE  x4,33*REGBYTES(x2)
177   mfpcr  x3,ASM_CR(PCR_BADVADDR)      # badvaddr
178   STORE  x3,34*REGBYTES(x2)
179   mfpcr  x3,ASM_CR(PCR_CAUSE)        # cause
180   STORE  x3,35*REGBYTES(x2)
181
182   li    s9, 0
183   move  sp, x2
184   move  a0, x2
185   j     handle_trap
186
187   .global  cpu_halt
188   .global  after_cpu_halt
189 cpu_halt:
190   setpcr ASM_CR(PCR_SR), SR_ET
191 1:b     1b   # handle_ipi can advance the PC to break out of this loop.
192   ret
193 after_cpu_halt: