Updated RISC-V boot sequence; use 8KB pages
[akaros.git] / kern / arch / riscv / boot.S
1 /* See COPYRIGHT for copyright information. */
2
3 #include <arch/pcr.h>
4 #include <ros/arch/arch.h>
5 #include <ros/memlayout.h>
6 #incldue <arch/mmu.h>
7
8 ///////////////////////////////////////////////////////////////////
9 // The kernel (this code) is linked at address 0xFFFFFFFF80000000,
10 // but we tell the bootloader to load it at physical address 
11 // 0x00000000, which is the start of extended memory.
12 // (See kernel.ld)
13 ///////////////////////////////////////////////////////////////////
14
15 ///////////////////////////////////////////////////////////////////
16 // entry point
17 ///////////////////////////////////////////////////////////////////
18
19 #define PCR0 (SR_S | SR_ET | SR_SX)
20 .text
21
22 .global _start
23 .ent _start
24 _start:
25   // This is the first kernel code that executes; it is run only by core 0.
26
27   // set up trap entry point.  this is not a relocated address, as we
28   // do not support trapping before the MMU is set up.
29   la     t0, trap_entry
30   mtpcr  t0, ASM_CR(PCR_EVEC)
31
32   // enable traps
33   li     t0, PCR0
34   mtpcr  t0, ASM_CR(PCR_SR)
35
36   // core 0?
37   mfpcr  t0, ASM_CR(PCR_COREID)
38   bnez   t0, notcore0
39
40   // set up stack
41   la     sp, bootstacktop
42   li     t1, KERN_LOAD_ADDR
43   sub    sp, sp, t1
44
45   // set up initial page mappings
46   la     a0, l1pt
47   sub    a0, a0, t1
48   la     a1, l1pt_boot
49   sub    a1, a1, t1
50 #ifdef __riscv64
51   la     a2, l2pt
52   sub    a2, a1, t1
53 #endif
54   jal    pagetable_init
55   jal    enable_mmu
56
57   // relocate stack and call into C code using absolute jump, not pc-relative
58   la     sp, bootstacktop
59   la     t0, cmain
60   jr     t0
61
62 notcore0:
63   // set up stack: sp = percoore_stacks+(core_id()+1)*KSTKSIZE
64   la     sp, percore_stacks
65   add    t0, t0, 1
66   sll    t0, t0, KSTKSHIFT
67   add    sp, sp, t0
68   li     t1, KERN_LOAD_ADDR
69   sub    sp, sp, t1
70   
71   jal    enable_mmu
72
73   // relocate stack and call into C code
74   li     t1, KERN_LOAD_ADDR
75   add    sp, sp, t1
76   la     t0, smp_init
77   jr     t0
78
79 .end _start
80
81 .ent enable_mmu
82 enable_mmu:
83   la     t0, l1pt_boot
84   li     t1, KERN_LOAD_ADDR
85   sub    t0, t0, t1
86   mtpcr  t0, ASM_CR(PCR_PTBR)
87   li     t0, PCR0 | SR_VM
88   mtpcr  t0, ASM_CR(PCR_SR)
89   ret
90 .end enable_mmu
91
92 ///////////////////////////////////////////////////////////////////
93 // boot stack and regular stacks.
94 // (boot stack cannot be in .bss, as .bss is later zereoed by the kernel.)
95 ///////////////////////////////////////////////////////////////////
96
97 .data
98   .align  PGSHIFT
99 l1pt_boot:
100   .space  PGSIZE
101 .global l1pt
102 l1pt:
103   .space  PGSIZE
104 l2pt:
105   .space  PGSIZE
106
107   .space  KSTKSIZE
108   .global bootstacktop
109 bootstacktop:
110
111 .bss
112   .align  PGSHIFT
113   .global percore_stacks
114 percore_stacks:
115   .space  KSTKSIZE*MAX_NUM_CPUS