14af7f1a6cf1ba2fd9e423826cc1e7e9be0b5b1e
[akaros.git] / kern / arch / riscv / boot.S
1 /* See COPYRIGHT for copyright information. */
2
3 #include <arch/pcr.h>
4 #include <ros/arch/arch.h>
5 #include <ros/memlayout.h>
6 #incldue <arch/mmu.h>
7
8 ///////////////////////////////////////////////////////////////////
9 // The kernel (this code) is linked at address 0xFFFFFFFF80000000,
10 // but we tell the bootloader to load it at physical address 
11 // 0x00000000, which is the start of extended memory.
12 // (See kernel.ld)
13 ///////////////////////////////////////////////////////////////////
14
15 ///////////////////////////////////////////////////////////////////
16 // entry point
17 ///////////////////////////////////////////////////////////////////
18
19 #define PCR0 (SR_S | SR_ET | SR_SX)
20 .text
21
22 .global _start
23 .ent _start
24 _start:
25   // This is the first kernel code that executes; it is run only by core 0.
26
27   // set up trap entry point.  this is not a relocated address, as we
28   // do not support trapping before the MMU is set up.
29   la     t0, trap_entry
30   mtpcr  t0, ASM_CR(PCR_EVEC)
31
32   // clear IPIs and enable traps
33   mtpcr  zero, ASM_CR(PCR_CLR_IPI)
34   li     t0, PCR0
35   mtpcr  t0, ASM_CR(PCR_SR)
36
37   // core 0?
38   mfpcr  t0, ASM_CR(PCR_COREID)
39   bnez   t0, notcore0
40
41   // terminate frame pointer for backtracing and set up stack
42   li     s9, 0
43   la     sp, bootstacktop
44   li     t1, KERN_LOAD_ADDR
45   sub    sp, sp, t1
46
47   // get memory size and core count from first two words of memory
48   lw     s0, 0(zero)
49   lw     s1, 4(zero)
50
51   // set up initial page mappings
52   move   a0, s0
53   la     a1, l1pt
54   sub    a1, a1, t1
55   la     a2, l1pt_boot
56   sub    a2, a2, t1
57 #ifdef __riscv64
58   la     a3, l2pt
59   sub    a3, a3, t1
60 #endif
61   jal    pagetable_init
62   jal    enable_mmu
63
64   // relocate stack and call into C code using absolute jump, not pc-relative
65   move   a0, s0
66   move   a1, s1
67   la     sp, bootstacktop
68   la     t0, cmain
69   jr     t0
70
71 notcore0:
72   // set up stack: sp = percoore_stacks+(core_id()+1)*KSTKSIZE
73   la     sp, percore_stacks
74   add    t0, t0, 1
75   sll    t0, t0, KSTKSHIFT
76   add    sp, sp, t0
77   li     t1, KERN_LOAD_ADDR
78   sub    sp, sp, t1
79   
80   jal    enable_mmu
81
82   // relocate stack and call into C code
83   li     t1, KERN_LOAD_ADDR
84   add    sp, sp, t1
85   la     t0, smp_init
86   jr     t0
87
88 .end _start
89
90 .ent enable_mmu
91 enable_mmu:
92   la     t0, l1pt_boot
93   li     t1, KERN_LOAD_ADDR
94   sub    t0, t0, t1
95   mtpcr  t0, ASM_CR(PCR_PTBR)
96   li     t0, PCR0 | SR_VM
97   mtpcr  t0, ASM_CR(PCR_SR)
98   ret
99 .end enable_mmu
100
101 ///////////////////////////////////////////////////////////////////
102 // boot stack and regular stacks.
103 // (boot stack cannot be in .bss, as .bss is later zereoed by the kernel.)
104 ///////////////////////////////////////////////////////////////////
105
106 .data
107   .align  PGSHIFT
108 l1pt_boot:
109   .space  PGSIZE
110 .global l1pt
111 l1pt:
112   .space  PGSIZE
113 l2pt:
114   .space  PGSIZE
115
116   .space  KSTKSIZE
117   .global bootstacktop
118 bootstacktop:
119
120 .bss
121   .align  PGSHIFT
122   .global percore_stacks
123 percore_stacks:
124   .space  KSTKSIZE*MAX_NUM_CPUS