x86: use a flat segmentation model
[akaros.git] / kern / arch / i686 / kernel.ld
1 /* Simple linker script for the ROS kernel.
2    See the GNU ld 'info' manual ("info ld") to learn the syntax. */
3
4 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
5 OUTPUT_ARCH(i386)
6 ENTRY(_start)
7 KERNBASE = 0xc0000000;
8
9 SECTIONS
10 {
11         /* Entry Linked and loaded at 0x00100000 (includes multiboot) */
12         . = 0x00100000;
13
14         .bootstrap : {
15                 obj/kern/arch/i686/entry.o (.text .bootdata)
16         }
17
18         /* Link the main kernel for the space after entry + KERNBASE.  We'll still
19          * load it adjacent in physical memory */
20         . += KERNBASE;
21
22         .text : AT(ADDR(.text) - KERNBASE) {
23                 *(.text .stub .text.* .gnu.linkonce.t.*)
24                 *(EXCLUDE_FILE(*obj/kern/arch/i686/entry.o) .text)
25         }
26
27         PROVIDE(etext = .);     /* Define the 'etext' symbol to this value */
28
29         .rodata : {
30                 *(.rodata .rodata.* .gnu.linkonce.r.*)
31         }
32
33         /* Include debugging information in kernel memory */
34         .stab : {
35                 PROVIDE(stab = .);
36                 PROVIDE(__STAB_BEGIN__ = .);
37                 *(.stab);
38                 PROVIDE(estab = .);
39                 PROVIDE(__STAB_END__ = .);
40                 BYTE(0)         /* Force the linker to allocate space
41                                    for this section */
42         }
43
44         .stabstr : {
45                 PROVIDE(stabstr = .);
46                 PROVIDE(__STABSTR_BEGIN__ = .);
47                 *(.stabstr);
48                 PROVIDE(estabstr = .);
49                 PROVIDE(__STABSTR_END__ = .);
50                 BYTE(0)         /* Force the linker to allocate space
51                                    for this section */
52         }
53
54         /* Adjust the address for the data segment to the next page */
55         . = ALIGN(0x1000);
56
57         /* The data segment */
58         .data : {
59                 *(.data)
60         }
61
62         PROVIDE(edata = .);
63
64         .bss : {
65                 *(.bss)
66         }
67
68         PROVIDE(end = .);
69
70         /DISCARD/ : {
71                 *(.eh_frame .note.GNU-stack)
72         }
73 }