6947dbee96383f0e1584bb4419178f84e49adbfa
[akaros.git] / kern / arch / riscv / boot.S
1 /* See COPYRIGHT for copyright information. */
2
3 #include <arch/pcr.h>
4 #include <ros/arch/arch.h>
5 #include <ros/memlayout.h>
6 #incldue <arch/mmu.h>
7
8 ///////////////////////////////////////////////////////////////////
9 // The kernel (this code) is linked at address 0xFFFFFFFF80000000,
10 // but we tell the bootloader to load it at physical address 
11 // 0x00000000, which is the start of extended memory.
12 // (See kernel.ld)
13 ///////////////////////////////////////////////////////////////////
14
15 ///////////////////////////////////////////////////////////////////
16 // entry point
17 ///////////////////////////////////////////////////////////////////
18
19 .section ".boottext"
20
21 .global _start
22 _start:
23   // This is the first kernel code that executes; it is run only by core 0.
24
25   // set up trap entry point.  this is not a relocated address, as we
26   // do not support trapping before the MMU is set up.
27   la     $t0, trap_entry
28   mtpcr  $t0, ASM_CR(PCR_EVEC)
29
30   // enable traps
31   li     $t0, SR_S | SR_ET | SR_SX
32   mtpcr  $t0, ASM_CR(PCR_SR)
33
34   // core 0?
35   mfpcr  $t0, ASM_CR(PCR_COREID)
36   bnez   $t0, notcore0
37
38   // set up stack and terminate frame pointer for backtracing
39   li     $fp, 0
40   la     $sp, bootstacktop
41   li     $t1, LOAD_ADDR
42   sub    $sp, $sp, $t1
43
44   // set up initial page mappings
45   la     $a0, l1pt
46   sub    $a0, $a0, $t1
47   la     $a1, l1pt_boot
48   sub    $a1, $a1, $t1
49 #ifdef __riscv64
50   la     $a2, l2pt
51   sub    $a2, $a2, $t1
52 #endif
53   jal    pagetable_init
54
55   // turn on MMU
56   la     $a0, l1pt_boot
57   sub    $a0, $a0, $t1
58   jal    mmu_init
59
60   // relocate stack and call into C code using absolute jump, not pc-relative
61   la     $sp, bootstacktop
62   lui    $t0, %hi(cmain)
63   jalr.j $t0, %lo(cmain)
64
65 notcore0:
66   // set up stack and terminate frame pointer for backtracing
67   // sp = percoore_stacks+(core_id()+1)*KSTKSIZE
68   li     $fp, 0
69   la     $sp, percore_stacks
70   add    $t0, $t0, 1
71   sll    $t0, $t0, KSTKSHIFT
72   add    $sp, $sp, $t0
73   li     $t1, LOAD_ADDR
74   sub    $sp, $sp, $t1
75   
76   // turn on MMU
77   la     $a0, l1pt_boot
78   sub    $a0, $a0, $t1
79   jal    mmu_init
80
81   // relocate stack and call into C code
82   li     $t1, LOAD_ADDR
83   add    $sp, $sp, $t1
84   lui    $t0, %hi(smp_init)
85   jalr.j $t0, %lo(smp_init)
86
87 ///////////////////////////////////////////////////////////////////
88 // boot stack and regular stacks.
89 // (boot stack cannot be in .bss, as .bss is later zereoed by the kernel.)
90 ///////////////////////////////////////////////////////////////////
91
92 .data
93   .align  PGSHIFT
94   .space  KSTKSIZE
95   .global bootstacktop
96 bootstacktop:
97
98 .bss
99   .align  PGSHIFT
100   .global percore_stacks
101 percore_stacks:
102   .space  KSTKSIZE*MAX_NUM_CPUS